You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 28KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 9)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2014)
  9. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[info@bitcoin.org],[bitcoin])
  10. AC_CONFIG_SRCDIR([src/main.cpp])
  11. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  12. AC_CONFIG_AUX_DIR([build-aux])
  13. AC_CONFIG_MACRO_DIR([build-aux/m4])
  14. LT_INIT([disable-shared])
  15. AC_CANONICAL_HOST
  16. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  17. AH_TOP([#define BITCOIN_CONFIG_H])
  18. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  19. # This m4 will only be used if a system copy cannot be found. This is helpful
  20. # on systems where autotools are installed but the pkg-config macros are not in
  21. # a default location. It is currently used for building on OSX where autotools
  22. # are preinstalled but pkg-config comes from macports or homebrew. It should
  23. # probably be removed when building on <= 10.6 is no longer supported.
  24. m4_include([pkg.m4])
  25. dnl faketime breaks configure and is only needed for make. Disable it here.
  26. unset FAKETIME
  27. if test "x${CXXFLAGS+set}" = "xset"; then
  28. CXXFLAGS_overridden=yes
  29. else
  30. CXXFLAGS_overridden=no
  31. fi
  32. dnl ==============================================================
  33. dnl Setup for automake
  34. dnl ==============================================================
  35. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  36. dnl faketime messes with timestamps and causes configure to be re-run.
  37. dnl --disable-maintainer-mode can be used to bypass this.
  38. AM_MAINTAINER_MODE([enable])
  39. dnl make the compilation flags quiet unless V=1 is used
  40. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  41. dnl Checks for programs.
  42. AC_PROG_CXX
  43. AC_PROG_CC
  44. AC_PROG_CPP
  45. AC_PROG_CXXCPP
  46. AC_PROG_INSTALL
  47. AC_PROG_OBJC
  48. AC_PROG_LN_S
  49. m4_ifdef([AC_PROG_OBJCXX],[AC_PROG_OBJCXX])
  50. AC_PROG_MKDIR_P
  51. AC_PROG_SED
  52. AC_PATH_TOOL(AR, ar)
  53. AC_PATH_TOOL(RANLIB, ranlib)
  54. AC_PATH_TOOL(STRIP, strip)
  55. AC_PATH_TOOL(GCOV, gcov)
  56. AC_PATH_PROG(LCOV, lcov)
  57. AC_PATH_PROG(JAVA, java)
  58. AC_PATH_PROG(GENHTML, genhtml)
  59. AC_PATH_PROG([GIT], [git])
  60. AC_PATH_PROG(CCACHE,ccache)
  61. AC_PATH_PROG(XGETTEXT,xgettext)
  62. AC_PATH_PROG(HEXDUMP,hexdump)
  63. PKG_PROG_PKG_CONFIG
  64. # Enable wallet
  65. AC_ARG_ENABLE([wallet],
  66. [AS_HELP_STRING([--enable-wallet],
  67. [enable wallet (default is yes)])],
  68. [enable_wallet=$enableval],
  69. [enable_wallet=yes])
  70. AC_ARG_WITH([miniupnpc],
  71. [AS_HELP_STRING([--with-miniupnpc],
  72. [enable UPNP (default is yes if libminiupnpc is found)])],
  73. [use_upnp=$withval],
  74. [use_upnp=auto])
  75. AC_ARG_ENABLE([upnp-default],
  76. [AS_HELP_STRING([--enable-upnp-default],
  77. [if UPNP is enabled, turn it on at startup (default is no)])],
  78. [use_upnp_default=$enableval],
  79. [use_upnp_default=no])
  80. AC_ARG_ENABLE(tests,
  81. AS_HELP_STRING([--enable-tests],[compile tests (default is yes)]),
  82. [use_tests=$enableval],
  83. [use_tests=yes])
  84. AC_ARG_WITH([comparison-tool],
  85. AS_HELP_STRING([--with-comparison-tool],[path to java comparison tool (requires --enable-tests)]),
  86. [use_comparison_tool=$withval],
  87. [use_comparison_tool=no])
  88. AC_ARG_ENABLE([comparison-tool-reorg-tests],
  89. AS_HELP_STRING([--enable-comparison-tool-reorg-tests],[enable expensive reorg tests in the comparison tool (default no)]),
  90. [use_comparison_tool_reorg_tests=$enableval],
  91. [use_comparison_tool_reorg_tests=no])
  92. AC_ARG_WITH([qrencode],
  93. [AS_HELP_STRING([--with-qrencode],
  94. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  95. [use_qr=$withval],
  96. [use_qr=auto])
  97. AC_ARG_ENABLE([hardening],
  98. [AS_HELP_STRING([--enable-hardening],
  99. [attempt to harden the resulting executables (default is yes)])],
  100. [use_hardening=$enableval],
  101. [use_hardening=yes])
  102. AC_ARG_ENABLE([reduce-exports],
  103. [AS_HELP_STRING([--enable-reduce-exports],
  104. [attempt to reduce exported symbols in the resulting executables (default is yes)])],
  105. [use_reduce_exports=$enableval],
  106. [use_reduce_exports=auto])
  107. AC_ARG_ENABLE([ccache],
  108. [AS_HELP_STRING([--enable-ccache],
  109. [use ccache for building (default is yes if ccache is found)])],
  110. [use_ccache=$enableval],
  111. [use_ccache=auto])
  112. AC_ARG_ENABLE([lcov],
  113. [AS_HELP_STRING([--enable-lcov],
  114. [enable lcov testing (default is no)])],
  115. [use_lcov=yes],
  116. [use_lcov=no])
  117. AC_ARG_ENABLE([glibc-back-compat],
  118. [AS_HELP_STRING([--enable-glibc-back-compat],
  119. [enable backwards compatibility with glibc and libstdc++])],
  120. [use_glibc_compat=$enableval],
  121. [use_glibc_compat=no])
  122. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  123. # Enable debug
  124. AC_ARG_ENABLE([debug],
  125. [AS_HELP_STRING([--enable-debug],
  126. [use debug compiler flags and macros (default is no)])],
  127. [enable_debug=$enableval],
  128. [enable_debug=no])
  129. if test "x$enable_debug" = xyes; then
  130. if test "x$GCC" = xyes; then
  131. CFLAGS="-g3 -O0 -DDEBUG"
  132. fi
  133. if test "x$GXX" = xyes; then
  134. CXXFLAGS="-g3 -O0 -DDEBUG"
  135. fi
  136. fi
  137. ## TODO: Remove these hard-coded paths and flags. They are here for the sake of
  138. ## compatibility with the legacy buildsystem.
  139. ##
  140. if test "x$CXXFLAGS_overridden" = "xno"; then
  141. CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter"
  142. fi
  143. CPPFLAGS="$CPPFLAGS -DBOOST_SPIRIT_THREADSAFE -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  144. AC_LANG_PUSH([C++])
  145. use_pkgconfig=yes
  146. case $host in
  147. *mingw*)
  148. #pkgconfig does more harm than good with MinGW
  149. use_pkgconfig=no
  150. TARGET_OS=windows
  151. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  152. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  153. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  154. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  155. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  156. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  157. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  158. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  159. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  160. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  161. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  162. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  163. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  164. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  165. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  166. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  167. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  168. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  169. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  170. AX_CHECK_LINK_FLAG([[-static-libgcc]],[LDFLAGS="$LDFLAGS -static-libgcc"])
  171. AX_CHECK_LINK_FLAG([[-static-libstdc++]],[LDFLAGS="$LDFLAGS -static-libstdc++"])
  172. # -static is interpreted by libtool, where it has a different meaning.
  173. # In libtool-speak, it's -all-static.
  174. AX_CHECK_LINK_FLAG([[-static]],[LDFLAGS="$LDFLAGS -static"; LIBTOOL_LDFLAGS="$LIBTOOL_LDFLAGS -all-static"])
  175. AC_PATH_PROG([MAKENSIS], [makensis], none)
  176. if test x$MAKENSIS = xnone; then
  177. AC_MSG_WARN("makensis not found. Cannot create installer.")
  178. fi
  179. AC_PATH_TOOL(WINDRES, windres, none)
  180. if test x$WINDRES = xnone; then
  181. AC_MSG_ERROR("windres not found")
  182. fi
  183. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  184. LEVELDB_TARGET_FLAGS="TARGET_OS=OS_WINDOWS_CROSSCOMPILE"
  185. if test "x$CXXFLAGS_overridden" = "xno"; then
  186. CXXFLAGS="$CXXFLAGS -w"
  187. fi
  188. case $host in
  189. i?86-*) WINDOWS_BITS=32 ;;
  190. x86_64-*) WINDOWS_BITS=64 ;;
  191. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  192. esac
  193. AC_SUBST(WINDOWS_BITS)
  194. ;;
  195. *darwin*)
  196. TARGET_OS=darwin
  197. LEVELDB_TARGET_FLAGS="TARGET_OS=Darwin"
  198. if test x$cross_compiling != xyes; then
  199. BUILD_OS=darwin
  200. AC_CHECK_PROG([PORT],port, port)
  201. if test x$PORT = xport; then
  202. dnl add default macports paths
  203. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include -I/opt/local/include/db48"
  204. LIBS="$LIBS -L/opt/local/lib -L/opt/local/lib/db48"
  205. fi
  206. AC_CHECK_PROG([BREW],brew, brew)
  207. if test x$BREW = xbrew; then
  208. dnl These Homebrew packages may be bottled, meaning that they won't be found
  209. dnl in expected paths because they may conflict with system files. Ask
  210. dnl Homebrew where each one is located, then adjust paths accordingly.
  211. dnl It's safe to add these paths even if the functionality is disabled by
  212. dnl the user (--without-wallet or --without-gui for example).
  213. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  214. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  215. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  216. if test x$openssl_prefix != x; then
  217. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  218. export PKG_CONFIG_PATH
  219. fi
  220. if test x$bdb_prefix != x; then
  221. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  222. LIBS="$LIBS -L$bdb_prefix/lib"
  223. fi
  224. if test x$qt5_prefix != x; then
  225. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  226. export PKG_CONFIG_PATH
  227. fi
  228. fi
  229. else
  230. case $build_os in
  231. *darwin*)
  232. BUILD_OS=darwin
  233. ;;
  234. *)
  235. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  236. AC_PATH_TOOL([OTOOL], [otool], otool)
  237. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  238. ;;
  239. esac
  240. fi
  241. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  242. ;;
  243. *linux*)
  244. TARGET_OS=linux
  245. ;;
  246. *)
  247. ;;
  248. esac
  249. if test x$use_comparison_tool != xno; then
  250. AC_SUBST(JAVA_COMPARISON_TOOL, $use_comparison_tool)
  251. fi
  252. if test x$use_comparison_tool_reorg_tests != xno; then
  253. if test x$use_comparison_tool = x; then
  254. AC_MSG_ERROR("comparison tool reorg tests but comparison tool was not specified")
  255. fi
  256. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 1)
  257. else
  258. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 0)
  259. fi
  260. if test x$use_lcov = xyes; then
  261. if test x$LCOV = x; then
  262. AC_MSG_ERROR("lcov testing requested but lcov not found")
  263. fi
  264. if test x$GCOV = x; then
  265. AC_MSG_ERROR("lcov testing requested but gcov not found")
  266. fi
  267. if test x$JAVA = x; then
  268. AC_MSG_ERROR("lcov testing requested but java not found")
  269. fi
  270. if test x$GENHTML = x; then
  271. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  272. fi
  273. if test x$use_comparison_tool = x; then
  274. AC_MSG_ERROR("lcov testing requested but comparison tool was not specified")
  275. fi
  276. LCOV="$LCOV --gcov-tool=$GCOV"
  277. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  278. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  279. fi
  280. dnl Require little endian
  281. AC_C_BIGENDIAN([AC_MSG_ERROR("Big Endian not supported")])
  282. dnl Check for pthread compile/link requirements
  283. AX_PTHREAD
  284. # The following macro will add the necessary defines to bitcoin-config.h, but
  285. # they also need to be passed down to any subprojects. Pull the results out of
  286. # the cache and add them to CPPFLAGS.
  287. AC_SYS_LARGEFILE
  288. # detect POSIX or GNU variant of strerror_r
  289. AC_FUNC_STRERROR_R
  290. if test x$ac_cv_sys_file_offset_bits != x &&
  291. test x$ac_cv_sys_file_offset_bits != xno &&
  292. test x$ac_cv_sys_file_offset_bits != xunknown; then
  293. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  294. fi
  295. if test x$ac_cv_sys_large_files != x &&
  296. test x$ac_cv_sys_large_files != xno &&
  297. test x$ac_cv_sys_large_files != xunknown; then
  298. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  299. fi
  300. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  301. if test x$use_glibc_compat != xno; then
  302. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  303. # See which one is present here.
  304. AC_MSG_CHECKING(__fdelt_chk type)
  305. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  306. #undef _FORTIFY_SOURCE
  307. #endif
  308. #define _FORTIFY_SOURCE 2
  309. #include <sys/select.h>
  310. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  311. [ fdelt_type="long unsigned int"],
  312. [ fdelt_type="long int"])
  313. AC_MSG_RESULT($fdelt_type)
  314. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  315. fi
  316. if test x$use_hardening != xno; then
  317. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  318. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  319. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  320. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  321. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  322. ])
  323. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  324. ])
  325. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  326. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  327. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  328. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  329. if test x$TARGET_OS != xwindows; then
  330. # All windows code is PIC, forcing it on just adds useless compile warnings
  331. AX_CHECK_COMPILE_FLAG([-fPIE],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fPIE"])
  332. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  333. fi
  334. CXXFLAGS="$CXXFLAGS $HARDENED_CXXFLAGS"
  335. CPPFLAGS="$CPPFLAGS $HARDENED_CPPFLAGS"
  336. LDFLAGS="$LDFLAGS $HARDENED_LDFLAGS"
  337. OBJCXXFLAGS="$CXXFLAGS"
  338. fi
  339. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  340. if test x$TARGET_OS = xdarwin; then
  341. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  342. fi
  343. AC_CHECK_HEADERS([endian.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  344. AC_SEARCH_LIBS([getaddrinfo_a], [anl], [AC_DEFINE(HAVE_GETADDRINFO_A, 1, [Define this symbol if you have getaddrinfo_a])])
  345. AC_SEARCH_LIBS([inet_pton], [nsl resolv], [AC_DEFINE(HAVE_INET_PTON, 1, [Define this symbol if you have inet_pton])])
  346. AC_CHECK_DECLS([le32toh, le64toh, htole32, htole64, be32toh, be64toh, htobe32, htobe64],,,
  347. [#if HAVE_ENDIAN_H
  348. #include <endian.h>
  349. #endif])
  350. dnl Check for MSG_NOSIGNAL
  351. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  352. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  353. [[ int f = MSG_NOSIGNAL; ]])],
  354. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  355. [ AC_MSG_RESULT(no)]
  356. )
  357. AC_SEARCH_LIBS([clock_gettime],[rt])
  358. AC_MSG_CHECKING([for visibility attribute])
  359. AC_LINK_IFELSE([AC_LANG_SOURCE([
  360. int foo_def( void ) __attribute__((visibility("default")));
  361. int main(){}
  362. ])],
  363. [
  364. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  365. AC_MSG_RESULT(yes)
  366. ],
  367. [
  368. AC_MSG_RESULT(no)
  369. if test x$use_reduce_exports = xyes; then
  370. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduced-exports.])
  371. fi
  372. AC_MSG_WARN([Cannot find a working visibility attribute. Disabling reduced exports.])
  373. use_reduce_exports=no
  374. ]
  375. )
  376. if test x$use_reduce_exports != xno; then
  377. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  378. [
  379. if test x$use_reduce_exports = xyes; then
  380. AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduced-exports.])
  381. fi
  382. AC_MSG_WARN([Cannot set default symbol visibility. Disabling reduced exports.])
  383. use_reduce_exports=no
  384. ])
  385. fi
  386. LEVELDB_CPPFLAGS=
  387. LIBLEVELDB=
  388. LIBMEMENV=
  389. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  390. AC_SUBST(LEVELDB_CPPFLAGS)
  391. AC_SUBST(LIBLEVELDB)
  392. AC_SUBST(LIBMEMENV)
  393. if test x$enable_wallet != xno; then
  394. dnl Check for libdb_cxx only if wallet enabled
  395. BITCOIN_FIND_BDB48
  396. fi
  397. dnl Check for libminiupnpc (optional)
  398. if test x$use_upnp != xno; then
  399. AC_CHECK_HEADERS(
  400. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  401. [AC_CHECK_LIB([miniupnpc], [main],, [have_miniupnpc=no])],
  402. [have_miniupnpc=no]
  403. )
  404. fi
  405. dnl Check for boost libs
  406. AX_BOOST_BASE
  407. AX_BOOST_SYSTEM
  408. AX_BOOST_FILESYSTEM
  409. AX_BOOST_PROGRAM_OPTIONS
  410. AX_BOOST_THREAD
  411. AX_BOOST_CHRONO
  412. if test x$use_reduce_exports != xno; then
  413. AC_MSG_CHECKING([for working boost reduced exports])
  414. TEMP_CPPFLAGS="$CPPFLAGS"
  415. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  416. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  417. @%:@include <boost/version.hpp>
  418. ]], [[
  419. #if BOOST_VERSION >= 104900
  420. // Everything is okay
  421. #else
  422. # error Boost version is too old
  423. #endif
  424. ]])],[
  425. AC_MSG_RESULT(yes)
  426. ],[:
  427. if test x$use_reduce_exports = xauto; then
  428. use_reduce_exports=no
  429. else
  430. if test x$use_reduce_exports = xyes; then
  431. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduced-exports.])
  432. fi
  433. fi
  434. AC_MSG_RESULT(no)
  435. AC_MSG_WARN([boost versions < 1.49 are known to have symbol visibility issues. Disabling reduced exports.])
  436. ])
  437. CPPFLAGS="$TEMP_CPPFLAGS"
  438. fi
  439. if test x$use_reduce_exports != xno; then
  440. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  441. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  442. fi
  443. if test x$use_tests = xyes; then
  444. if test x$HEXDUMP = x; then
  445. AC_MSG_ERROR(hexdump is required for tests)
  446. fi
  447. AX_BOOST_UNIT_TEST_FRAMEWORK
  448. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  449. AC_MSG_CHECKING([for dynamic linked boost test])
  450. TEMP_LIBS="$LIBS"
  451. LIBS="$LIBS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  452. TEMP_CPPFLAGS="$CPPFLAGS"
  453. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  454. AC_LINK_IFELSE([AC_LANG_SOURCE([
  455. #define BOOST_TEST_DYN_LINK
  456. #define BOOST_TEST_MAIN
  457. #include <boost/test/unit_test.hpp>
  458. ])],
  459. [AC_MSG_RESULT(yes)]
  460. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  461. [AC_MSG_RESULT(no)])
  462. LIBS="$TEMP_LIBS"
  463. CPPFLAGS="$TEMP_CPPFLAGS"
  464. fi
  465. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB"
  466. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  467. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  468. dnl a working version is available, else fall back to sleep. sleep was removed
  469. dnl after 1.56.
  470. dnl If neither is available, abort.
  471. dnl If sleep_for is used, boost_chrono becomes a requirement.
  472. if test x$ax_cv_boost_chrono = xyes; then
  473. TEMP_LIBS="$LIBS"
  474. LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB $LIBS"
  475. TEMP_CPPFLAGS="$CPPFLAGS"
  476. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  477. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  478. #include <boost/thread/thread.hpp>
  479. #include <boost/version.hpp>
  480. ]],[[
  481. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  482. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  483. #else
  484. choke me
  485. #endif
  486. ]])],
  487. [boost_sleep=yes; BOOST_LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB";
  488. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  489. [boost_sleep=no])
  490. LIBS="$TEMP_LIBS"
  491. CPPFLAGS="$TEMP_CPPFLAGS"
  492. fi
  493. if test x$boost_sleep != xyes; then
  494. TEMP_LIBS="$LIBS"
  495. LIBS="$BOOST_LIBS $LIBS"
  496. TEMP_CPPFLAGS="$CPPFLAGS"
  497. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  498. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  499. #include <boost/version.hpp>
  500. #include <boost/thread.hpp>
  501. #include <boost/date_time/posix_time/posix_time_types.hpp>
  502. ]],[[
  503. #if BOOST_VERSION <= 105600
  504. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  505. #else
  506. choke me
  507. #endif
  508. ]])],
  509. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  510. [boost_sleep=no])
  511. LIBS="$TEMP_LIBS"
  512. CPPFLAGS="$TEMP_CPPFLAGS"
  513. fi
  514. if test x$boost_sleep != xyes; then
  515. AC_MSG_ERROR(No working boost sleep implementation found.)
  516. fi
  517. AC_ARG_WITH([utils],
  518. [AS_HELP_STRING([--with-utils],
  519. [build bitcoin-cli bitcoin-tx (default=yes)])],
  520. [build_bitcoin_utils=$withval],
  521. [build_bitcoin_utils=yes])
  522. AC_ARG_WITH([daemon],
  523. [AS_HELP_STRING([--with-daemon],
  524. [build bitcoind daemon (default=yes)])],
  525. [build_bitcoind=$withval],
  526. [build_bitcoind=yes])
  527. BITCOIN_QT_INIT
  528. if test x$use_pkgconfig = xyes; then
  529. if test x"$PKG_CONFIG" = "x"; then
  530. AC_MSG_ERROR(pkg-config not found.)
  531. fi
  532. : #NOP
  533. m4_ifdef(
  534. [PKG_CHECK_MODULES],
  535. [
  536. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  537. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  538. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  539. if test x$use_qr != xno; then
  540. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  541. fi
  542. ]
  543. )
  544. else
  545. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  546. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  547. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  548. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  549. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],,BITCOIN_QT_FAIL(libprotobuf not found)))
  550. if test x$use_qr != xno; then
  551. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],, [have_qrencode=no])])
  552. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  553. fi
  554. fi
  555. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  556. AC_MSG_CHECKING([whether to build bitcoind])
  557. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  558. AC_MSG_RESULT($build_bitcoind)
  559. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  560. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  561. AC_MSG_RESULT($build_bitcoin_utils)
  562. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  563. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt4])
  564. AC_LANG_POP
  565. if test "x$use_ccache" != "xno"; then
  566. AC_MSG_CHECKING(if ccache should be used)
  567. if test x$CCACHE = x; then
  568. if test "x$use_ccache" = "xyes"; then
  569. AC_MSG_ERROR([ccache not found.]);
  570. else
  571. use_ccache=no
  572. fi
  573. else
  574. use_ccache=yes
  575. CC="$ac_cv_path_CCACHE $CC"
  576. CXX="$ac_cv_path_CCACHE $CXX"
  577. fi
  578. AC_MSG_RESULT($use_ccache)
  579. fi
  580. if test "x$use_ccache" = "xyes"; then
  581. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  582. fi
  583. dnl enable wallet
  584. AC_MSG_CHECKING([if wallet should be enabled])
  585. if test x$enable_wallet != xno; then
  586. AC_MSG_RESULT(yes)
  587. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  588. else
  589. AC_MSG_RESULT(no)
  590. fi
  591. dnl enable upnp support
  592. AC_MSG_CHECKING([whether to build with support for UPnP])
  593. if test x$have_miniupnpc = xno; then
  594. if test x$use_upnp = xyes; then
  595. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  596. fi
  597. AC_MSG_RESULT(no)
  598. else
  599. if test x$use_upnp != xno; then
  600. AC_MSG_RESULT(yes)
  601. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  602. use_upnp=yes
  603. upnp_setting=0
  604. if test x$use_upnp_default != xno; then
  605. use_upnp_default=yes
  606. upnp_setting=1
  607. fi
  608. AC_MSG_RESULT($use_upnp_default)
  609. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  610. if test x$TARGET_OS = xwindows; then
  611. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  612. fi
  613. else
  614. AC_MSG_RESULT(no)
  615. fi
  616. fi
  617. dnl these are only used when qt is enabled
  618. if test x$bitcoin_enable_qt != xno; then
  619. BUILD_QT=qt
  620. dnl enable dbus support
  621. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  622. if test x$bitcoin_enable_qt_dbus != xno; then
  623. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  624. fi
  625. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  626. dnl enable qr support
  627. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  628. if test x$have_qrencode = xno; then
  629. if test x$use_qr = xyes; then
  630. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  631. fi
  632. AC_MSG_RESULT(no)
  633. else
  634. if test x$use_qr != xno; then
  635. AC_MSG_RESULT(yes)
  636. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  637. use_qr=yes
  638. else
  639. AC_MSG_RESULT(no)
  640. fi
  641. fi
  642. if test x$XGETTEXT = x; then
  643. AC_MSG_WARN("xgettext is required to update qt translations")
  644. fi
  645. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  646. if test x$use_tests$bitcoin_enable_qt_test = xyesyes; then
  647. AC_MSG_RESULT([yes])
  648. BUILD_TEST_QT="test"
  649. else
  650. AC_MSG_RESULT([no])
  651. fi
  652. fi
  653. AC_MSG_CHECKING([whether to build test_bitcoin])
  654. if test x$use_tests = xyes; then
  655. AC_MSG_RESULT([yes])
  656. BUILD_TEST="test"
  657. else
  658. AC_MSG_RESULT([no])
  659. fi
  660. AC_MSG_CHECKING([whether to reduce exports])
  661. if test x$use_reduce_exports != xno; then
  662. AC_MSG_RESULT([yes])
  663. else
  664. AC_MSG_RESULT([no])
  665. fi
  666. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests = xnononono; then
  667. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-daemon --with-gui or --enable-tests])
  668. fi
  669. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  670. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  671. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  672. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  673. AM_CONDITIONAL([ENABLE_TESTS],[test x$use_tests = xyes])
  674. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  675. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$use_tests$bitcoin_enable_qt_test = xyesyes])
  676. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  677. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  678. AM_CONDITIONAL([USE_COMPARISON_TOOL],[test x$use_comparison_tool != xno])
  679. AM_CONDITIONAL([USE_COMPARISON_TOOL_REORG_TESTS],[test x$use_comparison_tool_reorg_test != xno])
  680. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  681. AM_CONDITIONAL([USE_LIBSECP256K1],[test x$use_libsecp256k1 = xyes])
  682. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  683. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  684. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  685. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  686. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  687. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Version is release])
  688. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  689. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  690. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  691. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  692. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  693. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  694. AC_SUBST(RELDFLAGS)
  695. AC_SUBST(LIBTOOL_LDFLAGS)
  696. AC_SUBST(USE_UPNP)
  697. AC_SUBST(USE_QRCODE)
  698. AC_SUBST(BOOST_LIBS)
  699. AC_SUBST(TESTDEFS)
  700. AC_SUBST(LEVELDB_TARGET_FLAGS)
  701. AC_SUBST(BUILD_TEST)
  702. AC_SUBST(BUILD_QT)
  703. AC_SUBST(BUILD_TEST_QT)
  704. AC_SUBST(MINIUPNPC_CPPFLAGS)
  705. AC_CONFIG_FILES([Makefile src/Makefile share/setup.nsi share/qt/Info.plist src/test/buildenv.py])
  706. AC_CONFIG_FILES([qa/pull-tester/run-bitcoind-for-test.sh],[chmod +x qa/pull-tester/run-bitcoind-for-test.sh])
  707. AC_CONFIG_FILES([qa/pull-tester/build-tests.sh],[chmod +x qa/pull-tester/build-tests.sh])
  708. AC_OUTPUT
  709. dnl Taken from https://wiki.debian.org/RpathIssue
  710. case $host in
  711. *-*-linux-gnu)
  712. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  713. sed < libtool > libtool-2 \
  714. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  715. mv libtool-2 libtool
  716. chmod 755 libtool
  717. ;;
  718. esac