You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 45KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 14)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2017)
  9. define(_COPYRIGHT_HOLDERS,[The %s developers])
  10. define(_COPYRIGHT_HOLDERS_SUBSTITUTION,[[Bitcoin Core]])
  11. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[https://github.com/bitcoin/bitcoin/issues],[bitcoin],[https://bitcoincore.org/])
  12. AC_CONFIG_SRCDIR([src/validation.cpp])
  13. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  14. AC_CONFIG_AUX_DIR([build-aux])
  15. AC_CONFIG_MACRO_DIR([build-aux/m4])
  16. BITCOIN_DAEMON_NAME=bitcoind
  17. BITCOIN_GUI_NAME=bitcoin-qt
  18. BITCOIN_CLI_NAME=bitcoin-cli
  19. BITCOIN_TX_NAME=bitcoin-tx
  20. dnl Unless the user specified ARFLAGS, force it to be cr
  21. AC_ARG_VAR(ARFLAGS, [Flags for the archiver, defaults to <cr> if not set])
  22. if test "x${ARFLAGS+set}" != "xset"; then
  23. ARFLAGS="cr"
  24. fi
  25. AC_CANONICAL_HOST
  26. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  27. AH_TOP([#define BITCOIN_CONFIG_H])
  28. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  29. dnl faketime breaks configure and is only needed for make. Disable it here.
  30. unset FAKETIME
  31. dnl Automake init set-up and checks
  32. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  33. dnl faketime messes with timestamps and causes configure to be re-run.
  34. dnl --disable-maintainer-mode can be used to bypass this.
  35. AM_MAINTAINER_MODE([enable])
  36. dnl make the compilation flags quiet unless V=1 is used
  37. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  38. dnl Compiler checks (here before libtool).
  39. if test "x${CXXFLAGS+set}" = "xset"; then
  40. CXXFLAGS_overridden=yes
  41. else
  42. CXXFLAGS_overridden=no
  43. fi
  44. AC_PROG_CXX
  45. dnl By default, libtool for mingw refuses to link static libs into a dll for
  46. dnl fear of mixing pic/non-pic objects, and import/export complications. Since
  47. dnl we have those under control, re-enable that functionality.
  48. case $host in
  49. *mingw*)
  50. lt_cv_deplibs_check_method="pass_all"
  51. ;;
  52. esac
  53. dnl Require C++11 compiler (no GNU extensions)
  54. AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory], [nodefault])
  55. dnl Check if -latomic is required for <std::atomic>
  56. CHECK_ATOMIC
  57. dnl Unless the user specified OBJCXX, force it to be the same as CXX. This ensures
  58. dnl that we get the same -std flags for both.
  59. m4_ifdef([AC_PROG_OBJCXX],[
  60. if test "x${OBJCXX+set}" = "x"; then
  61. OBJCXX="${CXX}"
  62. fi
  63. AC_PROG_OBJCXX
  64. ])
  65. dnl Libtool init checks.
  66. LT_INIT([pic-only])
  67. dnl Check/return PATH for base programs.
  68. AC_PATH_TOOL(AR, ar)
  69. AC_PATH_TOOL(RANLIB, ranlib)
  70. AC_PATH_TOOL(STRIP, strip)
  71. AC_PATH_TOOL(GCOV, gcov)
  72. AC_PATH_PROG(LCOV, lcov)
  73. dnl Python 3.x is supported from 3.4 on (see https://github.com/bitcoin/bitcoin/issues/7893)
  74. AC_PATH_PROGS([PYTHON], [python3.6 python3.5 python3.4 python3 python2.7 python2 python])
  75. AC_PATH_PROG(GENHTML, genhtml)
  76. AC_PATH_PROG([GIT], [git])
  77. AC_PATH_PROG(CCACHE,ccache)
  78. AC_PATH_PROG(XGETTEXT,xgettext)
  79. AC_PATH_PROG(HEXDUMP,hexdump)
  80. AC_PATH_TOOL(READELF, readelf)
  81. AC_PATH_TOOL(CPPFILT, c++filt)
  82. AC_PATH_TOOL(OBJCOPY, objcopy)
  83. AC_ARG_VAR(PYTHONPATH, Augments the default search path for python module files)
  84. # Enable wallet
  85. AC_ARG_ENABLE([wallet],
  86. [AS_HELP_STRING([--disable-wallet],
  87. [disable wallet (enabled by default)])],
  88. [enable_wallet=$enableval],
  89. [enable_wallet=yes])
  90. AC_ARG_WITH([miniupnpc],
  91. [AS_HELP_STRING([--with-miniupnpc],
  92. [enable UPNP (default is yes if libminiupnpc is found)])],
  93. [use_upnp=$withval],
  94. [use_upnp=auto])
  95. AC_ARG_ENABLE([upnp-default],
  96. [AS_HELP_STRING([--enable-upnp-default],
  97. [if UPNP is enabled, turn it on at startup (default is no)])],
  98. [use_upnp_default=$enableval],
  99. [use_upnp_default=no])
  100. AC_ARG_ENABLE(tests,
  101. AS_HELP_STRING([--disable-tests],[do not compile tests (default is to compile)]),
  102. [use_tests=$enableval],
  103. [use_tests=yes])
  104. AC_ARG_ENABLE(gui-tests,
  105. AS_HELP_STRING([--disable-gui-tests],[do not compile GUI tests (default is to compile if GUI and tests enabled)]),
  106. [use_gui_tests=$enableval],
  107. [use_gui_tests=$use_tests])
  108. AC_ARG_ENABLE(bench,
  109. AS_HELP_STRING([--disable-bench],[do not compile benchmarks (default is to compile)]),
  110. [use_bench=$enableval],
  111. [use_bench=yes])
  112. AC_ARG_ENABLE([extended-functional-tests],
  113. AS_HELP_STRING([--enable-extended-functional-tests],[enable expensive functional tests when using lcov (default no)]),
  114. [use_extended_functional_tests=$enableval],
  115. [use_extended_functional_tests=no])
  116. AC_ARG_WITH([qrencode],
  117. [AS_HELP_STRING([--with-qrencode],
  118. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  119. [use_qr=$withval],
  120. [use_qr=auto])
  121. AC_ARG_ENABLE([hardening],
  122. [AS_HELP_STRING([--disable-hardening],
  123. [do not attempt to harden the resulting executables (default is to harden)])],
  124. [use_hardening=$enableval],
  125. [use_hardening=yes])
  126. AC_ARG_ENABLE([reduce-exports],
  127. [AS_HELP_STRING([--enable-reduce-exports],
  128. [attempt to reduce exported symbols in the resulting executables (default is no)])],
  129. [use_reduce_exports=$enableval],
  130. [use_reduce_exports=no])
  131. AC_ARG_ENABLE([ccache],
  132. [AS_HELP_STRING([--disable-ccache],
  133. [do not use ccache for building (default is to use if found)])],
  134. [use_ccache=$enableval],
  135. [use_ccache=auto])
  136. AC_ARG_ENABLE([lcov],
  137. [AS_HELP_STRING([--enable-lcov],
  138. [enable lcov testing (default is no)])],
  139. [use_lcov=yes],
  140. [use_lcov=no])
  141. AC_ARG_ENABLE([lcov-branch-coverage],
  142. [AS_HELP_STRING([--enable-lcov-branch-coverage],
  143. [enable lcov testing branch coverage (default is no)])],
  144. [use_lcov_branch=yes],
  145. [use_lcov_branch=no])
  146. AC_ARG_ENABLE([glibc-back-compat],
  147. [AS_HELP_STRING([--enable-glibc-back-compat],
  148. [enable backwards compatibility with glibc])],
  149. [use_glibc_compat=$enableval],
  150. [use_glibc_compat=no])
  151. AC_ARG_ENABLE([experimental-asm],
  152. [AS_HELP_STRING([--enable-experimental-asm],
  153. [Enable experimental assembly routines (default is no)])],
  154. [experimental_asm=$enableval],
  155. [experimental_asm=no])
  156. if test "x$experimental_asm" = xyes; then
  157. AC_DEFINE(EXPERIMENTAL_ASM, 1, [Define this symbol to build in experimental assembly routines])
  158. fi
  159. AC_ARG_WITH([system-univalue],
  160. [AS_HELP_STRING([--with-system-univalue],
  161. [Build with system UniValue (default is no)])],
  162. [system_univalue=$withval],
  163. [system_univalue=no]
  164. )
  165. AC_ARG_ENABLE([zmq],
  166. [AS_HELP_STRING([--disable-zmq],
  167. [disable ZMQ notifications])],
  168. [use_zmq=$enableval],
  169. [use_zmq=yes])
  170. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  171. AC_ARG_ENABLE(man,
  172. [AS_HELP_STRING([--disable-man],
  173. [do not install man pages (default is to install)])],,
  174. enable_man=yes)
  175. AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
  176. # Enable debug
  177. AC_ARG_ENABLE([debug],
  178. [AS_HELP_STRING([--enable-debug],
  179. [use debug compiler flags and macros (default is no)])],
  180. [enable_debug=$enableval],
  181. [enable_debug=no])
  182. # Turn warnings into errors
  183. AC_ARG_ENABLE([werror],
  184. [AS_HELP_STRING([--enable-werror],
  185. [Treat certain compiler warnings as errors (default is no)])],
  186. [enable_werror=$enableval],
  187. [enable_werror=no])
  188. AC_LANG_PUSH([C++])
  189. AX_CHECK_COMPILE_FLAG([-Werror],[CXXFLAG_WERROR="-Werror"],[CXXFLAG_WERROR=""])
  190. if test "x$enable_debug" = xyes; then
  191. CPPFLAGS="$CPPFLAGS -DDEBUG -DDEBUG_LOCKORDER"
  192. if test "x$GCC" = xyes; then
  193. CFLAGS="$CFLAGS -g3 -O0"
  194. fi
  195. if test "x$GXX" = xyes; then
  196. CXXFLAGS="$CXXFLAGS -g3 -O0"
  197. fi
  198. fi
  199. ERROR_CXXFLAGS=
  200. if test "x$enable_werror" = "xyes"; then
  201. if test "x$CXXFLAG_WERROR" = "x"; then
  202. AC_MSG_ERROR("enable-werror set but -Werror is not usable")
  203. fi
  204. AX_CHECK_COMPILE_FLAG([-Werror=vla],[ERROR_CXXFLAGS="$ERROR_CXXFLAGS -Werror=vla"],,[[$CXXFLAG_WERROR]])
  205. fi
  206. if test "x$CXXFLAGS_overridden" = "xno"; then
  207. AX_CHECK_COMPILE_FLAG([-Wall],[CXXFLAGS="$CXXFLAGS -Wall"],,[[$CXXFLAG_WERROR]])
  208. AX_CHECK_COMPILE_FLAG([-Wextra],[CXXFLAGS="$CXXFLAGS -Wextra"],,[[$CXXFLAG_WERROR]])
  209. AX_CHECK_COMPILE_FLAG([-Wformat],[CXXFLAGS="$CXXFLAGS -Wformat"],,[[$CXXFLAG_WERROR]])
  210. AX_CHECK_COMPILE_FLAG([-Wvla],[CXXFLAGS="$CXXFLAGS -Wvla"],,[[$CXXFLAG_WERROR]])
  211. AX_CHECK_COMPILE_FLAG([-Wformat-security],[CXXFLAGS="$CXXFLAGS -Wformat-security"],,[[$CXXFLAG_WERROR]])
  212. ## Some compilers (gcc) ignore unknown -Wno-* options, but warn about all
  213. ## unknown options if any other warning is produced. Test the -Wfoo case, and
  214. ## set the -Wno-foo case if it works.
  215. AX_CHECK_COMPILE_FLAG([-Wunused-parameter],[CXXFLAGS="$CXXFLAGS -Wno-unused-parameter"],,[[$CXXFLAG_WERROR]])
  216. AX_CHECK_COMPILE_FLAG([-Wself-assign],[CXXFLAGS="$CXXFLAGS -Wno-self-assign"],,[[$CXXFLAG_WERROR]])
  217. AX_CHECK_COMPILE_FLAG([-Wunused-local-typedef],[CXXFLAGS="$CXXFLAGS -Wno-unused-local-typedef"],,[[$CXXFLAG_WERROR]])
  218. AX_CHECK_COMPILE_FLAG([-Wdeprecated-register],[CXXFLAGS="$CXXFLAGS -Wno-deprecated-register"],,[[$CXXFLAG_WERROR]])
  219. AX_CHECK_COMPILE_FLAG([-Wimplicit-fallthrough],[CXXFLAGS="$CXXFLAGS -Wno-implicit-fallthrough"],,[[$CXXFLAG_WERROR]])
  220. # Check for optional instruction set support. Enabling these does _not_ imply that all code will
  221. # be compiled with them, rather that specific objects/libs may use them after checking for runtime
  222. # compatibility.
  223. AX_CHECK_COMPILE_FLAG([-msse4.2],[[SSE42_CXXFLAGS="-msse4.2"]],,[[$CXXFLAG_WERROR]])
  224. fi
  225. TEMP_CXXFLAGS="$CXXFLAGS"
  226. CXXFLAGS="$CXXFLAGS $SSE42_CXXFLAGS"
  227. AC_MSG_CHECKING(for assembler crc32 support)
  228. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  229. #include <stdint.h>
  230. #if defined(_MSC_VER)
  231. #include <intrin.h>
  232. #elif defined(__GNUC__) && defined(__SSE4_2__)
  233. #include <nmmintrin.h>
  234. #endif
  235. ]],[[
  236. uint64_t l = 0;
  237. l = _mm_crc32_u8(l, 0);
  238. l = _mm_crc32_u32(l, 0);
  239. l = _mm_crc32_u64(l, 0);
  240. return l;
  241. ]])],
  242. [ AC_MSG_RESULT(yes); enable_hwcrc32=yes],
  243. [ AC_MSG_RESULT(no)]
  244. )
  245. CXXFLAGS="$TEMP_CXXFLAGS"
  246. CPPFLAGS="$CPPFLAGS -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  247. AC_ARG_WITH([utils],
  248. [AS_HELP_STRING([--with-utils],
  249. [build bitcoin-cli bitcoin-tx (default=yes)])],
  250. [build_bitcoin_utils=$withval],
  251. [build_bitcoin_utils=yes])
  252. AC_ARG_WITH([libs],
  253. [AS_HELP_STRING([--with-libs],
  254. [build libraries (default=yes)])],
  255. [build_bitcoin_libs=$withval],
  256. [build_bitcoin_libs=yes])
  257. AC_ARG_WITH([daemon],
  258. [AS_HELP_STRING([--with-daemon],
  259. [build bitcoind daemon (default=yes)])],
  260. [build_bitcoind=$withval],
  261. [build_bitcoind=yes])
  262. use_pkgconfig=yes
  263. case $host in
  264. *mingw*)
  265. #pkgconfig does more harm than good with MinGW
  266. use_pkgconfig=no
  267. TARGET_OS=windows
  268. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  269. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  270. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  271. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  272. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  273. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  274. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  275. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  276. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  277. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  278. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  279. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  280. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  281. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  282. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  283. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  284. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  285. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  286. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  287. # -static is interpreted by libtool, where it has a different meaning.
  288. # In libtool-speak, it's -all-static.
  289. AX_CHECK_LINK_FLAG([[-static]],[LIBTOOL_APP_LDFLAGS="$LIBTOOL_APP_LDFLAGS -all-static"])
  290. AC_PATH_PROG([MAKENSIS], [makensis], none)
  291. if test x$MAKENSIS = xnone; then
  292. AC_MSG_WARN("makensis not found. Cannot create installer.")
  293. fi
  294. AC_PATH_TOOL(WINDRES, windres, none)
  295. if test x$WINDRES = xnone; then
  296. AC_MSG_ERROR("windres not found")
  297. fi
  298. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  299. LEVELDB_TARGET_FLAGS="-DOS_WINDOWS"
  300. if test "x$CXXFLAGS_overridden" = "xno"; then
  301. CXXFLAGS="$CXXFLAGS -w"
  302. fi
  303. case $host in
  304. i?86-*) WINDOWS_BITS=32 ;;
  305. x86_64-*) WINDOWS_BITS=64 ;;
  306. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  307. esac
  308. AC_SUBST(WINDOWS_BITS)
  309. dnl libtool insists upon adding -nostdlib and a list of objects/libs to link against.
  310. dnl That breaks our ability to build dll's with static libgcc/libstdc++/libssp. Override
  311. dnl its command here, with the predeps/postdeps removed, and -static inserted. Postdeps are
  312. dnl also overridden to prevent their insertion later.
  313. dnl This should only affect dll's.
  314. archive_cmds_CXX="\$CC -shared \$libobjs \$deplibs \$compiler_flags -static -o \$output_objdir/\$soname \${wl}--enable-auto-image-base -Xlinker --out-implib -Xlinker \$lib"
  315. postdeps_CXX=
  316. ;;
  317. *darwin*)
  318. TARGET_OS=darwin
  319. LEVELDB_TARGET_FLAGS="-DOS_MACOSX"
  320. if test x$cross_compiling != xyes; then
  321. BUILD_OS=darwin
  322. AC_CHECK_PROG([PORT],port, port)
  323. if test x$PORT = xport; then
  324. dnl add default macports paths
  325. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  326. LIBS="$LIBS -L/opt/local/lib"
  327. if test -d /opt/local/include/db48; then
  328. CPPFLAGS="$CPPFLAGS -I/opt/local/include/db48"
  329. LIBS="$LIBS -L/opt/local/lib/db48"
  330. fi
  331. fi
  332. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  333. AC_CHECK_PROG([BREW],brew, brew)
  334. if test x$BREW = xbrew; then
  335. dnl These Homebrew packages may be keg-only, meaning that they won't be found
  336. dnl in expected paths because they may conflict with system files. Ask
  337. dnl Homebrew where each one is located, then adjust paths accordingly.
  338. dnl It's safe to add these paths even if the functionality is disabled by
  339. dnl the user (--without-wallet or --without-gui for example).
  340. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  341. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  342. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  343. if test x$openssl_prefix != x; then
  344. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  345. export PKG_CONFIG_PATH
  346. fi
  347. if test x$bdb_prefix != x; then
  348. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  349. LIBS="$LIBS -L$bdb_prefix/lib"
  350. fi
  351. if test x$qt5_prefix != x; then
  352. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  353. export PKG_CONFIG_PATH
  354. fi
  355. fi
  356. else
  357. case $build_os in
  358. *darwin*)
  359. BUILD_OS=darwin
  360. ;;
  361. *)
  362. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  363. AC_PATH_TOOL([OTOOL], [otool], otool)
  364. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  365. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  366. AC_PATH_PROGS([IMAGEMAGICK_CONVERT], [convert],convert)
  367. AC_PATH_PROGS([TIFFCP], [tiffcp],tiffcp)
  368. dnl libtool will try to strip the static lib, which is a problem for
  369. dnl cross-builds because strip attempts to call a hard-coded ld,
  370. dnl which may not exist in the path. Stripping the .a is not
  371. dnl necessary, so just disable it.
  372. old_striplib=
  373. ;;
  374. esac
  375. fi
  376. AX_CHECK_LINK_FLAG([[-Wl,-headerpad_max_install_names]], [LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"])
  377. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  378. OBJCXXFLAGS="$CXXFLAGS"
  379. ;;
  380. *linux*)
  381. TARGET_OS=linux
  382. LEVELDB_TARGET_FLAGS="-DOS_LINUX"
  383. ;;
  384. *freebsd*)
  385. LEVELDB_TARGET_FLAGS="-DOS_FREEBSD"
  386. ;;
  387. *openbsd*)
  388. LEVELDB_TARGET_FLAGS="-DOS_OPENBSD"
  389. ;;
  390. *)
  391. OTHER_OS=`echo ${host_os} | awk '{print toupper($0)}'`
  392. AC_MSG_WARN([Guessing LevelDB OS as OS_${OTHER_OS}, please check whether this is correct, if not add an entry to configure.ac.])
  393. LEVELDB_TARGET_FLAGS="-DOS_${OTHER_OS}"
  394. ;;
  395. esac
  396. if test x$use_pkgconfig = xyes; then
  397. m4_ifndef([PKG_PROG_PKG_CONFIG], [AC_MSG_ERROR(PKG_PROG_PKG_CONFIG macro not found. Please install pkg-config and re-run autogen.sh.)])
  398. m4_ifdef([PKG_PROG_PKG_CONFIG], [
  399. PKG_PROG_PKG_CONFIG
  400. if test x"$PKG_CONFIG" = "x"; then
  401. AC_MSG_ERROR(pkg-config not found.)
  402. fi
  403. ])
  404. fi
  405. if test x$use_extended_functional_tests != xno; then
  406. AC_SUBST(EXTENDED_FUNCTIONAL_TESTS, --extended)
  407. fi
  408. if test x$use_lcov = xyes; then
  409. if test x$LCOV = x; then
  410. AC_MSG_ERROR("lcov testing requested but lcov not found")
  411. fi
  412. if test x$GCOV = x; then
  413. AC_MSG_ERROR("lcov testing requested but gcov not found")
  414. fi
  415. if test x$PYTHON = x; then
  416. AC_MSG_ERROR("lcov testing requested but python not found")
  417. fi
  418. if test x$GENHTML = x; then
  419. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  420. fi
  421. LCOV="$LCOV --gcov-tool=$GCOV"
  422. AX_CHECK_LINK_FLAG([[--coverage]], [LDFLAGS="$LDFLAGS --coverage"],
  423. [AC_MSG_ERROR("lcov testing requested but --coverage linker flag does not work")])
  424. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  425. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  426. AC_DEFINE(USE_COVERAGE, 1, [Define this symbol if coverage is enabled])
  427. CXXFLAGS="$CXXFLAGS -Og"
  428. fi
  429. if test x$use_lcov_branch != xno; then
  430. AC_SUBST(LCOV_OPTS, "$LCOV_OPTS --rc lcov_branch_coverage=1")
  431. fi
  432. dnl Check for endianness
  433. AC_C_BIGENDIAN
  434. dnl Check for pthread compile/link requirements
  435. AX_PTHREAD
  436. # The following macro will add the necessary defines to bitcoin-config.h, but
  437. # they also need to be passed down to any subprojects. Pull the results out of
  438. # the cache and add them to CPPFLAGS.
  439. AC_SYS_LARGEFILE
  440. # detect POSIX or GNU variant of strerror_r
  441. AC_FUNC_STRERROR_R
  442. if test x$ac_cv_sys_file_offset_bits != x &&
  443. test x$ac_cv_sys_file_offset_bits != xno &&
  444. test x$ac_cv_sys_file_offset_bits != xunknown; then
  445. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  446. fi
  447. if test x$ac_cv_sys_large_files != x &&
  448. test x$ac_cv_sys_large_files != xno &&
  449. test x$ac_cv_sys_large_files != xunknown; then
  450. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  451. fi
  452. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  453. AX_GCC_FUNC_ATTRIBUTE([visibility])
  454. AX_GCC_FUNC_ATTRIBUTE([dllexport])
  455. AX_GCC_FUNC_ATTRIBUTE([dllimport])
  456. if test x$use_glibc_compat != xno; then
  457. #glibc absorbed clock_gettime in 2.17. librt (its previous location) is safe to link
  458. #in anyway for back-compat.
  459. AC_CHECK_LIB([rt],[clock_gettime],, AC_MSG_ERROR(lib missing))
  460. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  461. # See which one is present here.
  462. AC_MSG_CHECKING(__fdelt_chk type)
  463. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  464. #undef _FORTIFY_SOURCE
  465. #endif
  466. #define _FORTIFY_SOURCE 2
  467. #include <sys/select.h>
  468. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  469. [ fdelt_type="long unsigned int"],
  470. [ fdelt_type="long int"])
  471. AC_MSG_RESULT($fdelt_type)
  472. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  473. else
  474. AC_SEARCH_LIBS([clock_gettime],[rt])
  475. fi
  476. if test x$TARGET_OS != xwindows; then
  477. # All windows code is PIC, forcing it on just adds useless compile warnings
  478. AX_CHECK_COMPILE_FLAG([-fPIC],[PIC_FLAGS="-fPIC"])
  479. fi
  480. if test x$use_hardening != xno; then
  481. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  482. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  483. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  484. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  485. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  486. ])
  487. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  488. ])
  489. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  490. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  491. AX_CHECK_LINK_FLAG([[-Wl,--high-entropy-va]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--high-entropy-va"])
  492. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  493. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  494. if test x$TARGET_OS != xwindows; then
  495. AX_CHECK_COMPILE_FLAG([-fPIE],[PIE_FLAGS="-fPIE"])
  496. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  497. fi
  498. case $host in
  499. *mingw*)
  500. AC_CHECK_LIB([ssp], [main],, AC_MSG_ERROR(lib missing))
  501. ;;
  502. esac
  503. fi
  504. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  505. if test x$TARGET_OS = xdarwin; then
  506. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  507. fi
  508. AC_CHECK_HEADERS([endian.h sys/endian.h byteswap.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  509. AC_CHECK_DECLS([strnlen])
  510. # Check for daemon(3), unrelated to --with-daemon (although used by it)
  511. AC_CHECK_DECLS([daemon])
  512. AC_CHECK_DECLS([le16toh, le32toh, le64toh, htole16, htole32, htole64, be16toh, be32toh, be64toh, htobe16, htobe32, htobe64],,,
  513. [#if HAVE_ENDIAN_H
  514. #include <endian.h>
  515. #elif HAVE_SYS_ENDIAN_H
  516. #include <sys/endian.h>
  517. #endif])
  518. AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64],,,
  519. [#if HAVE_BYTESWAP_H
  520. #include <byteswap.h>
  521. #endif])
  522. AC_CHECK_DECLS([__builtin_clz, __builtin_clzl, __builtin_clzll])
  523. dnl Check for MSG_NOSIGNAL
  524. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  525. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  526. [[ int f = MSG_NOSIGNAL; ]])],
  527. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  528. [ AC_MSG_RESULT(no)]
  529. )
  530. dnl Check for MSG_DONTWAIT
  531. AC_MSG_CHECKING(for MSG_DONTWAIT)
  532. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  533. [[ int f = MSG_DONTWAIT; ]])],
  534. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_DONTWAIT, 1,[Define this symbol if you have MSG_DONTWAIT]) ],
  535. [ AC_MSG_RESULT(no)]
  536. )
  537. dnl Check for malloc_info (for memory statistics information in getmemoryinfo)
  538. AC_MSG_CHECKING(for getmemoryinfo)
  539. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  540. [[ int f = malloc_info(0, NULL); ]])],
  541. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MALLOC_INFO, 1,[Define this symbol if you have malloc_info]) ],
  542. [ AC_MSG_RESULT(no)]
  543. )
  544. dnl Check for mallopt(M_ARENA_MAX) (to set glibc arenas)
  545. AC_MSG_CHECKING(for mallopt M_ARENA_MAX)
  546. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  547. [[ mallopt(M_ARENA_MAX, 1); ]])],
  548. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MALLOPT_ARENA_MAX, 1,[Define this symbol if you have mallopt with M_ARENA_MAX]) ],
  549. [ AC_MSG_RESULT(no)]
  550. )
  551. AC_MSG_CHECKING([for visibility attribute])
  552. AC_LINK_IFELSE([AC_LANG_SOURCE([
  553. int foo_def( void ) __attribute__((visibility("default")));
  554. int main(){}
  555. ])],
  556. [
  557. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  558. AC_MSG_RESULT(yes)
  559. ],
  560. [
  561. AC_MSG_RESULT(no)
  562. if test x$use_reduce_exports = xyes; then
  563. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduce-exports.])
  564. fi
  565. ]
  566. )
  567. # Check for different ways of gathering OS randomness
  568. AC_MSG_CHECKING(for Linux getrandom syscall)
  569. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
  570. #include <sys/syscall.h>
  571. #include <linux/random.h>]],
  572. [[ syscall(SYS_getrandom, nullptr, 32, 0); ]])],
  573. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SYS_GETRANDOM, 1,[Define this symbol if the Linux getrandom system call is available]) ],
  574. [ AC_MSG_RESULT(no)]
  575. )
  576. AC_MSG_CHECKING(for getentropy)
  577. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>]],
  578. [[ getentropy(nullptr, 32) ]])],
  579. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_GETENTROPY, 1,[Define this symbol if the BSD getentropy system call is available]) ],
  580. [ AC_MSG_RESULT(no)]
  581. )
  582. AC_MSG_CHECKING(for sysctl KERN_ARND)
  583. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
  584. #include <sys/sysctl.h>]],
  585. [[ static const int name[2] = {CTL_KERN, KERN_ARND};
  586. sysctl(name, 2, nullptr, nullptr, nullptr, 0); ]])],
  587. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SYSCTL_ARND, 1,[Define this symbol if the BSD sysctl(KERN_ARND) is available]) ],
  588. [ AC_MSG_RESULT(no)]
  589. )
  590. # Check for reduced exports
  591. if test x$use_reduce_exports = xyes; then
  592. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  593. [AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduce-exports.])])
  594. fi
  595. LEVELDB_CPPFLAGS=
  596. LIBLEVELDB=
  597. LIBMEMENV=
  598. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  599. AC_SUBST(LEVELDB_CPPFLAGS)
  600. AC_SUBST(LIBLEVELDB)
  601. AC_SUBST(LIBMEMENV)
  602. if test x$enable_wallet != xno; then
  603. dnl Check for libdb_cxx only if wallet enabled
  604. BITCOIN_FIND_BDB48
  605. fi
  606. dnl Check for libminiupnpc (optional)
  607. if test x$use_upnp != xno; then
  608. AC_CHECK_HEADERS(
  609. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  610. [AC_CHECK_LIB([miniupnpc], [main],[MINIUPNPC_LIBS=-lminiupnpc], [have_miniupnpc=no])],
  611. [have_miniupnpc=no]
  612. )
  613. fi
  614. BITCOIN_QT_INIT
  615. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  616. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt5])
  617. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  618. use_boost=no
  619. else
  620. use_boost=yes
  621. fi
  622. if test x$use_boost = xyes; then
  623. dnl Minimum required Boost version
  624. define(MINIMUM_REQUIRED_BOOST, 1.47.0)
  625. dnl Check for boost libs
  626. AX_BOOST_BASE([MINIMUM_REQUIRED_BOOST])
  627. AX_BOOST_SYSTEM
  628. AX_BOOST_FILESYSTEM
  629. AX_BOOST_PROGRAM_OPTIONS
  630. AX_BOOST_THREAD
  631. AX_BOOST_CHRONO
  632. dnl Boost 1.56 through 1.62 allow using std::atomic instead of its own atomic
  633. dnl counter implementations. In 1.63 and later the std::atomic approach is default.
  634. m4_pattern_allow(DBOOST_AC_USE_STD_ATOMIC) dnl otherwise it's treated like a macro
  635. BOOST_CPPFLAGS="-DBOOST_SP_USE_STD_ATOMIC -DBOOST_AC_USE_STD_ATOMIC $BOOST_CPPFLAGS"
  636. if test x$use_reduce_exports = xyes; then
  637. AC_MSG_CHECKING([for working boost reduced exports])
  638. TEMP_CPPFLAGS="$CPPFLAGS"
  639. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  640. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  641. @%:@include <boost/version.hpp>
  642. ]], [[
  643. #if BOOST_VERSION >= 104900
  644. // Everything is okay
  645. #else
  646. # error Boost version is too old
  647. #endif
  648. ]])],[
  649. AC_MSG_RESULT(yes)
  650. ],[
  651. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduce-exports.])
  652. ])
  653. CPPFLAGS="$TEMP_CPPFLAGS"
  654. fi
  655. fi
  656. if test x$use_reduce_exports = xyes; then
  657. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  658. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  659. fi
  660. if test x$use_tests = xyes; then
  661. if test x$HEXDUMP = x; then
  662. AC_MSG_ERROR(hexdump is required for tests)
  663. fi
  664. if test x$use_boost = xyes; then
  665. AX_BOOST_UNIT_TEST_FRAMEWORK
  666. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  667. AC_MSG_CHECKING([for dynamic linked boost test])
  668. TEMP_LIBS="$LIBS"
  669. LIBS="$LIBS $BOOST_LDFLAGS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  670. TEMP_CPPFLAGS="$CPPFLAGS"
  671. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  672. AC_LINK_IFELSE([AC_LANG_SOURCE([
  673. #define BOOST_TEST_DYN_LINK
  674. #define BOOST_TEST_MAIN
  675. #include <boost/test/unit_test.hpp>
  676. ])],
  677. [AC_MSG_RESULT(yes)]
  678. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  679. [AC_MSG_RESULT(no)])
  680. LIBS="$TEMP_LIBS"
  681. CPPFLAGS="$TEMP_CPPFLAGS"
  682. fi
  683. fi
  684. if test x$use_boost = xyes; then
  685. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB $BOOST_CHRONO_LIB"
  686. dnl If boost (prior to 1.57) was built without c++11, it emulated scoped enums
  687. dnl using c++98 constructs. Unfortunately, this implementation detail leaked into
  688. dnl the abi. This was fixed in 1.57.
  689. dnl When building against that installed version using c++11, the headers pick up
  690. dnl on the native c++11 scoped enum support and enable it, however it will fail to
  691. dnl link. This can be worked around by disabling c++11 scoped enums if linking will
  692. dnl fail.
  693. dnl BOOST_NO_SCOPED_ENUMS was changed to BOOST_NO_CXX11_SCOPED_ENUMS in 1.51.
  694. TEMP_LIBS="$LIBS"
  695. LIBS="$BOOST_LIBS $LIBS"
  696. TEMP_CPPFLAGS="$CPPFLAGS"
  697. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  698. AC_MSG_CHECKING([for mismatched boost c++11 scoped enums])
  699. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  700. #include "boost/config.hpp"
  701. #include "boost/version.hpp"
  702. #if !defined(BOOST_NO_SCOPED_ENUMS) && !defined(BOOST_NO_CXX11_SCOPED_ENUMS) && BOOST_VERSION < 105700
  703. #define BOOST_NO_SCOPED_ENUMS
  704. #define BOOST_NO_CXX11_SCOPED_ENUMS
  705. #define CHECK
  706. #endif
  707. #include "boost/filesystem.hpp"
  708. ]],[[
  709. #if defined(CHECK)
  710. boost::filesystem::copy_file("foo", "bar");
  711. #else
  712. choke;
  713. #endif
  714. ]])],
  715. [AC_MSG_RESULT(mismatched); BOOST_CPPFLAGS="$BOOST_CPPFLAGS -DBOOST_NO_SCOPED_ENUMS -DBOOST_NO_CXX11_SCOPED_ENUMS"], [AC_MSG_RESULT(ok)])
  716. LIBS="$TEMP_LIBS"
  717. CPPFLAGS="$TEMP_CPPFLAGS"
  718. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  719. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  720. dnl a working version is available, else fall back to sleep. sleep was removed
  721. dnl after 1.56.
  722. dnl If neither is available, abort.
  723. TEMP_LIBS="$LIBS"
  724. LIBS="$BOOST_LIBS $LIBS"
  725. TEMP_CPPFLAGS="$CPPFLAGS"
  726. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  727. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  728. #include <boost/thread/thread.hpp>
  729. #include <boost/version.hpp>
  730. ]],[[
  731. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  732. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  733. #else
  734. choke me
  735. #endif
  736. ]])],
  737. [boost_sleep=yes;
  738. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  739. [boost_sleep=no])
  740. LIBS="$TEMP_LIBS"
  741. CPPFLAGS="$TEMP_CPPFLAGS"
  742. if test x$boost_sleep != xyes; then
  743. TEMP_LIBS="$LIBS"
  744. LIBS="$BOOST_LIBS $LIBS"
  745. TEMP_CPPFLAGS="$CPPFLAGS"
  746. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  747. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  748. #include <boost/version.hpp>
  749. #include <boost/thread.hpp>
  750. #include <boost/date_time/posix_time/posix_time_types.hpp>
  751. ]],[[
  752. #if BOOST_VERSION <= 105600
  753. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  754. #else
  755. choke me
  756. #endif
  757. ]])],
  758. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  759. [boost_sleep=no])
  760. LIBS="$TEMP_LIBS"
  761. CPPFLAGS="$TEMP_CPPFLAGS"
  762. fi
  763. if test x$boost_sleep != xyes; then
  764. AC_MSG_ERROR(No working boost sleep implementation found.)
  765. fi
  766. fi
  767. if test x$use_pkgconfig = xyes; then
  768. : dnl
  769. m4_ifdef(
  770. [PKG_CHECK_MODULES],
  771. [
  772. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  773. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  774. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  775. if test x$use_qr != xno; then
  776. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  777. fi
  778. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  779. PKG_CHECK_MODULES([EVENT], [libevent],, [AC_MSG_ERROR(libevent not found.)])
  780. if test x$TARGET_OS != xwindows; then
  781. PKG_CHECK_MODULES([EVENT_PTHREADS], [libevent_pthreads],, [AC_MSG_ERROR(libevent_pthreads not found.)])
  782. fi
  783. fi
  784. if test "x$use_zmq" = "xyes"; then
  785. PKG_CHECK_MODULES([ZMQ],[libzmq >= 4],
  786. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  787. [AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  788. AC_MSG_WARN([libzmq version 4.x or greater not found, disabling])
  789. use_zmq=no])
  790. else
  791. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  792. fi
  793. ]
  794. )
  795. else
  796. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  797. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  798. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  799. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  800. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  801. AC_CHECK_HEADER([event2/event.h],, AC_MSG_ERROR(libevent headers missing),)
  802. AC_CHECK_LIB([event],[main],EVENT_LIBS=-levent,AC_MSG_ERROR(libevent missing))
  803. if test x$TARGET_OS != xwindows; then
  804. AC_CHECK_LIB([event_pthreads],[main],EVENT_PTHREADS_LIBS=-levent_pthreads,AC_MSG_ERROR(libevent_pthreads missing))
  805. fi
  806. fi
  807. if test "x$use_zmq" = "xyes"; then
  808. AC_CHECK_HEADER([zmq.h],
  809. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  810. [AC_MSG_WARN([zmq.h not found, disabling zmq support])
  811. use_zmq=no
  812. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  813. AC_CHECK_LIB([zmq],[zmq_ctx_shutdown],ZMQ_LIBS=-lzmq,
  814. [AC_MSG_WARN([libzmq >= 4.0 not found, disabling zmq support])
  815. use_zmq=no
  816. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  817. else
  818. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  819. fi
  820. if test "x$use_zmq" = "xyes"; then
  821. dnl Assume libzmq was built for static linking
  822. case $host in
  823. *mingw*)
  824. ZMQ_CFLAGS="$ZMQ_CFLAGS -DZMQ_STATIC"
  825. ;;
  826. esac
  827. fi
  828. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],[PROTOBUF_LIBS=-lprotobuf], BITCOIN_QT_FAIL(libprotobuf not found)))
  829. if test x$use_qr != xno; then
  830. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],[QR_LIBS=-lqrencode], [have_qrencode=no])])
  831. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  832. fi
  833. fi
  834. save_CXXFLAGS="${CXXFLAGS}"
  835. CXXFLAGS="${CXXFLAGS} ${CRYPTO_CFLAGS} ${SSL_CFLAGS}"
  836. AC_CHECK_DECLS([EVP_MD_CTX_new],,,[AC_INCLUDES_DEFAULT
  837. #include <openssl/x509_vfy.h>
  838. ])
  839. CXXFLAGS="${save_CXXFLAGS}"
  840. dnl univalue check
  841. need_bundled_univalue=yes
  842. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  843. need_bundled_univalue=no
  844. else
  845. if test x$system_univalue != xno ; then
  846. found_univalue=no
  847. if test x$use_pkgconfig = xyes; then
  848. : #NOP
  849. m4_ifdef(
  850. [PKG_CHECK_MODULES],
  851. [
  852. PKG_CHECK_MODULES([UNIVALUE],[libunivalue],[found_univalue=yes],[true])
  853. ]
  854. )
  855. else
  856. AC_CHECK_HEADER([univalue.h],[
  857. AC_CHECK_LIB([univalue], [main],[
  858. UNIVALUE_LIBS=-lunivalue
  859. found_univalue=yes
  860. ],[true])
  861. ],[true])
  862. fi
  863. if test x$found_univalue = xyes ; then
  864. system_univalue=yes
  865. need_bundled_univalue=no
  866. elif test x$system_univalue = xyes ; then
  867. AC_MSG_ERROR([univalue not found])
  868. else
  869. system_univalue=no
  870. fi
  871. fi
  872. if test x$need_bundled_univalue = xyes ; then
  873. UNIVALUE_CFLAGS='-I$(srcdir)/univalue/include'
  874. UNIVALUE_LIBS='univalue/libunivalue.la'
  875. fi
  876. fi
  877. AM_CONDITIONAL([EMBEDDED_UNIVALUE],[test x$need_bundled_univalue = xyes])
  878. AC_SUBST(UNIVALUE_CFLAGS)
  879. AC_SUBST(UNIVALUE_LIBS)
  880. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  881. AC_MSG_CHECKING([whether to build bitcoind])
  882. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  883. AC_MSG_RESULT($build_bitcoind)
  884. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  885. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  886. AC_MSG_RESULT($build_bitcoin_utils)
  887. AC_MSG_CHECKING([whether to build libraries])
  888. AM_CONDITIONAL([BUILD_BITCOIN_LIBS], [test x$build_bitcoin_libs = xyes])
  889. if test x$build_bitcoin_libs = xyes; then
  890. AC_DEFINE(HAVE_CONSENSUS_LIB, 1, [Define this symbol if the consensus lib has been built])
  891. AC_CONFIG_FILES([libbitcoinconsensus.pc:libbitcoinconsensus.pc.in])
  892. fi
  893. AC_MSG_RESULT($build_bitcoin_libs)
  894. AC_LANG_POP
  895. if test "x$use_ccache" != "xno"; then
  896. AC_MSG_CHECKING(if ccache should be used)
  897. if test x$CCACHE = x; then
  898. if test "x$use_ccache" = "xyes"; then
  899. AC_MSG_ERROR([ccache not found.]);
  900. else
  901. use_ccache=no
  902. fi
  903. else
  904. use_ccache=yes
  905. CC="$ac_cv_path_CCACHE $CC"
  906. CXX="$ac_cv_path_CCACHE $CXX"
  907. fi
  908. AC_MSG_RESULT($use_ccache)
  909. fi
  910. if test "x$use_ccache" = "xyes"; then
  911. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  912. fi
  913. dnl enable wallet
  914. AC_MSG_CHECKING([if wallet should be enabled])
  915. if test x$enable_wallet != xno; then
  916. AC_MSG_RESULT(yes)
  917. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  918. else
  919. AC_MSG_RESULT(no)
  920. fi
  921. dnl enable upnp support
  922. AC_MSG_CHECKING([whether to build with support for UPnP])
  923. if test x$have_miniupnpc = xno; then
  924. if test x$use_upnp = xyes; then
  925. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  926. fi
  927. AC_MSG_RESULT(no)
  928. else
  929. if test x$use_upnp != xno; then
  930. AC_MSG_RESULT(yes)
  931. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  932. use_upnp=yes
  933. upnp_setting=0
  934. if test x$use_upnp_default != xno; then
  935. use_upnp_default=yes
  936. upnp_setting=1
  937. fi
  938. AC_MSG_RESULT($use_upnp_default)
  939. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  940. if test x$TARGET_OS = xwindows; then
  941. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  942. fi
  943. else
  944. AC_MSG_RESULT(no)
  945. fi
  946. fi
  947. dnl these are only used when qt is enabled
  948. BUILD_TEST_QT=""
  949. if test x$bitcoin_enable_qt != xno; then
  950. dnl enable dbus support
  951. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  952. if test x$bitcoin_enable_qt_dbus != xno; then
  953. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  954. fi
  955. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  956. dnl enable qr support
  957. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  958. if test x$have_qrencode = xno; then
  959. if test x$use_qr = xyes; then
  960. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  961. fi
  962. AC_MSG_RESULT(no)
  963. else
  964. if test x$use_qr != xno; then
  965. AC_MSG_RESULT(yes)
  966. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  967. use_qr=yes
  968. else
  969. AC_MSG_RESULT(no)
  970. fi
  971. fi
  972. if test x$XGETTEXT = x; then
  973. AC_MSG_WARN("xgettext is required to update qt translations")
  974. fi
  975. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  976. if test x$use_gui_tests$bitcoin_enable_qt_test = xyesyes; then
  977. AC_MSG_RESULT([yes])
  978. BUILD_TEST_QT="yes"
  979. else
  980. AC_MSG_RESULT([no])
  981. fi
  982. fi
  983. AM_CONDITIONAL([ENABLE_ZMQ], [test "x$use_zmq" = "xyes"])
  984. AC_MSG_CHECKING([whether to build test_bitcoin])
  985. if test x$use_tests = xyes; then
  986. AC_MSG_RESULT([yes])
  987. BUILD_TEST="yes"
  988. else
  989. AC_MSG_RESULT([no])
  990. BUILD_TEST=""
  991. fi
  992. AC_MSG_CHECKING([whether to reduce exports])
  993. if test x$use_reduce_exports = xyes; then
  994. AC_MSG_RESULT([yes])
  995. else
  996. AC_MSG_RESULT([no])
  997. fi
  998. if test x$build_bitcoin_utils$build_bitcoin_libs$build_bitcoind$bitcoin_enable_qt$use_bench$use_tests = xnononononono; then
  999. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-libs --with-daemon --with-gui --enable-bench or --enable-tests])
  1000. fi
  1001. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  1002. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  1003. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  1004. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  1005. AM_CONDITIONAL([ENABLE_TESTS],[test x$BUILD_TEST = xyes])
  1006. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  1007. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$BUILD_TEST_QT = xyes])
  1008. AM_CONDITIONAL([ENABLE_BENCH],[test x$use_bench = xyes])
  1009. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  1010. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  1011. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  1012. AM_CONDITIONAL([HARDEN],[test x$use_hardening = xyes])
  1013. AM_CONDITIONAL([ENABLE_HWCRC32],[test x$enable_hwcrc32 = xyes])
  1014. AM_CONDITIONAL([EXPERIMENTAL_ASM],[test x$experimental_asm = xyes])
  1015. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  1016. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  1017. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  1018. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  1019. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  1020. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Copyright year])
  1021. AC_DEFINE(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS", [Copyright holder(s) before %s replacement])
  1022. AC_DEFINE(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION", [Replacement for %s in copyright holders string])
  1023. define(_COPYRIGHT_HOLDERS_FINAL, [patsubst(_COPYRIGHT_HOLDERS, [%s], [_COPYRIGHT_HOLDERS_SUBSTITUTION])])
  1024. AC_DEFINE(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL", [Copyright holder(s)])
  1025. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  1026. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  1027. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  1028. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  1029. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  1030. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  1031. AC_SUBST(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS")
  1032. AC_SUBST(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION")
  1033. AC_SUBST(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL")
  1034. AC_SUBST(BITCOIN_DAEMON_NAME)
  1035. AC_SUBST(BITCOIN_GUI_NAME)
  1036. AC_SUBST(BITCOIN_CLI_NAME)
  1037. AC_SUBST(BITCOIN_TX_NAME)
  1038. AC_SUBST(RELDFLAGS)
  1039. AC_SUBST(ERROR_CXXFLAGS)
  1040. AC_SUBST(HARDENED_CXXFLAGS)
  1041. AC_SUBST(HARDENED_CPPFLAGS)
  1042. AC_SUBST(HARDENED_LDFLAGS)
  1043. AC_SUBST(PIC_FLAGS)
  1044. AC_SUBST(PIE_FLAGS)
  1045. AC_SUBST(SSE42_CXXFLAGS)
  1046. AC_SUBST(LIBTOOL_APP_LDFLAGS)
  1047. AC_SUBST(USE_UPNP)
  1048. AC_SUBST(USE_QRCODE)
  1049. AC_SUBST(BOOST_LIBS)
  1050. AC_SUBST(TESTDEFS)
  1051. AC_SUBST(LEVELDB_TARGET_FLAGS)
  1052. AC_SUBST(MINIUPNPC_CPPFLAGS)
  1053. AC_SUBST(MINIUPNPC_LIBS)
  1054. AC_SUBST(CRYPTO_LIBS)
  1055. AC_SUBST(SSL_LIBS)
  1056. AC_SUBST(EVENT_LIBS)
  1057. AC_SUBST(EVENT_PTHREADS_LIBS)
  1058. AC_SUBST(ZMQ_LIBS)
  1059. AC_SUBST(PROTOBUF_LIBS)
  1060. AC_SUBST(QR_LIBS)
  1061. AC_CONFIG_FILES([Makefile src/Makefile doc/man/Makefile share/setup.nsi share/qt/Info.plist test/config.ini])
  1062. AC_CONFIG_FILES([contrib/devtools/split-debug.sh],[chmod +x contrib/devtools/split-debug.sh])
  1063. AC_CONFIG_FILES([doc/Doxyfile])
  1064. AC_CONFIG_LINKS([test/functional/test_runner.py:test/functional/test_runner.py])
  1065. AC_CONFIG_LINKS([test/util/bitcoin-util-test.py:test/util/bitcoin-util-test.py])
  1066. dnl boost's m4 checks do something really nasty: they export these vars. As a
  1067. dnl result, they leak into secp256k1's configure and crazy things happen.
  1068. dnl Until this is fixed upstream and we've synced, we'll just un-export them.
  1069. CPPFLAGS_TEMP="$CPPFLAGS"
  1070. unset CPPFLAGS
  1071. CPPFLAGS="$CPPFLAGS_TEMP"
  1072. LDFLAGS_TEMP="$LDFLAGS"
  1073. unset LDFLAGS
  1074. LDFLAGS="$LDFLAGS_TEMP"
  1075. LIBS_TEMP="$LIBS"
  1076. unset LIBS
  1077. LIBS="$LIBS_TEMP"
  1078. PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
  1079. unset PKG_CONFIG_PATH
  1080. PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
  1081. PKGCONFIG_LIBDIR_TEMP="$PKG_CONFIG_LIBDIR"
  1082. unset PKG_CONFIG_LIBDIR
  1083. PKG_CONFIG_LIBDIR="$PKGCONFIG_LIBDIR_TEMP"
  1084. if test x$need_bundled_univalue = xyes; then
  1085. AC_CONFIG_SUBDIRS([src/univalue])
  1086. fi
  1087. ac_configure_args="${ac_configure_args} --disable-shared --with-pic --with-bignum=no --enable-module-recovery"
  1088. AC_CONFIG_SUBDIRS([src/secp256k1])
  1089. AC_OUTPUT
  1090. dnl Taken from https://wiki.debian.org/RpathIssue
  1091. case $host in
  1092. *-*-linux-gnu)
  1093. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  1094. sed < libtool > libtool-2 \
  1095. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  1096. mv libtool-2 libtool
  1097. chmod 755 libtool
  1098. ;;
  1099. esac
  1100. dnl Replace the BUILDDIR path with the correct Windows path if compiling on Native Windows
  1101. case ${OS} in
  1102. *Windows*)
  1103. sed 's/BUILDDIR="\/\([[a-z]]\)/BUILDDIR="\1:/' test/config.ini > test/config-2.ini
  1104. mv test/config-2.ini test/config.ini
  1105. ;;
  1106. esac
  1107. echo
  1108. echo "Options used to compile and link:"
  1109. echo " with wallet = $enable_wallet"
  1110. echo " with gui / qt = $bitcoin_enable_qt"
  1111. if test x$bitcoin_enable_qt != xno; then
  1112. echo " qt version = $bitcoin_qt_got_major_vers"
  1113. echo " with qr = $use_qr"
  1114. fi
  1115. echo " with zmq = $use_zmq"
  1116. echo " with test = $use_tests"
  1117. echo " with bench = $use_bench"
  1118. echo " with upnp = $use_upnp"
  1119. echo " debug enabled = $enable_debug"
  1120. echo " werror = $enable_werror"
  1121. echo
  1122. echo " target os = $TARGET_OS"
  1123. echo " build os = $BUILD_OS"
  1124. echo
  1125. echo " CC = $CC"
  1126. echo " CFLAGS = $CFLAGS"
  1127. echo " CPPFLAGS = $CPPFLAGS"
  1128. echo " CXX = $CXX"
  1129. echo " CXXFLAGS = $CXXFLAGS"
  1130. echo " LDFLAGS = $LDFLAGS"
  1131. echo " ARFLAGS = $ARFLAGS"
  1132. echo