You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 43KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961962963964965966967968969970971972973974975976977978979980981982983984985986987988989990991992993994995996997998999100010011002100310041005100610071008100910101011101210131014101510161017101810191020102110221023102410251026102710281029103010311032103310341035103610371038103910401041104210431044104510461047104810491050105110521053105410551056105710581059106010611062106310641065106610671068106910701071107210731074107510761077107810791080108110821083108410851086108710881089109010911092109310941095109610971098109911001101110211031104110511061107110811091110111111121113111411151116111711181119112011211122112311241125112611271128112911301131113211331134113511361137113811391140114111421143114411451146114711481149115011511152115311541155115611571158115911601161116211631164116511661167116811691170117111721173117411751176117711781179118011811182118311841185118611871188118911901191119211931194119511961197119811991200120112021203120412051206120712081209121012111212121312141215121612171218121912201221122212231224122512261227122812291230123112321233123412351236123712381239124012411242124312441245124612471248124912501251125212531254125512561257
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 14)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2017)
  9. define(_COPYRIGHT_HOLDERS,[The %s developers])
  10. define(_COPYRIGHT_HOLDERS_SUBSTITUTION,[[Bitcoin Core]])
  11. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[https://github.com/bitcoin/bitcoin/issues],[bitcoin],[https://bitcoincore.org/])
  12. AC_CONFIG_SRCDIR([src/validation.cpp])
  13. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  14. AC_CONFIG_AUX_DIR([build-aux])
  15. AC_CONFIG_MACRO_DIR([build-aux/m4])
  16. BITCOIN_DAEMON_NAME=bitcoind
  17. BITCOIN_GUI_NAME=bitcoin-qt
  18. BITCOIN_CLI_NAME=bitcoin-cli
  19. BITCOIN_TX_NAME=bitcoin-tx
  20. AC_CANONICAL_HOST
  21. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  22. AH_TOP([#define BITCOIN_CONFIG_H])
  23. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  24. dnl faketime breaks configure and is only needed for make. Disable it here.
  25. unset FAKETIME
  26. dnl Automake init set-up and checks
  27. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  28. dnl faketime messes with timestamps and causes configure to be re-run.
  29. dnl --disable-maintainer-mode can be used to bypass this.
  30. AM_MAINTAINER_MODE([enable])
  31. dnl make the compilation flags quiet unless V=1 is used
  32. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33. dnl Compiler checks (here before libtool).
  34. if test "x${CXXFLAGS+set}" = "xset"; then
  35. CXXFLAGS_overridden=yes
  36. else
  37. CXXFLAGS_overridden=no
  38. fi
  39. AC_PROG_CXX
  40. dnl By default, libtool for mingw refuses to link static libs into a dll for
  41. dnl fear of mixing pic/non-pic objects, and import/export complications. Since
  42. dnl we have those under control, re-enable that functionality.
  43. case $host in
  44. *mingw*)
  45. lt_cv_deplibs_check_method="pass_all"
  46. ;;
  47. esac
  48. dnl Require C++11 compiler (no GNU extensions)
  49. AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory], [nodefault])
  50. dnl Check if -latomic is required for <std::atomic>
  51. CHECK_ATOMIC
  52. dnl Unless the user specified OBJCXX, force it to be the same as CXX. This ensures
  53. dnl that we get the same -std flags for both.
  54. m4_ifdef([AC_PROG_OBJCXX],[
  55. if test "x${OBJCXX+set}" = "x"; then
  56. OBJCXX="${CXX}"
  57. fi
  58. AC_PROG_OBJCXX
  59. ])
  60. dnl Libtool init checks.
  61. LT_INIT([pic-only])
  62. dnl Check/return PATH for base programs.
  63. AC_PATH_TOOL(AR, ar)
  64. AC_PATH_TOOL(RANLIB, ranlib)
  65. AC_PATH_TOOL(STRIP, strip)
  66. AC_PATH_TOOL(GCOV, gcov)
  67. AC_PATH_PROG(LCOV, lcov)
  68. dnl Python 3.x is supported from 3.4 on (see https://github.com/bitcoin/bitcoin/issues/7893)
  69. AC_PATH_PROGS([PYTHON], [python3.6 python3.5 python3.4 python3 python2.7 python2 python])
  70. AC_PATH_PROG(GENHTML, genhtml)
  71. AC_PATH_PROG([GIT], [git])
  72. AC_PATH_PROG(CCACHE,ccache)
  73. AC_PATH_PROG(XGETTEXT,xgettext)
  74. AC_PATH_PROG(HEXDUMP,hexdump)
  75. AC_PATH_TOOL(READELF, readelf)
  76. AC_PATH_TOOL(CPPFILT, c++filt)
  77. AC_PATH_TOOL(OBJCOPY, objcopy)
  78. AC_ARG_VAR(PYTHONPATH, Augments the default search path for python module files)
  79. # Enable wallet
  80. AC_ARG_ENABLE([wallet],
  81. [AS_HELP_STRING([--disable-wallet],
  82. [disable wallet (enabled by default)])],
  83. [enable_wallet=$enableval],
  84. [enable_wallet=yes])
  85. AC_ARG_WITH([miniupnpc],
  86. [AS_HELP_STRING([--with-miniupnpc],
  87. [enable UPNP (default is yes if libminiupnpc is found)])],
  88. [use_upnp=$withval],
  89. [use_upnp=auto])
  90. AC_ARG_ENABLE([upnp-default],
  91. [AS_HELP_STRING([--enable-upnp-default],
  92. [if UPNP is enabled, turn it on at startup (default is no)])],
  93. [use_upnp_default=$enableval],
  94. [use_upnp_default=no])
  95. AC_ARG_ENABLE(tests,
  96. AS_HELP_STRING([--disable-tests],[do not compile tests (default is to compile)]),
  97. [use_tests=$enableval],
  98. [use_tests=yes])
  99. AC_ARG_ENABLE(gui-tests,
  100. AS_HELP_STRING([--disable-gui-tests],[do not compile GUI tests (default is to compile if GUI and tests enabled)]),
  101. [use_gui_tests=$enableval],
  102. [use_gui_tests=$use_tests])
  103. AC_ARG_ENABLE(bench,
  104. AS_HELP_STRING([--disable-bench],[do not compile benchmarks (default is to compile)]),
  105. [use_bench=$enableval],
  106. [use_bench=yes])
  107. AC_ARG_ENABLE([extended-functional-tests],
  108. AS_HELP_STRING([--enable-extended-functional-tests],[enable expensive functional tests when using lcov (default no)]),
  109. [use_extended_functional_tests=$enableval],
  110. [use_extended_functional_tests=no])
  111. AC_ARG_WITH([qrencode],
  112. [AS_HELP_STRING([--with-qrencode],
  113. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  114. [use_qr=$withval],
  115. [use_qr=auto])
  116. AC_ARG_ENABLE([hardening],
  117. [AS_HELP_STRING([--disable-hardening],
  118. [do not attempt to harden the resulting executables (default is to harden)])],
  119. [use_hardening=$enableval],
  120. [use_hardening=yes])
  121. AC_ARG_ENABLE([reduce-exports],
  122. [AS_HELP_STRING([--enable-reduce-exports],
  123. [attempt to reduce exported symbols in the resulting executables (default is no)])],
  124. [use_reduce_exports=$enableval],
  125. [use_reduce_exports=no])
  126. AC_ARG_ENABLE([ccache],
  127. [AS_HELP_STRING([--disable-ccache],
  128. [do not use ccache for building (default is to use if found)])],
  129. [use_ccache=$enableval],
  130. [use_ccache=auto])
  131. AC_ARG_ENABLE([lcov],
  132. [AS_HELP_STRING([--enable-lcov],
  133. [enable lcov testing (default is no)])],
  134. [use_lcov=yes],
  135. [use_lcov=no])
  136. AC_ARG_ENABLE([lcov-branch-coverage],
  137. [AS_HELP_STRING([--enable-lcov-branch-coverage],
  138. [enable lcov testing branch coverage (default is no)])],
  139. [use_lcov_branch=yes],
  140. [use_lcov_branch=no])
  141. AC_ARG_ENABLE([glibc-back-compat],
  142. [AS_HELP_STRING([--enable-glibc-back-compat],
  143. [enable backwards compatibility with glibc])],
  144. [use_glibc_compat=$enableval],
  145. [use_glibc_compat=no])
  146. AC_ARG_WITH([system-univalue],
  147. [AS_HELP_STRING([--with-system-univalue],
  148. [Build with system UniValue (default is no)])],
  149. [system_univalue=$withval],
  150. [system_univalue=no]
  151. )
  152. AC_ARG_ENABLE([zmq],
  153. [AS_HELP_STRING([--disable-zmq],
  154. [disable ZMQ notifications])],
  155. [use_zmq=$enableval],
  156. [use_zmq=yes])
  157. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  158. AC_ARG_ENABLE(man,
  159. [AS_HELP_STRING([--disable-man],
  160. [do not install man pages (default is to install)])],,
  161. enable_man=yes)
  162. AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
  163. # Enable debug
  164. AC_ARG_ENABLE([debug],
  165. [AS_HELP_STRING([--enable-debug],
  166. [use debug compiler flags and macros (default is no)])],
  167. [enable_debug=$enableval],
  168. [enable_debug=no])
  169. # Turn warnings into errors
  170. AC_ARG_ENABLE([werror],
  171. [AS_HELP_STRING([--enable-werror],
  172. [Treat certain compiler warnings as errors (default is no)])],
  173. [enable_werror=$enableval],
  174. [enable_werror=no])
  175. AC_LANG_PUSH([C++])
  176. AX_CHECK_COMPILE_FLAG([-Werror],[CXXFLAG_WERROR="-Werror"],[CXXFLAG_WERROR=""])
  177. if test "x$enable_debug" = xyes; then
  178. CPPFLAGS="$CPPFLAGS -DDEBUG -DDEBUG_LOCKORDER"
  179. if test "x$GCC" = xyes; then
  180. CFLAGS="$CFLAGS -g3 -O0"
  181. fi
  182. if test "x$GXX" = xyes; then
  183. CXXFLAGS="$CXXFLAGS -g3 -O0"
  184. fi
  185. fi
  186. ERROR_CXXFLAGS=
  187. if test "x$enable_werror" = "xyes"; then
  188. if test "x$CXXFLAG_WERROR" = "x"; then
  189. AC_MSG_ERROR("enable-werror set but -Werror is not usable")
  190. fi
  191. AX_CHECK_COMPILE_FLAG([-Werror=vla],[ERROR_CXXFLAGS="$ERROR_CXXFLAGS -Werror=vla"],,[[$CXXFLAG_WERROR]])
  192. fi
  193. if test "x$CXXFLAGS_overridden" = "xno"; then
  194. AX_CHECK_COMPILE_FLAG([-Wall],[CXXFLAGS="$CXXFLAGS -Wall"],,[[$CXXFLAG_WERROR]])
  195. AX_CHECK_COMPILE_FLAG([-Wextra],[CXXFLAGS="$CXXFLAGS -Wextra"],,[[$CXXFLAG_WERROR]])
  196. AX_CHECK_COMPILE_FLAG([-Wformat],[CXXFLAGS="$CXXFLAGS -Wformat"],,[[$CXXFLAG_WERROR]])
  197. AX_CHECK_COMPILE_FLAG([-Wvla],[CXXFLAGS="$CXXFLAGS -Wvla"],,[[$CXXFLAG_WERROR]])
  198. AX_CHECK_COMPILE_FLAG([-Wformat-security],[CXXFLAGS="$CXXFLAGS -Wformat-security"],,[[$CXXFLAG_WERROR]])
  199. ## Some compilers (gcc) ignore unknown -Wno-* options, but warn about all
  200. ## unknown options if any other warning is produced. Test the -Wfoo case, and
  201. ## set the -Wno-foo case if it works.
  202. AX_CHECK_COMPILE_FLAG([-Wunused-parameter],[CXXFLAGS="$CXXFLAGS -Wno-unused-parameter"],,[[$CXXFLAG_WERROR]])
  203. AX_CHECK_COMPILE_FLAG([-Wself-assign],[CXXFLAGS="$CXXFLAGS -Wno-self-assign"],,[[$CXXFLAG_WERROR]])
  204. AX_CHECK_COMPILE_FLAG([-Wunused-local-typedef],[CXXFLAGS="$CXXFLAGS -Wno-unused-local-typedef"],,[[$CXXFLAG_WERROR]])
  205. AX_CHECK_COMPILE_FLAG([-Wdeprecated-register],[CXXFLAGS="$CXXFLAGS -Wno-deprecated-register"],,[[$CXXFLAG_WERROR]])
  206. AX_CHECK_COMPILE_FLAG([-Wimplicit-fallthrough],[CXXFLAGS="$CXXFLAGS -Wno-implicit-fallthrough"],,[[$CXXFLAG_WERROR]])
  207. fi
  208. CPPFLAGS="$CPPFLAGS -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  209. AC_ARG_WITH([utils],
  210. [AS_HELP_STRING([--with-utils],
  211. [build bitcoin-cli bitcoin-tx (default=yes)])],
  212. [build_bitcoin_utils=$withval],
  213. [build_bitcoin_utils=yes])
  214. AC_ARG_WITH([libs],
  215. [AS_HELP_STRING([--with-libs],
  216. [build libraries (default=yes)])],
  217. [build_bitcoin_libs=$withval],
  218. [build_bitcoin_libs=yes])
  219. AC_ARG_WITH([daemon],
  220. [AS_HELP_STRING([--with-daemon],
  221. [build bitcoind daemon (default=yes)])],
  222. [build_bitcoind=$withval],
  223. [build_bitcoind=yes])
  224. use_pkgconfig=yes
  225. case $host in
  226. *mingw*)
  227. #pkgconfig does more harm than good with MinGW
  228. use_pkgconfig=no
  229. TARGET_OS=windows
  230. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  231. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  232. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  233. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  234. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  235. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  236. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  237. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  238. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  239. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  240. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  241. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  242. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  243. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  244. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  245. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  246. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  247. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  248. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  249. # -static is interpreted by libtool, where it has a different meaning.
  250. # In libtool-speak, it's -all-static.
  251. AX_CHECK_LINK_FLAG([[-static]],[LIBTOOL_APP_LDFLAGS="$LIBTOOL_APP_LDFLAGS -all-static"])
  252. AC_PATH_PROG([MAKENSIS], [makensis], none)
  253. if test x$MAKENSIS = xnone; then
  254. AC_MSG_WARN("makensis not found. Cannot create installer.")
  255. fi
  256. AC_PATH_TOOL(WINDRES, windres, none)
  257. if test x$WINDRES = xnone; then
  258. AC_MSG_ERROR("windres not found")
  259. fi
  260. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  261. LEVELDB_TARGET_FLAGS="-DOS_WINDOWS"
  262. if test "x$CXXFLAGS_overridden" = "xno"; then
  263. CXXFLAGS="$CXXFLAGS -w"
  264. fi
  265. case $host in
  266. i?86-*) WINDOWS_BITS=32 ;;
  267. x86_64-*) WINDOWS_BITS=64 ;;
  268. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  269. esac
  270. AC_SUBST(WINDOWS_BITS)
  271. dnl libtool insists upon adding -nostdlib and a list of objects/libs to link against.
  272. dnl That breaks our ability to build dll's with static libgcc/libstdc++/libssp. Override
  273. dnl its command here, with the predeps/postdeps removed, and -static inserted. Postdeps are
  274. dnl also overridden to prevent their insertion later.
  275. dnl This should only affect dll's.
  276. archive_cmds_CXX="\$CC -shared \$libobjs \$deplibs \$compiler_flags -static -o \$output_objdir/\$soname \${wl}--enable-auto-image-base -Xlinker --out-implib -Xlinker \$lib"
  277. postdeps_CXX=
  278. ;;
  279. *darwin*)
  280. TARGET_OS=darwin
  281. LEVELDB_TARGET_FLAGS="-DOS_MACOSX"
  282. if test x$cross_compiling != xyes; then
  283. BUILD_OS=darwin
  284. AC_CHECK_PROG([PORT],port, port)
  285. if test x$PORT = xport; then
  286. dnl add default macports paths
  287. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  288. LIBS="$LIBS -L/opt/local/lib"
  289. if test -d /opt/local/include/db48; then
  290. CPPFLAGS="$CPPFLAGS -I/opt/local/include/db48"
  291. LIBS="$LIBS -L/opt/local/lib/db48"
  292. fi
  293. fi
  294. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  295. AC_CHECK_PROG([BREW],brew, brew)
  296. if test x$BREW = xbrew; then
  297. dnl These Homebrew packages may be keg-only, meaning that they won't be found
  298. dnl in expected paths because they may conflict with system files. Ask
  299. dnl Homebrew where each one is located, then adjust paths accordingly.
  300. dnl It's safe to add these paths even if the functionality is disabled by
  301. dnl the user (--without-wallet or --without-gui for example).
  302. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  303. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  304. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  305. if test x$openssl_prefix != x; then
  306. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  307. export PKG_CONFIG_PATH
  308. fi
  309. if test x$bdb_prefix != x; then
  310. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  311. LIBS="$LIBS -L$bdb_prefix/lib"
  312. fi
  313. if test x$qt5_prefix != x; then
  314. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  315. export PKG_CONFIG_PATH
  316. fi
  317. fi
  318. else
  319. case $build_os in
  320. *darwin*)
  321. BUILD_OS=darwin
  322. ;;
  323. *)
  324. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  325. AC_PATH_TOOL([OTOOL], [otool], otool)
  326. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  327. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  328. AC_PATH_PROGS([IMAGEMAGICK_CONVERT], [convert],convert)
  329. AC_PATH_PROGS([TIFFCP], [tiffcp],tiffcp)
  330. dnl libtool will try to strip the static lib, which is a problem for
  331. dnl cross-builds because strip attempts to call a hard-coded ld,
  332. dnl which may not exist in the path. Stripping the .a is not
  333. dnl necessary, so just disable it.
  334. old_striplib=
  335. ;;
  336. esac
  337. fi
  338. AX_CHECK_LINK_FLAG([[-Wl,-headerpad_max_install_names]], [LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"])
  339. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  340. OBJCXXFLAGS="$CXXFLAGS"
  341. ;;
  342. *linux*)
  343. TARGET_OS=linux
  344. LEVELDB_TARGET_FLAGS="-DOS_LINUX"
  345. ;;
  346. *freebsd*)
  347. LEVELDB_TARGET_FLAGS="-DOS_FREEBSD"
  348. ;;
  349. *openbsd*)
  350. LEVELDB_TARGET_FLAGS="-DOS_OPENBSD"
  351. ;;
  352. *)
  353. OTHER_OS=`echo ${host_os} | awk '{print toupper($0)}'`
  354. AC_MSG_WARN([Guessing LevelDB OS as OS_${OTHER_OS}, please check whether this is correct, if not add an entry to configure.ac.])
  355. LEVELDB_TARGET_FLAGS="-DOS_${OTHER_OS}"
  356. ;;
  357. esac
  358. if test x$use_pkgconfig = xyes; then
  359. m4_ifndef([PKG_PROG_PKG_CONFIG], [AC_MSG_ERROR(PKG_PROG_PKG_CONFIG macro not found. Please install pkg-config and re-run autogen.sh.)])
  360. m4_ifdef([PKG_PROG_PKG_CONFIG], [
  361. PKG_PROG_PKG_CONFIG
  362. if test x"$PKG_CONFIG" = "x"; then
  363. AC_MSG_ERROR(pkg-config not found.)
  364. fi
  365. ])
  366. fi
  367. if test x$use_extended_functional_tests != xno; then
  368. AC_SUBST(EXTENDED_FUNCTIONAL_TESTS, --extended)
  369. fi
  370. if test x$use_lcov = xyes; then
  371. if test x$LCOV = x; then
  372. AC_MSG_ERROR("lcov testing requested but lcov not found")
  373. fi
  374. if test x$GCOV = x; then
  375. AC_MSG_ERROR("lcov testing requested but gcov not found")
  376. fi
  377. if test x$PYTHON = x; then
  378. AC_MSG_ERROR("lcov testing requested but python not found")
  379. fi
  380. if test x$GENHTML = x; then
  381. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  382. fi
  383. LCOV="$LCOV --gcov-tool=$GCOV"
  384. AX_CHECK_LINK_FLAG([[--coverage]], [LDFLAGS="$LDFLAGS --coverage"],
  385. [AC_MSG_ERROR("lcov testing requested but --coverage linker flag does not work")])
  386. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  387. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  388. AC_DEFINE(USE_COVERAGE, 1, [Define this symbol if coverage is enabled])
  389. CXXFLAGS="$CXXFLAGS -Og"
  390. fi
  391. if test x$use_lcov_branch != xno; then
  392. AC_SUBST(LCOV_OPTS, "$LCOV_OPTS --rc lcov_branch_coverage=1")
  393. fi
  394. dnl Check for endianness
  395. AC_C_BIGENDIAN
  396. dnl Check for pthread compile/link requirements
  397. AX_PTHREAD
  398. # The following macro will add the necessary defines to bitcoin-config.h, but
  399. # they also need to be passed down to any subprojects. Pull the results out of
  400. # the cache and add them to CPPFLAGS.
  401. AC_SYS_LARGEFILE
  402. # detect POSIX or GNU variant of strerror_r
  403. AC_FUNC_STRERROR_R
  404. if test x$ac_cv_sys_file_offset_bits != x &&
  405. test x$ac_cv_sys_file_offset_bits != xno &&
  406. test x$ac_cv_sys_file_offset_bits != xunknown; then
  407. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  408. fi
  409. if test x$ac_cv_sys_large_files != x &&
  410. test x$ac_cv_sys_large_files != xno &&
  411. test x$ac_cv_sys_large_files != xunknown; then
  412. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  413. fi
  414. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  415. AX_GCC_FUNC_ATTRIBUTE([visibility])
  416. AX_GCC_FUNC_ATTRIBUTE([dllexport])
  417. AX_GCC_FUNC_ATTRIBUTE([dllimport])
  418. if test x$use_glibc_compat != xno; then
  419. #glibc absorbed clock_gettime in 2.17. librt (its previous location) is safe to link
  420. #in anyway for back-compat.
  421. AC_CHECK_LIB([rt],[clock_gettime],, AC_MSG_ERROR(lib missing))
  422. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  423. # See which one is present here.
  424. AC_MSG_CHECKING(__fdelt_chk type)
  425. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  426. #undef _FORTIFY_SOURCE
  427. #endif
  428. #define _FORTIFY_SOURCE 2
  429. #include <sys/select.h>
  430. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  431. [ fdelt_type="long unsigned int"],
  432. [ fdelt_type="long int"])
  433. AC_MSG_RESULT($fdelt_type)
  434. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  435. else
  436. AC_SEARCH_LIBS([clock_gettime],[rt])
  437. fi
  438. if test x$TARGET_OS != xwindows; then
  439. # All windows code is PIC, forcing it on just adds useless compile warnings
  440. AX_CHECK_COMPILE_FLAG([-fPIC],[PIC_FLAGS="-fPIC"])
  441. fi
  442. if test x$use_hardening != xno; then
  443. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  444. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  445. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  446. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  447. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  448. ])
  449. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  450. ])
  451. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  452. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  453. AX_CHECK_LINK_FLAG([[-Wl,--high-entropy-va]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--high-entropy-va"])
  454. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  455. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  456. if test x$TARGET_OS != xwindows; then
  457. AX_CHECK_COMPILE_FLAG([-fPIE],[PIE_FLAGS="-fPIE"])
  458. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  459. fi
  460. case $host in
  461. *mingw*)
  462. AC_CHECK_LIB([ssp], [main],, AC_MSG_ERROR(lib missing))
  463. ;;
  464. esac
  465. fi
  466. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  467. if test x$TARGET_OS = xdarwin; then
  468. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  469. fi
  470. AC_CHECK_HEADERS([endian.h sys/endian.h byteswap.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  471. AC_CHECK_DECLS([strnlen])
  472. # Check for daemon(3), unrelated to --with-daemon (although used by it)
  473. AC_CHECK_DECLS([daemon])
  474. AC_CHECK_DECLS([le16toh, le32toh, le64toh, htole16, htole32, htole64, be16toh, be32toh, be64toh, htobe16, htobe32, htobe64],,,
  475. [#if HAVE_ENDIAN_H
  476. #include <endian.h>
  477. #elif HAVE_SYS_ENDIAN_H
  478. #include <sys/endian.h>
  479. #endif])
  480. AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64],,,
  481. [#if HAVE_BYTESWAP_H
  482. #include <byteswap.h>
  483. #endif])
  484. AC_CHECK_DECLS([__builtin_clz, __builtin_clzl, __builtin_clzll])
  485. dnl Check for MSG_NOSIGNAL
  486. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  487. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  488. [[ int f = MSG_NOSIGNAL; ]])],
  489. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  490. [ AC_MSG_RESULT(no)]
  491. )
  492. dnl Check for MSG_DONTWAIT
  493. AC_MSG_CHECKING(for MSG_DONTWAIT)
  494. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  495. [[ int f = MSG_DONTWAIT; ]])],
  496. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_DONTWAIT, 1,[Define this symbol if you have MSG_DONTWAIT]) ],
  497. [ AC_MSG_RESULT(no)]
  498. )
  499. dnl Check for malloc_info (for memory statistics information in getmemoryinfo)
  500. AC_MSG_CHECKING(for getmemoryinfo)
  501. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  502. [[ int f = malloc_info(0, NULL); ]])],
  503. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MALLOC_INFO, 1,[Define this symbol if you have malloc_info]) ],
  504. [ AC_MSG_RESULT(no)]
  505. )
  506. dnl Check for mallopt(M_ARENA_MAX) (to set glibc arenas)
  507. AC_MSG_CHECKING(for mallopt M_ARENA_MAX)
  508. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  509. [[ mallopt(M_ARENA_MAX, 1); ]])],
  510. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MALLOPT_ARENA_MAX, 1,[Define this symbol if you have mallopt with M_ARENA_MAX]) ],
  511. [ AC_MSG_RESULT(no)]
  512. )
  513. AC_MSG_CHECKING([for visibility attribute])
  514. AC_LINK_IFELSE([AC_LANG_SOURCE([
  515. int foo_def( void ) __attribute__((visibility("default")));
  516. int main(){}
  517. ])],
  518. [
  519. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  520. AC_MSG_RESULT(yes)
  521. ],
  522. [
  523. AC_MSG_RESULT(no)
  524. if test x$use_reduce_exports = xyes; then
  525. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduce-exports.])
  526. fi
  527. ]
  528. )
  529. # Check for different ways of gathering OS randomness
  530. AC_MSG_CHECKING(for Linux getrandom syscall)
  531. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
  532. #include <sys/syscall.h>
  533. #include <linux/random.h>]],
  534. [[ syscall(SYS_getrandom, nullptr, 32, 0); ]])],
  535. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SYS_GETRANDOM, 1,[Define this symbol if the Linux getrandom system call is available]) ],
  536. [ AC_MSG_RESULT(no)]
  537. )
  538. AC_MSG_CHECKING(for getentropy)
  539. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>]],
  540. [[ getentropy(nullptr, 32) ]])],
  541. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_GETENTROPY, 1,[Define this symbol if the BSD getentropy system call is available]) ],
  542. [ AC_MSG_RESULT(no)]
  543. )
  544. AC_MSG_CHECKING(for sysctl KERN_ARND)
  545. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
  546. #include <sys/sysctl.h>]],
  547. [[ static const int name[2] = {CTL_KERN, KERN_ARND};
  548. sysctl(name, 2, nullptr, nullptr, nullptr, 0); ]])],
  549. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SYSCTL_ARND, 1,[Define this symbol if the BSD sysctl(KERN_ARND) is available]) ],
  550. [ AC_MSG_RESULT(no)]
  551. )
  552. # Check for reduced exports
  553. if test x$use_reduce_exports = xyes; then
  554. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  555. [AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduce-exports.])])
  556. fi
  557. LEVELDB_CPPFLAGS=
  558. LIBLEVELDB=
  559. LIBMEMENV=
  560. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  561. AC_SUBST(LEVELDB_CPPFLAGS)
  562. AC_SUBST(LIBLEVELDB)
  563. AC_SUBST(LIBMEMENV)
  564. if test x$enable_wallet != xno; then
  565. dnl Check for libdb_cxx only if wallet enabled
  566. BITCOIN_FIND_BDB48
  567. fi
  568. dnl Check for libminiupnpc (optional)
  569. if test x$use_upnp != xno; then
  570. AC_CHECK_HEADERS(
  571. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  572. [AC_CHECK_LIB([miniupnpc], [main],[MINIUPNPC_LIBS=-lminiupnpc], [have_miniupnpc=no])],
  573. [have_miniupnpc=no]
  574. )
  575. fi
  576. BITCOIN_QT_INIT
  577. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  578. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt5])
  579. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  580. use_boost=no
  581. else
  582. use_boost=yes
  583. fi
  584. if test x$use_boost = xyes; then
  585. dnl Minimum required Boost version
  586. define(MINIMUM_REQUIRED_BOOST, 1.47.0)
  587. dnl Check for boost libs
  588. AX_BOOST_BASE([MINIMUM_REQUIRED_BOOST])
  589. AX_BOOST_SYSTEM
  590. AX_BOOST_FILESYSTEM
  591. AX_BOOST_PROGRAM_OPTIONS
  592. AX_BOOST_THREAD
  593. AX_BOOST_CHRONO
  594. dnl Boost 1.56 through 1.62 allow using std::atomic instead of its own atomic
  595. dnl counter implementations. In 1.63 and later the std::atomic approach is default.
  596. m4_pattern_allow(DBOOST_AC_USE_STD_ATOMIC) dnl otherwise it's treated like a macro
  597. BOOST_CPPFLAGS="-DBOOST_SP_USE_STD_ATOMIC -DBOOST_AC_USE_STD_ATOMIC $BOOST_CPPFLAGS"
  598. if test x$use_reduce_exports = xyes; then
  599. AC_MSG_CHECKING([for working boost reduced exports])
  600. TEMP_CPPFLAGS="$CPPFLAGS"
  601. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  602. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  603. @%:@include <boost/version.hpp>
  604. ]], [[
  605. #if BOOST_VERSION >= 104900
  606. // Everything is okay
  607. #else
  608. # error Boost version is too old
  609. #endif
  610. ]])],[
  611. AC_MSG_RESULT(yes)
  612. ],[
  613. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduce-exports.])
  614. ])
  615. CPPFLAGS="$TEMP_CPPFLAGS"
  616. fi
  617. fi
  618. if test x$use_reduce_exports = xyes; then
  619. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  620. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  621. fi
  622. if test x$use_tests = xyes; then
  623. if test x$HEXDUMP = x; then
  624. AC_MSG_ERROR(hexdump is required for tests)
  625. fi
  626. if test x$use_boost = xyes; then
  627. AX_BOOST_UNIT_TEST_FRAMEWORK
  628. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  629. AC_MSG_CHECKING([for dynamic linked boost test])
  630. TEMP_LIBS="$LIBS"
  631. LIBS="$LIBS $BOOST_LDFLAGS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  632. TEMP_CPPFLAGS="$CPPFLAGS"
  633. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  634. AC_LINK_IFELSE([AC_LANG_SOURCE([
  635. #define BOOST_TEST_DYN_LINK
  636. #define BOOST_TEST_MAIN
  637. #include <boost/test/unit_test.hpp>
  638. ])],
  639. [AC_MSG_RESULT(yes)]
  640. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  641. [AC_MSG_RESULT(no)])
  642. LIBS="$TEMP_LIBS"
  643. CPPFLAGS="$TEMP_CPPFLAGS"
  644. fi
  645. fi
  646. if test x$use_boost = xyes; then
  647. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB $BOOST_CHRONO_LIB"
  648. dnl If boost (prior to 1.57) was built without c++11, it emulated scoped enums
  649. dnl using c++98 constructs. Unfortunately, this implementation detail leaked into
  650. dnl the abi. This was fixed in 1.57.
  651. dnl When building against that installed version using c++11, the headers pick up
  652. dnl on the native c++11 scoped enum support and enable it, however it will fail to
  653. dnl link. This can be worked around by disabling c++11 scoped enums if linking will
  654. dnl fail.
  655. dnl BOOST_NO_SCOPED_ENUMS was changed to BOOST_NO_CXX11_SCOPED_ENUMS in 1.51.
  656. TEMP_LIBS="$LIBS"
  657. LIBS="$BOOST_LIBS $LIBS"
  658. TEMP_CPPFLAGS="$CPPFLAGS"
  659. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  660. AC_MSG_CHECKING([for mismatched boost c++11 scoped enums])
  661. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  662. #include "boost/config.hpp"
  663. #include "boost/version.hpp"
  664. #if !defined(BOOST_NO_SCOPED_ENUMS) && !defined(BOOST_NO_CXX11_SCOPED_ENUMS) && BOOST_VERSION < 105700
  665. #define BOOST_NO_SCOPED_ENUMS
  666. #define BOOST_NO_CXX11_SCOPED_ENUMS
  667. #define CHECK
  668. #endif
  669. #include "boost/filesystem.hpp"
  670. ]],[[
  671. #if defined(CHECK)
  672. boost::filesystem::copy_file("foo", "bar");
  673. #else
  674. choke;
  675. #endif
  676. ]])],
  677. [AC_MSG_RESULT(mismatched); BOOST_CPPFLAGS="$BOOST_CPPFLAGS -DBOOST_NO_SCOPED_ENUMS -DBOOST_NO_CXX11_SCOPED_ENUMS"], [AC_MSG_RESULT(ok)])
  678. LIBS="$TEMP_LIBS"
  679. CPPFLAGS="$TEMP_CPPFLAGS"
  680. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  681. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  682. dnl a working version is available, else fall back to sleep. sleep was removed
  683. dnl after 1.56.
  684. dnl If neither is available, abort.
  685. TEMP_LIBS="$LIBS"
  686. LIBS="$BOOST_LIBS $LIBS"
  687. TEMP_CPPFLAGS="$CPPFLAGS"
  688. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  689. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  690. #include <boost/thread/thread.hpp>
  691. #include <boost/version.hpp>
  692. ]],[[
  693. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  694. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  695. #else
  696. choke me
  697. #endif
  698. ]])],
  699. [boost_sleep=yes;
  700. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  701. [boost_sleep=no])
  702. LIBS="$TEMP_LIBS"
  703. CPPFLAGS="$TEMP_CPPFLAGS"
  704. if test x$boost_sleep != xyes; then
  705. TEMP_LIBS="$LIBS"
  706. LIBS="$BOOST_LIBS $LIBS"
  707. TEMP_CPPFLAGS="$CPPFLAGS"
  708. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  709. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  710. #include <boost/version.hpp>
  711. #include <boost/thread.hpp>
  712. #include <boost/date_time/posix_time/posix_time_types.hpp>
  713. ]],[[
  714. #if BOOST_VERSION <= 105600
  715. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  716. #else
  717. choke me
  718. #endif
  719. ]])],
  720. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  721. [boost_sleep=no])
  722. LIBS="$TEMP_LIBS"
  723. CPPFLAGS="$TEMP_CPPFLAGS"
  724. fi
  725. if test x$boost_sleep != xyes; then
  726. AC_MSG_ERROR(No working boost sleep implementation found.)
  727. fi
  728. fi
  729. if test x$use_pkgconfig = xyes; then
  730. : dnl
  731. m4_ifdef(
  732. [PKG_CHECK_MODULES],
  733. [
  734. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  735. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  736. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  737. if test x$use_qr != xno; then
  738. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  739. fi
  740. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  741. PKG_CHECK_MODULES([EVENT], [libevent],, [AC_MSG_ERROR(libevent not found.)])
  742. if test x$TARGET_OS != xwindows; then
  743. PKG_CHECK_MODULES([EVENT_PTHREADS], [libevent_pthreads],, [AC_MSG_ERROR(libevent_pthreads not found.)])
  744. fi
  745. fi
  746. if test "x$use_zmq" = "xyes"; then
  747. PKG_CHECK_MODULES([ZMQ],[libzmq >= 4],
  748. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  749. [AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  750. AC_MSG_WARN([libzmq version 4.x or greater not found, disabling])
  751. use_zmq=no])
  752. else
  753. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  754. fi
  755. ]
  756. )
  757. else
  758. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  759. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  760. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  761. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  762. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  763. AC_CHECK_HEADER([event2/event.h],, AC_MSG_ERROR(libevent headers missing),)
  764. AC_CHECK_LIB([event],[main],EVENT_LIBS=-levent,AC_MSG_ERROR(libevent missing))
  765. if test x$TARGET_OS != xwindows; then
  766. AC_CHECK_LIB([event_pthreads],[main],EVENT_PTHREADS_LIBS=-levent_pthreads,AC_MSG_ERROR(libevent_pthreads missing))
  767. fi
  768. fi
  769. if test "x$use_zmq" = "xyes"; then
  770. AC_CHECK_HEADER([zmq.h],
  771. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  772. [AC_MSG_WARN([zmq.h not found, disabling zmq support])
  773. use_zmq=no
  774. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  775. AC_CHECK_LIB([zmq],[zmq_ctx_shutdown],ZMQ_LIBS=-lzmq,
  776. [AC_MSG_WARN([libzmq >= 4.0 not found, disabling zmq support])
  777. use_zmq=no
  778. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  779. else
  780. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  781. fi
  782. if test "x$use_zmq" = "xyes"; then
  783. dnl Assume libzmq was built for static linking
  784. case $host in
  785. *mingw*)
  786. ZMQ_CFLAGS="$ZMQ_CFLAGS -DZMQ_STATIC"
  787. ;;
  788. esac
  789. fi
  790. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],[PROTOBUF_LIBS=-lprotobuf], BITCOIN_QT_FAIL(libprotobuf not found)))
  791. if test x$use_qr != xno; then
  792. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],[QR_LIBS=-lqrencode], [have_qrencode=no])])
  793. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  794. fi
  795. fi
  796. save_CXXFLAGS="${CXXFLAGS}"
  797. CXXFLAGS="${CXXFLAGS} ${CRYPTO_CFLAGS} ${SSL_CFLAGS}"
  798. AC_CHECK_DECLS([EVP_MD_CTX_new],,,[AC_INCLUDES_DEFAULT
  799. #include <openssl/x509_vfy.h>
  800. ])
  801. CXXFLAGS="${save_CXXFLAGS}"
  802. dnl univalue check
  803. need_bundled_univalue=yes
  804. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  805. need_bundled_univalue=no
  806. else
  807. if test x$system_univalue != xno ; then
  808. found_univalue=no
  809. if test x$use_pkgconfig = xyes; then
  810. : #NOP
  811. m4_ifdef(
  812. [PKG_CHECK_MODULES],
  813. [
  814. PKG_CHECK_MODULES([UNIVALUE],[libunivalue],[found_univalue=yes],[true])
  815. ]
  816. )
  817. else
  818. AC_CHECK_HEADER([univalue.h],[
  819. AC_CHECK_LIB([univalue], [main],[
  820. UNIVALUE_LIBS=-lunivalue
  821. found_univalue=yes
  822. ],[true])
  823. ],[true])
  824. fi
  825. if test x$found_univalue = xyes ; then
  826. system_univalue=yes
  827. need_bundled_univalue=no
  828. elif test x$system_univalue = xyes ; then
  829. AC_MSG_ERROR([univalue not found])
  830. else
  831. system_univalue=no
  832. fi
  833. fi
  834. if test x$need_bundled_univalue = xyes ; then
  835. UNIVALUE_CFLAGS='-I$(srcdir)/univalue/include'
  836. UNIVALUE_LIBS='univalue/libunivalue.la'
  837. fi
  838. fi
  839. AM_CONDITIONAL([EMBEDDED_UNIVALUE],[test x$need_bundled_univalue = xyes])
  840. AC_SUBST(UNIVALUE_CFLAGS)
  841. AC_SUBST(UNIVALUE_LIBS)
  842. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  843. AC_MSG_CHECKING([whether to build bitcoind])
  844. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  845. AC_MSG_RESULT($build_bitcoind)
  846. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  847. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  848. AC_MSG_RESULT($build_bitcoin_utils)
  849. AC_MSG_CHECKING([whether to build libraries])
  850. AM_CONDITIONAL([BUILD_BITCOIN_LIBS], [test x$build_bitcoin_libs = xyes])
  851. if test x$build_bitcoin_libs = xyes; then
  852. AC_DEFINE(HAVE_CONSENSUS_LIB, 1, [Define this symbol if the consensus lib has been built])
  853. AC_CONFIG_FILES([libbitcoinconsensus.pc:libbitcoinconsensus.pc.in])
  854. fi
  855. AC_MSG_RESULT($build_bitcoin_libs)
  856. AC_LANG_POP
  857. if test "x$use_ccache" != "xno"; then
  858. AC_MSG_CHECKING(if ccache should be used)
  859. if test x$CCACHE = x; then
  860. if test "x$use_ccache" = "xyes"; then
  861. AC_MSG_ERROR([ccache not found.]);
  862. else
  863. use_ccache=no
  864. fi
  865. else
  866. use_ccache=yes
  867. CC="$ac_cv_path_CCACHE $CC"
  868. CXX="$ac_cv_path_CCACHE $CXX"
  869. fi
  870. AC_MSG_RESULT($use_ccache)
  871. fi
  872. if test "x$use_ccache" = "xyes"; then
  873. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  874. fi
  875. dnl enable wallet
  876. AC_MSG_CHECKING([if wallet should be enabled])
  877. if test x$enable_wallet != xno; then
  878. AC_MSG_RESULT(yes)
  879. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  880. else
  881. AC_MSG_RESULT(no)
  882. fi
  883. dnl enable upnp support
  884. AC_MSG_CHECKING([whether to build with support for UPnP])
  885. if test x$have_miniupnpc = xno; then
  886. if test x$use_upnp = xyes; then
  887. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  888. fi
  889. AC_MSG_RESULT(no)
  890. else
  891. if test x$use_upnp != xno; then
  892. AC_MSG_RESULT(yes)
  893. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  894. use_upnp=yes
  895. upnp_setting=0
  896. if test x$use_upnp_default != xno; then
  897. use_upnp_default=yes
  898. upnp_setting=1
  899. fi
  900. AC_MSG_RESULT($use_upnp_default)
  901. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  902. if test x$TARGET_OS = xwindows; then
  903. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  904. fi
  905. else
  906. AC_MSG_RESULT(no)
  907. fi
  908. fi
  909. dnl these are only used when qt is enabled
  910. BUILD_TEST_QT=""
  911. if test x$bitcoin_enable_qt != xno; then
  912. dnl enable dbus support
  913. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  914. if test x$bitcoin_enable_qt_dbus != xno; then
  915. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  916. fi
  917. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  918. dnl enable qr support
  919. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  920. if test x$have_qrencode = xno; then
  921. if test x$use_qr = xyes; then
  922. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  923. fi
  924. AC_MSG_RESULT(no)
  925. else
  926. if test x$use_qr != xno; then
  927. AC_MSG_RESULT(yes)
  928. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  929. use_qr=yes
  930. else
  931. AC_MSG_RESULT(no)
  932. fi
  933. fi
  934. if test x$XGETTEXT = x; then
  935. AC_MSG_WARN("xgettext is required to update qt translations")
  936. fi
  937. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  938. if test x$use_gui_tests$bitcoin_enable_qt_test = xyesyes; then
  939. AC_MSG_RESULT([yes])
  940. BUILD_TEST_QT="yes"
  941. else
  942. AC_MSG_RESULT([no])
  943. fi
  944. fi
  945. AM_CONDITIONAL([ENABLE_ZMQ], [test "x$use_zmq" = "xyes"])
  946. AC_MSG_CHECKING([whether to build test_bitcoin])
  947. if test x$use_tests = xyes; then
  948. AC_MSG_RESULT([yes])
  949. BUILD_TEST="yes"
  950. else
  951. AC_MSG_RESULT([no])
  952. BUILD_TEST=""
  953. fi
  954. AC_MSG_CHECKING([whether to reduce exports])
  955. if test x$use_reduce_exports = xyes; then
  956. AC_MSG_RESULT([yes])
  957. else
  958. AC_MSG_RESULT([no])
  959. fi
  960. if test x$build_bitcoin_utils$build_bitcoin_libs$build_bitcoind$bitcoin_enable_qt$use_bench$use_tests = xnononononono; then
  961. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-libs --with-daemon --with-gui --enable-bench or --enable-tests])
  962. fi
  963. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  964. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  965. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  966. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  967. AM_CONDITIONAL([ENABLE_TESTS],[test x$BUILD_TEST = xyes])
  968. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  969. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$BUILD_TEST_QT = xyes])
  970. AM_CONDITIONAL([ENABLE_BENCH],[test x$use_bench = xyes])
  971. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  972. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  973. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  974. AM_CONDITIONAL([HARDEN],[test x$use_hardening = xyes])
  975. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  976. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  977. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  978. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  979. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  980. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Copyright year])
  981. AC_DEFINE(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS", [Copyright holder(s) before %s replacement])
  982. AC_DEFINE(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION", [Replacement for %s in copyright holders string])
  983. define(_COPYRIGHT_HOLDERS_FINAL, [patsubst(_COPYRIGHT_HOLDERS, [%s], [_COPYRIGHT_HOLDERS_SUBSTITUTION])])
  984. AC_DEFINE(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL", [Copyright holder(s)])
  985. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  986. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  987. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  988. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  989. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  990. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  991. AC_SUBST(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS")
  992. AC_SUBST(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION")
  993. AC_SUBST(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL")
  994. AC_SUBST(BITCOIN_DAEMON_NAME)
  995. AC_SUBST(BITCOIN_GUI_NAME)
  996. AC_SUBST(BITCOIN_CLI_NAME)
  997. AC_SUBST(BITCOIN_TX_NAME)
  998. AC_SUBST(RELDFLAGS)
  999. AC_SUBST(ERROR_CXXFLAGS)
  1000. AC_SUBST(HARDENED_CXXFLAGS)
  1001. AC_SUBST(HARDENED_CPPFLAGS)
  1002. AC_SUBST(HARDENED_LDFLAGS)
  1003. AC_SUBST(PIC_FLAGS)
  1004. AC_SUBST(PIE_FLAGS)
  1005. AC_SUBST(LIBTOOL_APP_LDFLAGS)
  1006. AC_SUBST(USE_UPNP)
  1007. AC_SUBST(USE_QRCODE)
  1008. AC_SUBST(BOOST_LIBS)
  1009. AC_SUBST(TESTDEFS)
  1010. AC_SUBST(LEVELDB_TARGET_FLAGS)
  1011. AC_SUBST(MINIUPNPC_CPPFLAGS)
  1012. AC_SUBST(MINIUPNPC_LIBS)
  1013. AC_SUBST(CRYPTO_LIBS)
  1014. AC_SUBST(SSL_LIBS)
  1015. AC_SUBST(EVENT_LIBS)
  1016. AC_SUBST(EVENT_PTHREADS_LIBS)
  1017. AC_SUBST(ZMQ_LIBS)
  1018. AC_SUBST(PROTOBUF_LIBS)
  1019. AC_SUBST(QR_LIBS)
  1020. AC_CONFIG_FILES([Makefile src/Makefile doc/man/Makefile share/setup.nsi share/qt/Info.plist test/config.ini])
  1021. AC_CONFIG_FILES([contrib/devtools/split-debug.sh],[chmod +x contrib/devtools/split-debug.sh])
  1022. AC_CONFIG_FILES([doc/Doxyfile])
  1023. AC_CONFIG_LINKS([test/functional/test_runner.py:test/functional/test_runner.py])
  1024. AC_CONFIG_LINKS([test/util/bitcoin-util-test.py:test/util/bitcoin-util-test.py])
  1025. dnl boost's m4 checks do something really nasty: they export these vars. As a
  1026. dnl result, they leak into secp256k1's configure and crazy things happen.
  1027. dnl Until this is fixed upstream and we've synced, we'll just un-export them.
  1028. CPPFLAGS_TEMP="$CPPFLAGS"
  1029. unset CPPFLAGS
  1030. CPPFLAGS="$CPPFLAGS_TEMP"
  1031. LDFLAGS_TEMP="$LDFLAGS"
  1032. unset LDFLAGS
  1033. LDFLAGS="$LDFLAGS_TEMP"
  1034. LIBS_TEMP="$LIBS"
  1035. unset LIBS
  1036. LIBS="$LIBS_TEMP"
  1037. PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
  1038. unset PKG_CONFIG_PATH
  1039. PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
  1040. PKGCONFIG_LIBDIR_TEMP="$PKG_CONFIG_LIBDIR"
  1041. unset PKG_CONFIG_LIBDIR
  1042. PKG_CONFIG_LIBDIR="$PKGCONFIG_LIBDIR_TEMP"
  1043. if test x$need_bundled_univalue = xyes; then
  1044. AC_CONFIG_SUBDIRS([src/univalue])
  1045. fi
  1046. ac_configure_args="${ac_configure_args} --disable-shared --with-pic --with-bignum=no --enable-module-recovery"
  1047. AC_CONFIG_SUBDIRS([src/secp256k1])
  1048. AC_OUTPUT
  1049. dnl Taken from https://wiki.debian.org/RpathIssue
  1050. case $host in
  1051. *-*-linux-gnu)
  1052. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  1053. sed < libtool > libtool-2 \
  1054. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  1055. mv libtool-2 libtool
  1056. chmod 755 libtool
  1057. ;;
  1058. esac
  1059. dnl Replace the BUILDDIR path with the correct Windows path if compiling on Native Windows
  1060. case ${OS} in
  1061. *Windows*)
  1062. sed 's/BUILDDIR="\/\([[a-z]]\)/BUILDDIR="\1:/' test/config.ini > test/config-2.ini
  1063. mv test/config-2.ini test/config.ini
  1064. ;;
  1065. esac
  1066. echo
  1067. echo "Options used to compile and link:"
  1068. echo " with wallet = $enable_wallet"
  1069. echo " with gui / qt = $bitcoin_enable_qt"
  1070. if test x$bitcoin_enable_qt != xno; then
  1071. echo " qt version = $bitcoin_qt_got_major_vers"
  1072. echo " with qr = $use_qr"
  1073. fi
  1074. echo " with zmq = $use_zmq"
  1075. echo " with test = $use_tests"
  1076. echo " with bench = $use_bench"
  1077. echo " with upnp = $use_upnp"
  1078. echo " debug enabled = $enable_debug"
  1079. echo " werror = $enable_werror"
  1080. echo
  1081. echo " target os = $TARGET_OS"
  1082. echo " build os = $BUILD_OS"
  1083. echo
  1084. echo " CC = $CC"
  1085. echo " CFLAGS = $CFLAGS"
  1086. echo " CPPFLAGS = $CPPFLAGS"
  1087. echo " CXX = $CXX"
  1088. echo " CXXFLAGS = $CXXFLAGS"
  1089. echo " LDFLAGS = $LDFLAGS"
  1090. echo