You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 30KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 9)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2014)
  9. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[info@bitcoin.org],[bitcoin])
  10. AC_CONFIG_SRCDIR([src/main.cpp])
  11. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  12. AC_CONFIG_AUX_DIR([build-aux])
  13. AC_CONFIG_MACRO_DIR([build-aux/m4])
  14. AC_CANONICAL_HOST
  15. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  16. AH_TOP([#define BITCOIN_CONFIG_H])
  17. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  18. dnl faketime breaks configure and is only needed for make. Disable it here.
  19. unset FAKETIME
  20. dnl Automake init set-up and checks
  21. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  22. dnl faketime messes with timestamps and causes configure to be re-run.
  23. dnl --disable-maintainer-mode can be used to bypass this.
  24. AM_MAINTAINER_MODE([enable])
  25. dnl make the compilation flags quiet unless V=1 is used
  26. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  27. dnl Compiler checks (here before libtool).
  28. if test "x${CXXFLAGS+set}" = "xset"; then
  29. CXXFLAGS_overridden=yes
  30. else
  31. CXXFLAGS_overridden=no
  32. fi
  33. AC_PROG_CXX
  34. m4_ifdef([AC_PROG_OBJCXX],[AC_PROG_OBJCXX])
  35. dnl By default, libtool for mingw refuses to link static libs into a dll for
  36. dnl fear of mixing pic/non-pic objects, and import/export complications. Since
  37. dnl we have those under control, re-enable that functionality.
  38. case $host in
  39. *mingw*)
  40. lt_cv_deplibs_check_method="pass_all"
  41. ;;
  42. esac
  43. dnl Libtool init checks.
  44. LT_INIT([pic-only])
  45. dnl Check/return PATH for base programs.
  46. AC_PATH_TOOL(AR, ar)
  47. AC_PATH_TOOL(RANLIB, ranlib)
  48. AC_PATH_TOOL(STRIP, strip)
  49. AC_PATH_TOOL(GCOV, gcov)
  50. AC_PATH_PROG(LCOV, lcov)
  51. AC_PATH_PROG(JAVA, java)
  52. AC_PATH_PROG(GENHTML, genhtml)
  53. AC_PATH_PROG([GIT], [git])
  54. AC_PATH_PROG(CCACHE,ccache)
  55. AC_PATH_PROG(XGETTEXT,xgettext)
  56. AC_PATH_PROG(HEXDUMP,hexdump)
  57. # This m4 will only be used if a system copy cannot be found. This is helpful
  58. # on systems where autotools are installed but the pkg-config macros are not in
  59. # a default location. It is currently used for building on OSX where autotools
  60. # are preinstalled but pkg-config comes from macports or homebrew. It should
  61. # probably be removed when building on <= 10.6 is no longer supported.
  62. m4_include([pkg.m4])
  63. dnl pkg-config check.
  64. PKG_PROG_PKG_CONFIG
  65. # Enable wallet
  66. AC_ARG_ENABLE([wallet],
  67. [AS_HELP_STRING([--enable-wallet],
  68. [enable wallet (default is yes)])],
  69. [enable_wallet=$enableval],
  70. [enable_wallet=yes])
  71. AC_ARG_WITH([miniupnpc],
  72. [AS_HELP_STRING([--with-miniupnpc],
  73. [enable UPNP (default is yes if libminiupnpc is found)])],
  74. [use_upnp=$withval],
  75. [use_upnp=auto])
  76. AC_ARG_ENABLE([upnp-default],
  77. [AS_HELP_STRING([--enable-upnp-default],
  78. [if UPNP is enabled, turn it on at startup (default is no)])],
  79. [use_upnp_default=$enableval],
  80. [use_upnp_default=no])
  81. AC_ARG_ENABLE(tests,
  82. AS_HELP_STRING([--enable-tests],[compile tests (default is yes)]),
  83. [use_tests=$enableval],
  84. [use_tests=yes])
  85. AC_ARG_WITH([comparison-tool],
  86. AS_HELP_STRING([--with-comparison-tool],[path to java comparison tool (requires --enable-tests)]),
  87. [use_comparison_tool=$withval],
  88. [use_comparison_tool=no])
  89. AC_ARG_ENABLE([comparison-tool-reorg-tests],
  90. AS_HELP_STRING([--enable-comparison-tool-reorg-tests],[enable expensive reorg tests in the comparison tool (default no)]),
  91. [use_comparison_tool_reorg_tests=$enableval],
  92. [use_comparison_tool_reorg_tests=no])
  93. AC_ARG_WITH([qrencode],
  94. [AS_HELP_STRING([--with-qrencode],
  95. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  96. [use_qr=$withval],
  97. [use_qr=auto])
  98. AC_ARG_ENABLE([hardening],
  99. [AS_HELP_STRING([--enable-hardening],
  100. [attempt to harden the resulting executables (default is yes)])],
  101. [use_hardening=$enableval],
  102. [use_hardening=yes])
  103. AC_ARG_ENABLE([reduce-exports],
  104. [AS_HELP_STRING([--enable-reduce-exports],
  105. [attempt to reduce exported symbols in the resulting executables (default is yes)])],
  106. [use_reduce_exports=$enableval],
  107. [use_reduce_exports=auto])
  108. AC_ARG_ENABLE([ccache],
  109. [AS_HELP_STRING([--enable-ccache],
  110. [use ccache for building (default is yes if ccache is found)])],
  111. [use_ccache=$enableval],
  112. [use_ccache=auto])
  113. AC_ARG_ENABLE([lcov],
  114. [AS_HELP_STRING([--enable-lcov],
  115. [enable lcov testing (default is no)])],
  116. [use_lcov=yes],
  117. [use_lcov=no])
  118. AC_ARG_ENABLE([glibc-back-compat],
  119. [AS_HELP_STRING([--enable-glibc-back-compat],
  120. [enable backwards compatibility with glibc and libstdc++])],
  121. [use_glibc_compat=$enableval],
  122. [use_glibc_compat=no])
  123. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  124. # Enable debug
  125. AC_ARG_ENABLE([debug],
  126. [AS_HELP_STRING([--enable-debug],
  127. [use debug compiler flags and macros (default is no)])],
  128. [enable_debug=$enableval],
  129. [enable_debug=no])
  130. if test "x$enable_debug" = xyes; then
  131. if test "x$GCC" = xyes; then
  132. CFLAGS="-g3 -O0 -DDEBUG"
  133. fi
  134. if test "x$GXX" = xyes; then
  135. CXXFLAGS="-g3 -O0 -DDEBUG"
  136. fi
  137. fi
  138. ## TODO: Remove these hard-coded paths and flags. They are here for the sake of
  139. ## compatibility with the legacy buildsystem.
  140. ##
  141. if test "x$CXXFLAGS_overridden" = "xno"; then
  142. CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter"
  143. fi
  144. CPPFLAGS="$CPPFLAGS -DBOOST_SPIRIT_THREADSAFE -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  145. AC_LANG_PUSH([C++])
  146. use_pkgconfig=yes
  147. case $host in
  148. *mingw*)
  149. #pkgconfig does more harm than good with MinGW
  150. use_pkgconfig=no
  151. TARGET_OS=windows
  152. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  153. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  154. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  155. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  156. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  157. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  158. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  159. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  160. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  161. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  162. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  163. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  164. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  165. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  166. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  167. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  168. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  169. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  170. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  171. # -static is interpreted by libtool, where it has a different meaning.
  172. # In libtool-speak, it's -all-static.
  173. AX_CHECK_LINK_FLAG([[-static]],[LIBTOOL_APP_LDFLAGS="$LIBTOOL_APP_LDFLAGS -all-static"])
  174. AC_PATH_PROG([MAKENSIS], [makensis], none)
  175. if test x$MAKENSIS = xnone; then
  176. AC_MSG_WARN("makensis not found. Cannot create installer.")
  177. fi
  178. AC_PATH_TOOL(WINDRES, windres, none)
  179. if test x$WINDRES = xnone; then
  180. AC_MSG_ERROR("windres not found")
  181. fi
  182. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  183. LEVELDB_TARGET_FLAGS="TARGET_OS=OS_WINDOWS_CROSSCOMPILE"
  184. if test "x$CXXFLAGS_overridden" = "xno"; then
  185. CXXFLAGS="$CXXFLAGS -w"
  186. fi
  187. case $host in
  188. i?86-*) WINDOWS_BITS=32 ;;
  189. x86_64-*) WINDOWS_BITS=64 ;;
  190. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  191. esac
  192. AC_SUBST(WINDOWS_BITS)
  193. dnl libtool insists upon adding -nostdlib and a list of objects/libs to link against.
  194. dnl That breaks our ability to build dll's with static libgcc/libstdc++/libssp. Override
  195. dnl its command here, with the predeps/postdeps removed, and -static inserted. Postdeps are
  196. dnl also overridden to prevent their insertion later.
  197. dnl This should only affect dll's.
  198. archive_cmds_CXX="\$CC -shared \$libobjs \$deplibs \$compiler_flags -static -o \$output_objdir/\$soname \${wl}--enable-auto-image-base -Xlinker --out-implib -Xlinker \$lib"
  199. postdeps_CXX=
  200. ;;
  201. *darwin*)
  202. TARGET_OS=darwin
  203. LEVELDB_TARGET_FLAGS="TARGET_OS=Darwin"
  204. if test x$cross_compiling != xyes; then
  205. BUILD_OS=darwin
  206. AC_CHECK_PROG([PORT],port, port)
  207. if test x$PORT = xport; then
  208. dnl add default macports paths
  209. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include -I/opt/local/include/db48"
  210. LIBS="$LIBS -L/opt/local/lib -L/opt/local/lib/db48"
  211. fi
  212. AC_CHECK_PROG([BREW],brew, brew)
  213. if test x$BREW = xbrew; then
  214. dnl These Homebrew packages may be keg-only, meaning that they won't be found
  215. dnl in expected paths because they may conflict with system files. Ask
  216. dnl Homebrew where each one is located, then adjust paths accordingly.
  217. dnl It's safe to add these paths even if the functionality is disabled by
  218. dnl the user (--without-wallet or --without-gui for example).
  219. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  220. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  221. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  222. if test x$openssl_prefix != x; then
  223. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  224. export PKG_CONFIG_PATH
  225. fi
  226. if test x$bdb_prefix != x; then
  227. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  228. LIBS="$LIBS -L$bdb_prefix/lib"
  229. fi
  230. if test x$qt5_prefix != x; then
  231. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  232. export PKG_CONFIG_PATH
  233. fi
  234. fi
  235. else
  236. case $build_os in
  237. *darwin*)
  238. BUILD_OS=darwin
  239. ;;
  240. *)
  241. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  242. AC_PATH_TOOL([OTOOL], [otool], otool)
  243. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  244. ;;
  245. esac
  246. fi
  247. AX_CHECK_LINK_FLAG([[-Wl,-headerpad_max_install_names]], [LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"])
  248. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  249. ;;
  250. *linux*)
  251. TARGET_OS=linux
  252. ;;
  253. *)
  254. ;;
  255. esac
  256. if test x$use_comparison_tool != xno; then
  257. AC_SUBST(JAVA_COMPARISON_TOOL, $use_comparison_tool)
  258. fi
  259. if test x$use_comparison_tool_reorg_tests != xno; then
  260. if test x$use_comparison_tool = x; then
  261. AC_MSG_ERROR("comparison tool reorg tests but comparison tool was not specified")
  262. fi
  263. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 1)
  264. else
  265. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 0)
  266. fi
  267. if test x$use_lcov = xyes; then
  268. if test x$LCOV = x; then
  269. AC_MSG_ERROR("lcov testing requested but lcov not found")
  270. fi
  271. if test x$GCOV = x; then
  272. AC_MSG_ERROR("lcov testing requested but gcov not found")
  273. fi
  274. if test x$JAVA = x; then
  275. AC_MSG_ERROR("lcov testing requested but java not found")
  276. fi
  277. if test x$GENHTML = x; then
  278. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  279. fi
  280. if test x$use_comparison_tool = x; then
  281. AC_MSG_ERROR("lcov testing requested but comparison tool was not specified")
  282. fi
  283. LCOV="$LCOV --gcov-tool=$GCOV"
  284. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  285. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  286. fi
  287. dnl Require little endian
  288. AC_C_BIGENDIAN([AC_MSG_ERROR("Big Endian not supported")])
  289. dnl Check for pthread compile/link requirements
  290. AX_PTHREAD
  291. # The following macro will add the necessary defines to bitcoin-config.h, but
  292. # they also need to be passed down to any subprojects. Pull the results out of
  293. # the cache and add them to CPPFLAGS.
  294. AC_SYS_LARGEFILE
  295. # detect POSIX or GNU variant of strerror_r
  296. AC_FUNC_STRERROR_R
  297. if test x$ac_cv_sys_file_offset_bits != x &&
  298. test x$ac_cv_sys_file_offset_bits != xno &&
  299. test x$ac_cv_sys_file_offset_bits != xunknown; then
  300. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  301. fi
  302. if test x$ac_cv_sys_large_files != x &&
  303. test x$ac_cv_sys_large_files != xno &&
  304. test x$ac_cv_sys_large_files != xunknown; then
  305. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  306. fi
  307. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  308. AX_GCC_FUNC_ATTRIBUTE([visibility])
  309. AX_GCC_FUNC_ATTRIBUTE([dllexport])
  310. AX_GCC_FUNC_ATTRIBUTE([dllimport])
  311. if test x$use_glibc_compat != xno; then
  312. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  313. # See which one is present here.
  314. AC_MSG_CHECKING(__fdelt_chk type)
  315. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  316. #undef _FORTIFY_SOURCE
  317. #endif
  318. #define _FORTIFY_SOURCE 2
  319. #include <sys/select.h>
  320. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  321. [ fdelt_type="long unsigned int"],
  322. [ fdelt_type="long int"])
  323. AC_MSG_RESULT($fdelt_type)
  324. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  325. fi
  326. if test x$use_hardening != xno; then
  327. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  328. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  329. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  330. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  331. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  332. ])
  333. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  334. ])
  335. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  336. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  337. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  338. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  339. if test x$TARGET_OS != xwindows; then
  340. # All windows code is PIC, forcing it on just adds useless compile warnings
  341. AX_CHECK_COMPILE_FLAG([-fPIE],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fPIE"])
  342. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  343. fi
  344. case $host in
  345. *mingw*)
  346. AC_CHECK_LIB([ssp], [main],, AC_MSG_ERROR(lib missing))
  347. ;;
  348. esac
  349. CXXFLAGS="$CXXFLAGS $HARDENED_CXXFLAGS"
  350. CPPFLAGS="$CPPFLAGS $HARDENED_CPPFLAGS"
  351. LDFLAGS="$LDFLAGS $HARDENED_LDFLAGS"
  352. OBJCXXFLAGS="$CXXFLAGS"
  353. fi
  354. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  355. if test x$TARGET_OS = xdarwin; then
  356. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  357. fi
  358. AC_CHECK_HEADERS([endian.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  359. AC_SEARCH_LIBS([getaddrinfo_a], [anl], [AC_DEFINE(HAVE_GETADDRINFO_A, 1, [Define this symbol if you have getaddrinfo_a])])
  360. AC_SEARCH_LIBS([inet_pton], [nsl resolv], [AC_DEFINE(HAVE_INET_PTON, 1, [Define this symbol if you have inet_pton])])
  361. AC_CHECK_DECLS([le32toh, le64toh, htole32, htole64, be32toh, be64toh, htobe32, htobe64],,,
  362. [#if HAVE_ENDIAN_H
  363. #include <endian.h>
  364. #endif])
  365. dnl Check for MSG_NOSIGNAL
  366. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  367. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  368. [[ int f = MSG_NOSIGNAL; ]])],
  369. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  370. [ AC_MSG_RESULT(no)]
  371. )
  372. AC_SEARCH_LIBS([clock_gettime],[rt])
  373. AC_MSG_CHECKING([for visibility attribute])
  374. AC_LINK_IFELSE([AC_LANG_SOURCE([
  375. int foo_def( void ) __attribute__((visibility("default")));
  376. int main(){}
  377. ])],
  378. [
  379. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  380. AC_MSG_RESULT(yes)
  381. ],
  382. [
  383. AC_MSG_RESULT(no)
  384. if test x$use_reduce_exports = xyes; then
  385. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduced-exports.])
  386. fi
  387. AC_MSG_WARN([Cannot find a working visibility attribute. Disabling reduced exports.])
  388. use_reduce_exports=no
  389. ]
  390. )
  391. if test x$use_reduce_exports != xno; then
  392. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  393. [
  394. if test x$use_reduce_exports = xyes; then
  395. AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduced-exports.])
  396. fi
  397. AC_MSG_WARN([Cannot set default symbol visibility. Disabling reduced exports.])
  398. use_reduce_exports=no
  399. ])
  400. fi
  401. LEVELDB_CPPFLAGS=
  402. LIBLEVELDB=
  403. LIBMEMENV=
  404. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  405. AC_SUBST(LEVELDB_CPPFLAGS)
  406. AC_SUBST(LIBLEVELDB)
  407. AC_SUBST(LIBMEMENV)
  408. if test x$enable_wallet != xno; then
  409. dnl Check for libdb_cxx only if wallet enabled
  410. BITCOIN_FIND_BDB48
  411. fi
  412. dnl Check for libminiupnpc (optional)
  413. if test x$use_upnp != xno; then
  414. AC_CHECK_HEADERS(
  415. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  416. [AC_CHECK_LIB([miniupnpc], [main],[MINIUPNPC_LIBS=-lminiupnpc], [have_miniupnpc=no])],
  417. [have_miniupnpc=no]
  418. )
  419. fi
  420. dnl Check for boost libs
  421. AX_BOOST_BASE
  422. AX_BOOST_SYSTEM
  423. AX_BOOST_FILESYSTEM
  424. AX_BOOST_PROGRAM_OPTIONS
  425. AX_BOOST_THREAD
  426. AX_BOOST_CHRONO
  427. if test x$use_reduce_exports != xno; then
  428. AC_MSG_CHECKING([for working boost reduced exports])
  429. TEMP_CPPFLAGS="$CPPFLAGS"
  430. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  431. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  432. @%:@include <boost/version.hpp>
  433. ]], [[
  434. #if BOOST_VERSION >= 104900
  435. // Everything is okay
  436. #else
  437. # error Boost version is too old
  438. #endif
  439. ]])],[
  440. AC_MSG_RESULT(yes)
  441. ],[:
  442. if test x$use_reduce_exports = xauto; then
  443. use_reduce_exports=no
  444. else
  445. if test x$use_reduce_exports = xyes; then
  446. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduced-exports.])
  447. fi
  448. fi
  449. AC_MSG_RESULT(no)
  450. AC_MSG_WARN([boost versions < 1.49 are known to have symbol visibility issues. Disabling reduced exports.])
  451. ])
  452. CPPFLAGS="$TEMP_CPPFLAGS"
  453. fi
  454. if test x$use_reduce_exports != xno; then
  455. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  456. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  457. fi
  458. if test x$use_tests = xyes; then
  459. if test x$HEXDUMP = x; then
  460. AC_MSG_ERROR(hexdump is required for tests)
  461. fi
  462. AX_BOOST_UNIT_TEST_FRAMEWORK
  463. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  464. AC_MSG_CHECKING([for dynamic linked boost test])
  465. TEMP_LIBS="$LIBS"
  466. LIBS="$LIBS $BOOST_LDFLAGS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  467. TEMP_CPPFLAGS="$CPPFLAGS"
  468. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  469. AC_LINK_IFELSE([AC_LANG_SOURCE([
  470. #define BOOST_TEST_DYN_LINK
  471. #define BOOST_TEST_MAIN
  472. #include <boost/test/unit_test.hpp>
  473. ])],
  474. [AC_MSG_RESULT(yes)]
  475. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  476. [AC_MSG_RESULT(no)])
  477. LIBS="$TEMP_LIBS"
  478. CPPFLAGS="$TEMP_CPPFLAGS"
  479. fi
  480. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB"
  481. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  482. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  483. dnl a working version is available, else fall back to sleep. sleep was removed
  484. dnl after 1.56.
  485. dnl If neither is available, abort.
  486. dnl If sleep_for is used, boost_chrono becomes a requirement.
  487. if test x$ax_cv_boost_chrono = xyes; then
  488. TEMP_LIBS="$LIBS"
  489. LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB $LIBS"
  490. TEMP_CPPFLAGS="$CPPFLAGS"
  491. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  492. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  493. #include <boost/thread/thread.hpp>
  494. #include <boost/version.hpp>
  495. ]],[[
  496. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  497. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  498. #else
  499. choke me
  500. #endif
  501. ]])],
  502. [boost_sleep=yes; BOOST_LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB";
  503. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  504. [boost_sleep=no])
  505. LIBS="$TEMP_LIBS"
  506. CPPFLAGS="$TEMP_CPPFLAGS"
  507. fi
  508. if test x$boost_sleep != xyes; then
  509. TEMP_LIBS="$LIBS"
  510. LIBS="$BOOST_LIBS $LIBS"
  511. TEMP_CPPFLAGS="$CPPFLAGS"
  512. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  513. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  514. #include <boost/version.hpp>
  515. #include <boost/thread.hpp>
  516. #include <boost/date_time/posix_time/posix_time_types.hpp>
  517. ]],[[
  518. #if BOOST_VERSION <= 105600
  519. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  520. #else
  521. choke me
  522. #endif
  523. ]])],
  524. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  525. [boost_sleep=no])
  526. LIBS="$TEMP_LIBS"
  527. CPPFLAGS="$TEMP_CPPFLAGS"
  528. fi
  529. if test x$boost_sleep != xyes; then
  530. AC_MSG_ERROR(No working boost sleep implementation found.)
  531. fi
  532. AC_ARG_WITH([utils],
  533. [AS_HELP_STRING([--with-utils],
  534. [build bitcoin-cli bitcoin-tx (default=yes)])],
  535. [build_bitcoin_utils=$withval],
  536. [build_bitcoin_utils=yes])
  537. AC_ARG_WITH([libs],
  538. [AS_HELP_STRING([--with-libs],
  539. [build libraries (default=yes)])],
  540. [build_bitcoin_libs=$withval],
  541. [build_bitcoin_libs=yes])
  542. AC_ARG_WITH([daemon],
  543. [AS_HELP_STRING([--with-daemon],
  544. [build bitcoind daemon (default=yes)])],
  545. [build_bitcoind=$withval],
  546. [build_bitcoind=yes])
  547. BITCOIN_QT_INIT
  548. if test x$use_pkgconfig = xyes; then
  549. if test x"$PKG_CONFIG" = "x"; then
  550. AC_MSG_ERROR(pkg-config not found.)
  551. fi
  552. : #NOP
  553. m4_ifdef(
  554. [PKG_CHECK_MODULES],
  555. [
  556. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  557. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  558. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  559. if test x$use_qr != xno; then
  560. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  561. fi
  562. ]
  563. )
  564. else
  565. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  566. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  567. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  568. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  569. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],[PROTOBUF_LIBS=-lprotobuf], BITCOIN_QT_FAIL(libprotobuf not found)))
  570. if test x$use_qr != xno; then
  571. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],[QR_LIBS=-lqrencode], [have_qrencode=no])])
  572. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  573. fi
  574. fi
  575. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  576. AC_MSG_CHECKING([whether to build bitcoind])
  577. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  578. AC_MSG_RESULT($build_bitcoind)
  579. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  580. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  581. AC_MSG_RESULT($build_bitcoin_utils)
  582. AC_MSG_CHECKING([whether to build libraries])
  583. AM_CONDITIONAL([BUILD_BITCOIN_LIBS], [test x$build_bitcoin_libs = xyes])
  584. if test x$build_bitcoin_libs = xyes; then
  585. AC_DEFINE(HAVE_CONSENSUS_LIB, 1, [Define this symbol if the consensus lib has been built])
  586. AC_CONFIG_FILES([libbitcoinconsensus.pc:libbitcoinconsensus.pc.in])
  587. fi
  588. AC_MSG_RESULT($build_bitcoin_libs)
  589. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  590. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt4])
  591. AC_LANG_POP
  592. if test "x$use_ccache" != "xno"; then
  593. AC_MSG_CHECKING(if ccache should be used)
  594. if test x$CCACHE = x; then
  595. if test "x$use_ccache" = "xyes"; then
  596. AC_MSG_ERROR([ccache not found.]);
  597. else
  598. use_ccache=no
  599. fi
  600. else
  601. use_ccache=yes
  602. CC="$ac_cv_path_CCACHE $CC"
  603. CXX="$ac_cv_path_CCACHE $CXX"
  604. fi
  605. AC_MSG_RESULT($use_ccache)
  606. fi
  607. if test "x$use_ccache" = "xyes"; then
  608. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  609. fi
  610. dnl enable wallet
  611. AC_MSG_CHECKING([if wallet should be enabled])
  612. if test x$enable_wallet != xno; then
  613. AC_MSG_RESULT(yes)
  614. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  615. else
  616. AC_MSG_RESULT(no)
  617. fi
  618. dnl enable upnp support
  619. AC_MSG_CHECKING([whether to build with support for UPnP])
  620. if test x$have_miniupnpc = xno; then
  621. if test x$use_upnp = xyes; then
  622. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  623. fi
  624. AC_MSG_RESULT(no)
  625. else
  626. if test x$use_upnp != xno; then
  627. AC_MSG_RESULT(yes)
  628. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  629. use_upnp=yes
  630. upnp_setting=0
  631. if test x$use_upnp_default != xno; then
  632. use_upnp_default=yes
  633. upnp_setting=1
  634. fi
  635. AC_MSG_RESULT($use_upnp_default)
  636. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  637. if test x$TARGET_OS = xwindows; then
  638. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  639. fi
  640. else
  641. AC_MSG_RESULT(no)
  642. fi
  643. fi
  644. dnl these are only used when qt is enabled
  645. if test x$bitcoin_enable_qt != xno; then
  646. BUILD_QT=qt
  647. dnl enable dbus support
  648. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  649. if test x$bitcoin_enable_qt_dbus != xno; then
  650. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  651. fi
  652. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  653. dnl enable qr support
  654. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  655. if test x$have_qrencode = xno; then
  656. if test x$use_qr = xyes; then
  657. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  658. fi
  659. AC_MSG_RESULT(no)
  660. else
  661. if test x$use_qr != xno; then
  662. AC_MSG_RESULT(yes)
  663. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  664. use_qr=yes
  665. else
  666. AC_MSG_RESULT(no)
  667. fi
  668. fi
  669. if test x$XGETTEXT = x; then
  670. AC_MSG_WARN("xgettext is required to update qt translations")
  671. fi
  672. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  673. if test x$use_tests$bitcoin_enable_qt_test = xyesyes; then
  674. AC_MSG_RESULT([yes])
  675. BUILD_TEST_QT="test"
  676. else
  677. AC_MSG_RESULT([no])
  678. fi
  679. fi
  680. AC_MSG_CHECKING([whether to build test_bitcoin])
  681. if test x$use_tests = xyes; then
  682. AC_MSG_RESULT([yes])
  683. BUILD_TEST="test"
  684. else
  685. AC_MSG_RESULT([no])
  686. fi
  687. AC_MSG_CHECKING([whether to reduce exports])
  688. if test x$use_reduce_exports != xno; then
  689. AC_MSG_RESULT([yes])
  690. else
  691. AC_MSG_RESULT([no])
  692. fi
  693. if test x$build_bitcoin_utils$build_bitcoin_libs$build_bitcoind$bitcoin_enable_qt$use_tests = xnononono; then
  694. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-libs --with-daemon --with-gui or --enable-tests])
  695. fi
  696. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  697. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  698. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  699. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  700. AM_CONDITIONAL([ENABLE_TESTS],[test x$use_tests = xyes])
  701. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  702. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$use_tests$bitcoin_enable_qt_test = xyesyes])
  703. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  704. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  705. AM_CONDITIONAL([USE_COMPARISON_TOOL],[test x$use_comparison_tool != xno])
  706. AM_CONDITIONAL([USE_COMPARISON_TOOL_REORG_TESTS],[test x$use_comparison_tool_reorg_test != xno])
  707. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  708. AM_CONDITIONAL([USE_LIBSECP256K1],[test x$use_libsecp256k1 = xyes])
  709. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  710. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  711. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  712. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  713. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  714. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Version is release])
  715. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  716. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  717. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  718. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  719. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  720. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  721. AC_SUBST(RELDFLAGS)
  722. AC_SUBST(LIBTOOL_APP_LDFLAGS)
  723. AC_SUBST(USE_UPNP)
  724. AC_SUBST(USE_QRCODE)
  725. AC_SUBST(BOOST_LIBS)
  726. AC_SUBST(TESTDEFS)
  727. AC_SUBST(LEVELDB_TARGET_FLAGS)
  728. AC_SUBST(BUILD_TEST)
  729. AC_SUBST(BUILD_QT)
  730. AC_SUBST(BUILD_TEST_QT)
  731. AC_SUBST(MINIUPNPC_CPPFLAGS)
  732. AC_SUBST(MINIUPNPC_LIBS)
  733. AC_CONFIG_FILES([Makefile src/Makefile share/setup.nsi share/qt/Info.plist src/test/buildenv.py])
  734. AC_CONFIG_FILES([qa/pull-tester/run-bitcoind-for-test.sh],[chmod +x qa/pull-tester/run-bitcoind-for-test.sh])
  735. AC_CONFIG_FILES([qa/pull-tester/tests-config.sh],[chmod +x qa/pull-tester/tests-config.sh])
  736. dnl boost's m4 checks do something really nasty: they export these vars. As a
  737. dnl result, they leak into secp256k1's configure and crazy things happen.
  738. dnl Until this is fixed upstream and we've synced, we'll just un-export them.
  739. CPPFLAGS_TEMP="$CPPFLAGS"
  740. unset CPPFLAGS
  741. CPPFLAGS="$CPPFLAGS_TEMP"
  742. LDFLAGS_TEMP="$LDFLAGS"
  743. unset LDFLAGS
  744. LDFLAGS="$LDFLAGS_TEMP"
  745. LIBS_TEMP="$LIBS"
  746. unset LIBS
  747. LIBS="$LIBS_TEMP"
  748. PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
  749. unset PKG_CONFIG_PATH
  750. PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
  751. PKGCONFIG_LIBDIR_TEMP="$PKG_CONFIG_LIBDIR"
  752. unset PKG_CONFIG_LIBDIR
  753. PKG_CONFIG_LIBDIR="$PKGCONFIG_LIBDIR_TEMP"
  754. ac_configure_args="${ac_configure_args} --disable-shared --with-pic"
  755. AC_CONFIG_SUBDIRS([src/secp256k1])
  756. AC_OUTPUT
  757. dnl Taken from https://wiki.debian.org/RpathIssue
  758. case $host in
  759. *-*-linux-gnu)
  760. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  761. sed < libtool > libtool-2 \
  762. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  763. mv libtool-2 libtool
  764. chmod 755 libtool
  765. ;;
  766. esac