You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 27KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 9)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2014)
  9. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[info@bitcoin.org],[bitcoin])
  10. AC_CONFIG_SRCDIR([src/main.cpp])
  11. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  12. AC_CONFIG_AUX_DIR([build-aux])
  13. AC_CONFIG_MACRO_DIR([build-aux/m4])
  14. LT_INIT([disable-shared])
  15. AC_CANONICAL_HOST
  16. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  17. AH_TOP([#define BITCOIN_CONFIG_H])
  18. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  19. # This m4 will only be used if a system copy cannot be found. This is helpful
  20. # on systems where autotools are installed but the pkg-config macros are not in
  21. # a default location. It is currently used for building on OSX where autotools
  22. # are preinstalled but pkg-config comes from macports or homebrew. It should
  23. # probably be removed when building on <= 10.6 is no longer supported.
  24. m4_include([pkg.m4])
  25. dnl faketime breaks configure and is only needed for make. Disable it here.
  26. unset FAKETIME
  27. if test "x${CXXFLAGS+set}" = "xset"; then
  28. CXXFLAGS_overridden=yes
  29. else
  30. CXXFLAGS_overridden=no
  31. fi
  32. dnl ==============================================================
  33. dnl Setup for automake
  34. dnl ==============================================================
  35. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  36. dnl faketime messes with timestamps and causes configure to be re-run.
  37. dnl --disable-maintainer-mode can be used to bypass this.
  38. AM_MAINTAINER_MODE([enable])
  39. dnl make the compilation flags quiet unless V=1 is used
  40. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  41. dnl Checks for programs.
  42. AC_PROG_CXX
  43. AC_PROG_CC
  44. AC_PROG_CPP
  45. AC_PROG_CXXCPP
  46. AC_PROG_INSTALL
  47. AC_PROG_OBJC
  48. AC_PROG_LN_S
  49. m4_ifdef([AC_PROG_OBJCXX],[AC_PROG_OBJCXX])
  50. AC_PROG_MKDIR_P
  51. AC_PROG_SED
  52. AC_PATH_TOOL(AR, ar)
  53. AC_PATH_TOOL(RANLIB, ranlib)
  54. AC_PATH_TOOL(STRIP, strip)
  55. AC_PATH_TOOL(GCOV, gcov)
  56. AC_PATH_PROG(LCOV, lcov)
  57. AC_PATH_PROG(JAVA, java)
  58. AC_PATH_PROG(GENHTML, genhtml)
  59. AC_PATH_PROG([GIT], [git])
  60. AC_PATH_PROG(CCACHE,ccache)
  61. AC_PATH_PROG(XGETTEXT,xgettext)
  62. AC_PATH_PROG(HEXDUMP,hexdump)
  63. PKG_PROG_PKG_CONFIG
  64. # Enable wallet
  65. AC_ARG_ENABLE([wallet],
  66. [AS_HELP_STRING([--enable-wallet],
  67. [enable wallet (default is yes)])],
  68. [enable_wallet=$enableval],
  69. [enable_wallet=yes])
  70. AC_ARG_WITH([miniupnpc],
  71. [AS_HELP_STRING([--with-miniupnpc],
  72. [enable UPNP (default is yes if libminiupnpc is found)])],
  73. [use_upnp=$withval],
  74. [use_upnp=auto])
  75. AC_ARG_ENABLE([upnp-default],
  76. [AS_HELP_STRING([--enable-upnp-default],
  77. [if UPNP is enabled, turn it on at startup (default is no)])],
  78. [use_upnp_default=$enableval],
  79. [use_upnp_default=no])
  80. AC_ARG_ENABLE(tests,
  81. AS_HELP_STRING([--enable-tests],[compile tests (default is yes)]),
  82. [use_tests=$enableval],
  83. [use_tests=yes])
  84. AC_ARG_WITH([comparison-tool],
  85. AS_HELP_STRING([--with-comparison-tool],[path to java comparison tool (requires --enable-tests)]),
  86. [use_comparison_tool=$withval],
  87. [use_comparison_tool=no])
  88. AC_ARG_ENABLE([comparison-tool-reorg-tests],
  89. AS_HELP_STRING([--enable-comparison-tool-reorg-tests],[enable expensive reorg tests in the comparison tool (default no)]),
  90. [use_comparison_tool_reorg_tests=$enableval],
  91. [use_comparison_tool_reorg_tests=no])
  92. AC_ARG_WITH([qrencode],
  93. [AS_HELP_STRING([--with-qrencode],
  94. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  95. [use_qr=$withval],
  96. [use_qr=auto])
  97. AC_ARG_ENABLE([hardening],
  98. [AS_HELP_STRING([--enable-hardening],
  99. [attempt to harden the resulting executables (default is yes)])],
  100. [use_hardening=$enableval],
  101. [use_hardening=yes])
  102. AC_ARG_ENABLE([reduce-exports],
  103. [AS_HELP_STRING([--enable-reduce-exports],
  104. [attempt to reduce exported symbols in the resulting executables (default is yes)])],
  105. [use_reduce_exports=$enableval],
  106. [use_reduce_exports=auto])
  107. AC_ARG_ENABLE([ccache],
  108. [AS_HELP_STRING([--enable-ccache],
  109. [use ccache for building (default is yes if ccache is found)])],
  110. [use_ccache=$enableval],
  111. [use_ccache=auto])
  112. AC_ARG_ENABLE([lcov],
  113. [AS_HELP_STRING([--enable-lcov],
  114. [enable lcov testing (default is no)])],
  115. [use_lcov=yes],
  116. [use_lcov=no])
  117. AC_ARG_ENABLE([glibc-back-compat],
  118. [AS_HELP_STRING([--enable-glibc-back-compat],
  119. [enable backwards compatibility with glibc and libstdc++])],
  120. [use_glibc_compat=$enableval],
  121. [use_glibc_compat=no])
  122. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  123. # Enable debug
  124. AC_ARG_ENABLE([debug],
  125. [AS_HELP_STRING([--enable-debug],
  126. [use debug compiler flags and macros (default is no)])],
  127. [enable_debug=$enableval],
  128. [enable_debug=no])
  129. if test "x$enable_debug" = xyes; then
  130. if test "x$GCC" = xyes; then
  131. CFLAGS="-g3 -O0 -DDEBUG"
  132. fi
  133. if test "x$GXX" = xyes; then
  134. CXXFLAGS="-g3 -O0 -DDEBUG"
  135. fi
  136. fi
  137. ## TODO: Remove these hard-coded paths and flags. They are here for the sake of
  138. ## compatibility with the legacy buildsystem.
  139. ##
  140. if test "x$CXXFLAGS_overridden" = "xno"; then
  141. CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter"
  142. fi
  143. CPPFLAGS="$CPPFLAGS -DBOOST_SPIRIT_THREADSAFE -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  144. AC_LANG_PUSH([C++])
  145. use_pkgconfig=yes
  146. case $host in
  147. *mingw*)
  148. #pkgconfig does more harm than good with MinGW
  149. use_pkgconfig=no
  150. TARGET_OS=windows
  151. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  152. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  153. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  154. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  155. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  156. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  157. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  158. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  159. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  160. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  161. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  162. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  163. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  164. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  165. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  166. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  167. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  168. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  169. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  170. AX_CHECK_LINK_FLAG([[-static-libgcc]],[LDFLAGS="$LDFLAGS -static-libgcc"])
  171. AX_CHECK_LINK_FLAG([[-static-libstdc++]],[LDFLAGS="$LDFLAGS -static-libstdc++"])
  172. # -static is interpreted by libtool, where it has a different meaning.
  173. # In libtool-speak, it's -all-static.
  174. AX_CHECK_LINK_FLAG([[-static]],[LDFLAGS="$LDFLAGS -static"; LIBTOOL_LDFLAGS="$LIBTOOL_LDFLAGS -all-static"])
  175. AC_PATH_PROG([MAKENSIS], [makensis], none)
  176. if test x$MAKENSIS = xnone; then
  177. AC_MSG_WARN("makensis not found. Cannot create installer.")
  178. fi
  179. AC_PATH_TOOL(WINDRES, windres, none)
  180. if test x$WINDRES = xnone; then
  181. AC_MSG_ERROR("windres not found")
  182. fi
  183. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  184. LEVELDB_TARGET_FLAGS="TARGET_OS=OS_WINDOWS_CROSSCOMPILE"
  185. if test "x$CXXFLAGS_overridden" = "xno"; then
  186. CXXFLAGS="$CXXFLAGS -w"
  187. fi
  188. case $host in
  189. i?86-*) WINDOWS_BITS=32 ;;
  190. x86_64-*) WINDOWS_BITS=64 ;;
  191. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  192. esac
  193. AC_SUBST(WINDOWS_BITS)
  194. ;;
  195. *darwin*)
  196. TARGET_OS=darwin
  197. LEVELDB_TARGET_FLAGS="TARGET_OS=Darwin"
  198. if test x$cross_compiling != xyes; then
  199. BUILD_OS=darwin
  200. AC_CHECK_PROG([PORT],port, port)
  201. if test x$PORT = xport; then
  202. dnl add default macports paths
  203. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include -I/opt/local/include/db48"
  204. LIBS="$LIBS -L/opt/local/lib -L/opt/local/lib/db48"
  205. fi
  206. AC_CHECK_PROG([BREW],brew, brew)
  207. if test x$BREW = xbrew; then
  208. dnl add default homebrew paths
  209. openssl_prefix=`$BREW --prefix openssl`
  210. bdb_prefix=`$BREW --prefix berkeley-db4`
  211. export PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  212. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  213. LIBS="$LIBS -L$bdb_prefix/lib"
  214. fi
  215. else
  216. case $build_os in
  217. *darwin*)
  218. BUILD_OS=darwin
  219. ;;
  220. *)
  221. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  222. AC_PATH_TOOL([OTOOL], [otool], otool)
  223. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  224. ;;
  225. esac
  226. fi
  227. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  228. ;;
  229. *linux*)
  230. TARGET_OS=linux
  231. ;;
  232. *)
  233. ;;
  234. esac
  235. if test x$use_comparison_tool != xno; then
  236. AC_SUBST(JAVA_COMPARISON_TOOL, $use_comparison_tool)
  237. fi
  238. if test x$use_comparison_tool_reorg_tests != xno; then
  239. if test x$use_comparison_tool == x; then
  240. AC_MSG_ERROR("comparison tool reorg tests but comparison tool was not specified")
  241. fi
  242. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 1)
  243. else
  244. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 0)
  245. fi
  246. if test x$use_lcov == xyes; then
  247. if test x$LCOV == x; then
  248. AC_MSG_ERROR("lcov testing requested but lcov not found")
  249. fi
  250. if test x$GCOV == x; then
  251. AC_MSG_ERROR("lcov testing requested but gcov not found")
  252. fi
  253. if test x$JAVA == x; then
  254. AC_MSG_ERROR("lcov testing requested but java not found")
  255. fi
  256. if test x$GENHTML == x; then
  257. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  258. fi
  259. if test x$use_comparison_tool == x; then
  260. AC_MSG_ERROR("lcov testing requested but comparison tool was not specified")
  261. fi
  262. LCOV="$LCOV --gcov-tool=$GCOV"
  263. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  264. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  265. fi
  266. dnl Require little endian
  267. AC_C_BIGENDIAN([AC_MSG_ERROR("Big Endian not supported")])
  268. dnl Check for pthread compile/link requirements
  269. AX_PTHREAD
  270. # The following macro will add the necessary defines to bitcoin-config.h, but
  271. # they also need to be passed down to any subprojects. Pull the results out of
  272. # the cache and add them to CPPFLAGS.
  273. AC_SYS_LARGEFILE
  274. # detect POSIX or GNU variant of strerror_r
  275. AC_FUNC_STRERROR_R
  276. if test x$ac_cv_sys_file_offset_bits != x &&
  277. test x$ac_cv_sys_file_offset_bits != xno &&
  278. test x$ac_cv_sys_file_offset_bits != xunknown; then
  279. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  280. fi
  281. if test x$ac_cv_sys_large_files != x &&
  282. test x$ac_cv_sys_large_files != xno &&
  283. test x$ac_cv_sys_large_files != xunknown; then
  284. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  285. fi
  286. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  287. if test x$use_glibc_compat != xno; then
  288. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  289. # See which one is present here.
  290. AC_MSG_CHECKING(__fdelt_chk type)
  291. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  292. #undef _FORTIFY_SOURCE
  293. #endif
  294. #define _FORTIFY_SOURCE 2
  295. #include <sys/select.h>
  296. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  297. [ fdelt_type="long unsigned int"],
  298. [ fdelt_type="long int"])
  299. AC_MSG_RESULT($fdelt_type)
  300. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  301. fi
  302. if test x$use_hardening != xno; then
  303. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  304. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  305. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  306. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  307. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  308. ])
  309. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  310. ])
  311. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  312. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  313. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  314. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  315. if test x$TARGET_OS != xwindows; then
  316. # All windows code is PIC, forcing it on just adds useless compile warnings
  317. AX_CHECK_COMPILE_FLAG([-fPIE],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fPIE"])
  318. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  319. fi
  320. CXXFLAGS="$CXXFLAGS $HARDENED_CXXFLAGS"
  321. CPPFLAGS="$CPPFLAGS $HARDENED_CPPFLAGS"
  322. LDFLAGS="$LDFLAGS $HARDENED_LDFLAGS"
  323. OBJCXXFLAGS="$CXXFLAGS"
  324. fi
  325. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  326. if test x$TARGET_OS = xdarwin; then
  327. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  328. fi
  329. AC_CHECK_HEADERS([endian.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  330. AC_SEARCH_LIBS([getaddrinfo_a], [anl], [AC_DEFINE(HAVE_GETADDRINFO_A, 1, [Define this symbol if you have getaddrinfo_a])])
  331. AC_SEARCH_LIBS([inet_pton], [nsl resolv], [AC_DEFINE(HAVE_INET_PTON, 1, [Define this symbol if you have inet_pton])])
  332. AC_CHECK_DECLS([le32toh, le64toh, htole32, htole64, be32toh, be64toh, htobe32, htobe64],,,
  333. [#if HAVE_ENDIAN_H
  334. #include <endian.h>
  335. #endif])
  336. dnl Check for MSG_NOSIGNAL
  337. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  338. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  339. [[ int f = MSG_NOSIGNAL; ]])],
  340. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  341. [ AC_MSG_RESULT(no)]
  342. )
  343. AC_SEARCH_LIBS([clock_gettime],[rt])
  344. AC_MSG_CHECKING([for visibility attribute])
  345. AC_LINK_IFELSE([AC_LANG_SOURCE([
  346. int foo_def( void ) __attribute__((visibility("default")));
  347. int main(){}
  348. ])],
  349. [
  350. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  351. AC_MSG_RESULT(yes)
  352. ],
  353. [
  354. AC_MSG_RESULT(no)
  355. if test x$use_reduce_exports = xyes; then
  356. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduced-exports.])
  357. fi
  358. AC_MSG_WARN([Cannot find a working visibility attribute. Disabling reduced exports.])
  359. use_reduce_exports=no
  360. ]
  361. )
  362. if test x$use_reduce_exports != xno; then
  363. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  364. [
  365. if test x$use_reduce_exports = xyes; then
  366. AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduced-exports.])
  367. fi
  368. AC_MSG_WARN([Cannot set default symbol visibility. Disabling reduced exports.])
  369. use_reduce_exports=no
  370. ])
  371. fi
  372. LEVELDB_CPPFLAGS=
  373. LIBLEVELDB=
  374. LIBMEMENV=
  375. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  376. AC_SUBST(LEVELDB_CPPFLAGS)
  377. AC_SUBST(LIBLEVELDB)
  378. AC_SUBST(LIBMEMENV)
  379. if test x$enable_wallet != xno; then
  380. dnl Check for libdb_cxx only if wallet enabled
  381. BITCOIN_FIND_BDB48
  382. fi
  383. dnl Check for libminiupnpc (optional)
  384. if test x$use_upnp != xno; then
  385. AC_CHECK_HEADERS(
  386. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  387. [AC_CHECK_LIB([miniupnpc], [main],, [have_miniupnpc=no])],
  388. [have_miniupnpc=no]
  389. )
  390. fi
  391. dnl Check for boost libs
  392. AX_BOOST_BASE
  393. AX_BOOST_SYSTEM
  394. AX_BOOST_FILESYSTEM
  395. AX_BOOST_PROGRAM_OPTIONS
  396. AX_BOOST_THREAD
  397. AX_BOOST_CHRONO
  398. if test x$use_reduce_exports != xno; then
  399. AC_MSG_CHECKING([for working boost reduced exports])
  400. TEMP_CPPFLAGS="$CPPFLAGS"
  401. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  402. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  403. @%:@include <boost/version.hpp>
  404. ]], [[
  405. #if BOOST_VERSION >= 104900
  406. // Everything is okay
  407. #else
  408. # error Boost version is too old
  409. #endif
  410. ]])],[
  411. AC_MSG_RESULT(yes)
  412. ],[:
  413. if test x$use_reduce_exports = xauto; then
  414. use_reduce_exports=no
  415. else
  416. if test x$use_reduce_exports = xyes; then
  417. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduced-exports.])
  418. fi
  419. fi
  420. AC_MSG_RESULT(no)
  421. AC_MSG_WARN([boost versions < 1.49 are known to have symbol visibility issues. Disabling reduced exports.])
  422. ])
  423. CPPFLAGS="$TEMP_CPPFLAGS"
  424. fi
  425. if test x$use_reduce_exports != xno; then
  426. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  427. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  428. fi
  429. if test x$use_tests = xyes; then
  430. if test x$HEXDUMP = x; then
  431. AC_MSG_ERROR(hexdump is required for tests)
  432. fi
  433. AX_BOOST_UNIT_TEST_FRAMEWORK
  434. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  435. AC_MSG_CHECKING([for dynamic linked boost test])
  436. TEMP_LIBS="$LIBS"
  437. LIBS="$LIBS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  438. TEMP_CPPFLAGS="$CPPFLAGS"
  439. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  440. AC_LINK_IFELSE([AC_LANG_SOURCE([
  441. #define BOOST_TEST_DYN_LINK
  442. #define BOOST_TEST_MAIN
  443. #include <boost/test/unit_test.hpp>
  444. ])],
  445. [AC_MSG_RESULT(yes)]
  446. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  447. [AC_MSG_RESULT(no)])
  448. LIBS="$TEMP_LIBS"
  449. CPPFLAGS="$TEMP_CPPFLAGS"
  450. fi
  451. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB"
  452. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  453. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  454. dnl a working version is available, else fall back to sleep. sleep was removed
  455. dnl after 1.56.
  456. dnl If neither is available, abort.
  457. dnl If sleep_for is used, boost_chrono becomes a requirement.
  458. if test x$ax_cv_boost_chrono = xyes; then
  459. TEMP_LIBS="$LIBS"
  460. LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB $LIBS"
  461. TEMP_CPPFLAGS="$CPPFLAGS"
  462. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  463. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  464. #include <boost/thread/thread.hpp>
  465. #include <boost/version.hpp>
  466. ]],[[
  467. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  468. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  469. #else
  470. choke me
  471. #endif
  472. ]])],
  473. [boost_sleep=yes; BOOST_LIBS="$BOOST_LIBS $BOOST_CHRONO_LIB";
  474. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  475. [boost_sleep=no])
  476. LIBS="$TEMP_LIBS"
  477. CPPFLAGS="$TEMP_CPPFLAGS"
  478. fi
  479. if test x$boost_sleep != xyes; then
  480. TEMP_LIBS="$LIBS"
  481. LIBS="$BOOST_LIBS $LIBS"
  482. TEMP_CPPFLAGS="$CPPFLAGS"
  483. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  484. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  485. #include <boost/version.hpp>
  486. #include <boost/thread.hpp>
  487. #include <boost/date_time/posix_time/posix_time_types.hpp>
  488. ]],[[
  489. #if BOOST_VERSION <= 105600
  490. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  491. #else
  492. choke me
  493. #endif
  494. ]])],
  495. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  496. [boost_sleep=no])
  497. LIBS="$TEMP_LIBS"
  498. CPPFLAGS="$TEMP_CPPFLAGS"
  499. fi
  500. if test x$boost_sleep != xyes; then
  501. AC_MSG_ERROR(No working boost sleep implementation found.)
  502. fi
  503. AC_ARG_WITH([utils],
  504. [AS_HELP_STRING([--with-utils],
  505. [build bitcoin-cli bitcoin-tx (default=yes)])],
  506. [build_bitcoin_utils=$withval],
  507. [build_bitcoin_utils=yes])
  508. AC_ARG_WITH([daemon],
  509. [AS_HELP_STRING([--with-daemon],
  510. [build bitcoind daemon (default=yes)])],
  511. [build_bitcoind=$withval],
  512. [build_bitcoind=yes])
  513. BITCOIN_QT_INIT
  514. if test x$use_pkgconfig = xyes; then
  515. if test x"$PKG_CONFIG" == "x"; then
  516. AC_MSG_ERROR(pkg-config not found.)
  517. fi
  518. : #NOP
  519. m4_ifdef(
  520. [PKG_CHECK_MODULES],
  521. [
  522. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  523. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  524. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  525. if test x$use_qr != xno; then
  526. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  527. fi
  528. ]
  529. )
  530. else
  531. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  532. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  533. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  534. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  535. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],,BITCOIN_QT_FAIL(libprotobuf not found)))
  536. if test x$use_qr != xno; then
  537. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],, [have_qrencode=no])])
  538. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  539. fi
  540. fi
  541. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  542. AC_MSG_CHECKING([whether to build bitcoind])
  543. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  544. AC_MSG_RESULT($build_bitcoind)
  545. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  546. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  547. AC_MSG_RESULT($build_bitcoin_utils)
  548. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  549. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt4])
  550. AC_LANG_POP
  551. if test "x$use_ccache" != "xno"; then
  552. AC_MSG_CHECKING(if ccache should be used)
  553. if test x$CCACHE = x; then
  554. if test "x$use_ccache" = "xyes"; then
  555. AC_MSG_ERROR([ccache not found.]);
  556. else
  557. use_ccache=no
  558. fi
  559. else
  560. use_ccache=yes
  561. CC="$ac_cv_path_CCACHE $CC"
  562. CXX="$ac_cv_path_CCACHE $CXX"
  563. fi
  564. AC_MSG_RESULT($use_ccache)
  565. fi
  566. if test "x$use_ccache" = "xyes"; then
  567. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  568. fi
  569. dnl enable wallet
  570. AC_MSG_CHECKING([if wallet should be enabled])
  571. if test x$enable_wallet != xno; then
  572. AC_MSG_RESULT(yes)
  573. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  574. else
  575. AC_MSG_RESULT(no)
  576. fi
  577. dnl enable upnp support
  578. AC_MSG_CHECKING([whether to build with support for UPnP])
  579. if test x$have_miniupnpc = xno; then
  580. if test x$use_upnp = xyes; then
  581. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  582. fi
  583. AC_MSG_RESULT(no)
  584. else
  585. if test x$use_upnp != xno; then
  586. AC_MSG_RESULT(yes)
  587. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  588. use_upnp=yes
  589. upnp_setting=0
  590. if test x$use_upnp_default != xno; then
  591. use_upnp_default=yes
  592. upnp_setting=1
  593. fi
  594. AC_MSG_RESULT($use_upnp_default)
  595. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  596. if test x$TARGET_OS = xwindows; then
  597. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  598. fi
  599. else
  600. AC_MSG_RESULT(no)
  601. fi
  602. fi
  603. dnl these are only used when qt is enabled
  604. if test x$bitcoin_enable_qt != xno; then
  605. BUILD_QT=qt
  606. dnl enable dbus support
  607. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  608. if test x$bitcoin_enable_qt_dbus != xno; then
  609. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  610. fi
  611. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  612. dnl enable qr support
  613. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  614. if test x$have_qrencode = xno; then
  615. if test x$use_qr == xyes; then
  616. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  617. fi
  618. AC_MSG_RESULT(no)
  619. else
  620. if test x$use_qr != xno; then
  621. AC_MSG_RESULT(yes)
  622. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  623. use_qr=yes
  624. else
  625. AC_MSG_RESULT(no)
  626. fi
  627. fi
  628. if test x$XGETTEXT == x; then
  629. AC_MSG_WARN("xgettext is required to update qt translations")
  630. fi
  631. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  632. if test x$use_tests$bitcoin_enable_qt_test = xyesyes; then
  633. AC_MSG_RESULT([yes])
  634. BUILD_TEST_QT="test"
  635. else
  636. AC_MSG_RESULT([no])
  637. fi
  638. fi
  639. AC_MSG_CHECKING([whether to build test_bitcoin])
  640. if test x$use_tests = xyes; then
  641. AC_MSG_RESULT([yes])
  642. BUILD_TEST="test"
  643. else
  644. AC_MSG_RESULT([no])
  645. fi
  646. AC_MSG_CHECKING([whether to reduce exports])
  647. if test x$use_reduce_exports != xno; then
  648. AC_MSG_RESULT([yes])
  649. else
  650. AC_MSG_RESULT([no])
  651. fi
  652. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests = xnononono; then
  653. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-daemon --with-gui or --enable-tests])
  654. fi
  655. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  656. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  657. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  658. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet == xyes])
  659. AM_CONDITIONAL([ENABLE_TESTS],[test x$use_tests == xyes])
  660. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt == xyes])
  661. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$use_tests$bitcoin_enable_qt_test = xyesyes])
  662. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  663. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov == xyes])
  664. AM_CONDITIONAL([USE_COMPARISON_TOOL],[test x$use_comparison_tool != xno])
  665. AM_CONDITIONAL([USE_COMPARISON_TOOL_REORG_TESTS],[test x$use_comparison_tool_reorg_test != xno])
  666. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  667. AM_CONDITIONAL([USE_LIBSECP256K1],[test x$use_libsecp256k1 = xyes])
  668. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  669. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  670. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  671. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  672. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  673. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Version is release])
  674. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  675. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  676. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  677. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  678. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  679. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  680. AC_SUBST(RELDFLAGS)
  681. AC_SUBST(LIBTOOL_LDFLAGS)
  682. AC_SUBST(USE_UPNP)
  683. AC_SUBST(USE_QRCODE)
  684. AC_SUBST(BOOST_LIBS)
  685. AC_SUBST(TESTDEFS)
  686. AC_SUBST(LEVELDB_TARGET_FLAGS)
  687. AC_SUBST(BUILD_TEST)
  688. AC_SUBST(BUILD_QT)
  689. AC_SUBST(BUILD_TEST_QT)
  690. AC_SUBST(MINIUPNPC_CPPFLAGS)
  691. AC_CONFIG_FILES([Makefile src/Makefile share/setup.nsi share/qt/Info.plist])
  692. AC_CONFIG_FILES([qa/pull-tester/run-bitcoind-for-test.sh],[chmod +x qa/pull-tester/run-bitcoind-for-test.sh])
  693. AC_CONFIG_FILES([qa/pull-tester/build-tests.sh],[chmod +x qa/pull-tester/build-tests.sh])
  694. AC_OUTPUT
  695. dnl Taken from https://wiki.debian.org/RpathIssue
  696. case $host in
  697. *-*-linux-gnu)
  698. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  699. sed < libtool > libtool-2 \
  700. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  701. mv libtool-2 libtool
  702. chmod 755 libtool
  703. ;;
  704. esac