You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 44KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485868788899091929394959697989910010110210310410510610710810911011111211311411511611711811912012112212312412512612712812913013113213313413513613713813914014114214314414514614714814915015115215315415515615715815916016116216316416516616716816917017117217317417517617717817918018118218318418518618718818919019119219319419519619719819920020120220320420520620720820921021121221321421521621721821922022122222322422522622722822923023123223323423523623723823924024124224324424524624724824925025125225325425525625725825926026126226326426526626726826927027127227327427527627727827928028128228328428528628728828929029129229329429529629729829930030130230330430530630730830931031131231331431531631731831932032132232332432532632732832933033133233333433533633733833934034134234334434534634734834935035135235335435535635735835936036136236336436536636736836937037137237337437537637737837938038138238338438538638738838939039139239339439539639739839940040140240340440540640740840941041141241341441541641741841942042142242342442542642742842943043143243343443543643743843944044144244344444544644744844945045145245345445545645745845946046146246346446546646746846947047147247347447547647747847948048148248348448548648748848949049149249349449549649749849950050150250350450550650750850951051151251351451551651751851952052152252352452552652752852953053153253353453553653753853954054154254354454554654754854955055155255355455555655755855956056156256356456556656756856957057157257357457557657757857958058158258358458558658758858959059159259359459559659759859960060160260360460560660760860961061161261361461561661761861962062162262362462562662762862963063163263363463563663763863964064164264364464564664764864965065165265365465565665765865966066166266366466566666766866967067167267367467567667767867968068168268368468568668768868969069169269369469569669769869970070170270370470570670770870971071171271371471571671771871972072172272372472572672772872973073173273373473573673773873974074174274374474574674774874975075175275375475575675775875976076176276376476576676776876977077177277377477577677777877978078178278378478578678778878979079179279379479579679779879980080180280380480580680780880981081181281381481581681781881982082182282382482582682782882983083183283383483583683783883984084184284384484584684784884985085185285385485585685785885986086186286386486586686786886987087187287387487587687787887988088188288388488588688788888989089189289389489589689789889990090190290390490590690790890991091191291391491591691791891992092192292392492592692792892993093193293393493593693793893994094194294394494594694794894995095195295395495595695795895996096196296396496596696796896997097197297397497597697797897998098198298398498598698798898999099199299399499599699799899910001001100210031004100510061007100810091010101110121013101410151016101710181019102010211022102310241025102610271028102910301031103210331034103510361037103810391040104110421043104410451046104710481049105010511052105310541055105610571058105910601061106210631064106510661067106810691070107110721073107410751076107710781079108010811082108310841085108610871088108910901091109210931094109510961097109810991100110111021103110411051106110711081109111011111112111311141115111611171118111911201121112211231124112511261127112811291130113111321133113411351136113711381139114011411142114311441145114611471148114911501151115211531154115511561157115811591160116111621163116411651166116711681169117011711172117311741175117611771178117911801181118211831184118511861187118811891190119111921193119411951196119711981199120012011202120312041205120612071208120912101211121212131214121512161217121812191220122112221223122412251226122712281229123012311232123312341235123612371238123912401241124212431244124512461247124812491250125112521253125412551256125712581259126012611262126312641265
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 14)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2017)
  9. define(_COPYRIGHT_HOLDERS,[The %s developers])
  10. define(_COPYRIGHT_HOLDERS_SUBSTITUTION,[[Bitcoin Core]])
  11. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[https://github.com/bitcoin/bitcoin/issues],[bitcoin],[https://bitcoincore.org/])
  12. AC_CONFIG_SRCDIR([src/validation.cpp])
  13. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  14. AC_CONFIG_AUX_DIR([build-aux])
  15. AC_CONFIG_MACRO_DIR([build-aux/m4])
  16. BITCOIN_DAEMON_NAME=bitcoind
  17. BITCOIN_GUI_NAME=bitcoin-qt
  18. BITCOIN_CLI_NAME=bitcoin-cli
  19. BITCOIN_TX_NAME=bitcoin-tx
  20. AC_CANONICAL_HOST
  21. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  22. AH_TOP([#define BITCOIN_CONFIG_H])
  23. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  24. dnl faketime breaks configure and is only needed for make. Disable it here.
  25. unset FAKETIME
  26. dnl Automake init set-up and checks
  27. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  28. dnl faketime messes with timestamps and causes configure to be re-run.
  29. dnl --disable-maintainer-mode can be used to bypass this.
  30. AM_MAINTAINER_MODE([enable])
  31. dnl make the compilation flags quiet unless V=1 is used
  32. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33. dnl Compiler checks (here before libtool).
  34. if test "x${CXXFLAGS+set}" = "xset"; then
  35. CXXFLAGS_overridden=yes
  36. else
  37. CXXFLAGS_overridden=no
  38. fi
  39. AC_PROG_CXX
  40. dnl By default, libtool for mingw refuses to link static libs into a dll for
  41. dnl fear of mixing pic/non-pic objects, and import/export complications. Since
  42. dnl we have those under control, re-enable that functionality.
  43. case $host in
  44. *mingw*)
  45. lt_cv_deplibs_check_method="pass_all"
  46. ;;
  47. esac
  48. dnl Require C++11 compiler (no GNU extensions)
  49. AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory], [nodefault])
  50. dnl Check if -latomic is required for <std::atomic>
  51. CHECK_ATOMIC
  52. dnl Unless the user specified OBJCXX, force it to be the same as CXX. This ensures
  53. dnl that we get the same -std flags for both.
  54. m4_ifdef([AC_PROG_OBJCXX],[
  55. if test "x${OBJCXX+set}" = "x"; then
  56. OBJCXX="${CXX}"
  57. fi
  58. AC_PROG_OBJCXX
  59. ])
  60. dnl Libtool init checks.
  61. LT_INIT([pic-only])
  62. dnl Check/return PATH for base programs.
  63. AC_PATH_TOOL(AR, ar)
  64. AC_PATH_TOOL(RANLIB, ranlib)
  65. AC_PATH_TOOL(STRIP, strip)
  66. AC_PATH_TOOL(GCOV, gcov)
  67. AC_PATH_PROG(LCOV, lcov)
  68. dnl Python 3.x is supported from 3.4 on (see https://github.com/bitcoin/bitcoin/issues/7893)
  69. AC_PATH_PROGS([PYTHON], [python3.6 python3.5 python3.4 python3 python2.7 python2 python])
  70. AC_PATH_PROG(GENHTML, genhtml)
  71. AC_PATH_PROG([GIT], [git])
  72. AC_PATH_PROG(CCACHE,ccache)
  73. AC_PATH_PROG(XGETTEXT,xgettext)
  74. AC_PATH_PROG(HEXDUMP,hexdump)
  75. AC_PATH_TOOL(READELF, readelf)
  76. AC_PATH_TOOL(CPPFILT, c++filt)
  77. AC_PATH_TOOL(OBJCOPY, objcopy)
  78. AC_ARG_VAR(PYTHONPATH, Augments the default search path for python module files)
  79. # Enable wallet
  80. AC_ARG_ENABLE([wallet],
  81. [AS_HELP_STRING([--disable-wallet],
  82. [disable wallet (enabled by default)])],
  83. [enable_wallet=$enableval],
  84. [enable_wallet=yes])
  85. AC_ARG_WITH([miniupnpc],
  86. [AS_HELP_STRING([--with-miniupnpc],
  87. [enable UPNP (default is yes if libminiupnpc is found)])],
  88. [use_upnp=$withval],
  89. [use_upnp=auto])
  90. AC_ARG_ENABLE([upnp-default],
  91. [AS_HELP_STRING([--enable-upnp-default],
  92. [if UPNP is enabled, turn it on at startup (default is no)])],
  93. [use_upnp_default=$enableval],
  94. [use_upnp_default=no])
  95. AC_ARG_ENABLE(tests,
  96. AS_HELP_STRING([--disable-tests],[do not compile tests (default is to compile)]),
  97. [use_tests=$enableval],
  98. [use_tests=yes])
  99. AC_ARG_ENABLE(gui-tests,
  100. AS_HELP_STRING([--disable-gui-tests],[do not compile GUI tests (default is to compile if GUI and tests enabled)]),
  101. [use_gui_tests=$enableval],
  102. [use_gui_tests=$use_tests])
  103. AC_ARG_ENABLE(bench,
  104. AS_HELP_STRING([--disable-bench],[do not compile benchmarks (default is to compile)]),
  105. [use_bench=$enableval],
  106. [use_bench=yes])
  107. AC_ARG_ENABLE([extended-functional-tests],
  108. AS_HELP_STRING([--enable-extended-functional-tests],[enable expensive functional tests when using lcov (default no)]),
  109. [use_extended_functional_tests=$enableval],
  110. [use_extended_functional_tests=no])
  111. AC_ARG_WITH([qrencode],
  112. [AS_HELP_STRING([--with-qrencode],
  113. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  114. [use_qr=$withval],
  115. [use_qr=auto])
  116. AC_ARG_ENABLE([hardening],
  117. [AS_HELP_STRING([--disable-hardening],
  118. [do not attempt to harden the resulting executables (default is to harden)])],
  119. [use_hardening=$enableval],
  120. [use_hardening=yes])
  121. AC_ARG_ENABLE([reduce-exports],
  122. [AS_HELP_STRING([--enable-reduce-exports],
  123. [attempt to reduce exported symbols in the resulting executables (default is no)])],
  124. [use_reduce_exports=$enableval],
  125. [use_reduce_exports=no])
  126. AC_ARG_ENABLE([ccache],
  127. [AS_HELP_STRING([--disable-ccache],
  128. [do not use ccache for building (default is to use if found)])],
  129. [use_ccache=$enableval],
  130. [use_ccache=auto])
  131. AC_ARG_ENABLE([lcov],
  132. [AS_HELP_STRING([--enable-lcov],
  133. [enable lcov testing (default is no)])],
  134. [use_lcov=yes],
  135. [use_lcov=no])
  136. AC_ARG_ENABLE([lcov-branch-coverage],
  137. [AS_HELP_STRING([--enable-lcov-branch-coverage],
  138. [enable lcov testing branch coverage (default is no)])],
  139. [use_lcov_branch=yes],
  140. [use_lcov_branch=no])
  141. AC_ARG_ENABLE([glibc-back-compat],
  142. [AS_HELP_STRING([--enable-glibc-back-compat],
  143. [enable backwards compatibility with glibc])],
  144. [use_glibc_compat=$enableval],
  145. [use_glibc_compat=no])
  146. AC_ARG_WITH([system-univalue],
  147. [AS_HELP_STRING([--with-system-univalue],
  148. [Build with system UniValue (default is no)])],
  149. [system_univalue=$withval],
  150. [system_univalue=no]
  151. )
  152. AC_ARG_ENABLE([zmq],
  153. [AS_HELP_STRING([--disable-zmq],
  154. [disable ZMQ notifications])],
  155. [use_zmq=$enableval],
  156. [use_zmq=yes])
  157. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  158. AC_ARG_ENABLE(man,
  159. [AS_HELP_STRING([--disable-man],
  160. [do not install man pages (default is to install)])],,
  161. enable_man=yes)
  162. AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
  163. # Enable debug
  164. AC_ARG_ENABLE([debug],
  165. [AS_HELP_STRING([--enable-debug],
  166. [use debug compiler flags and macros (default is no)])],
  167. [enable_debug=$enableval],
  168. [enable_debug=no])
  169. # Turn warnings into errors
  170. AC_ARG_ENABLE([werror],
  171. [AS_HELP_STRING([--enable-werror],
  172. [Treat certain compiler warnings as errors (default is no)])],
  173. [enable_werror=$enableval],
  174. [enable_werror=no])
  175. AC_LANG_PUSH([C++])
  176. AX_CHECK_COMPILE_FLAG([-Werror],[CXXFLAG_WERROR="-Werror"],[CXXFLAG_WERROR=""])
  177. if test "x$enable_debug" = xyes; then
  178. CPPFLAGS="$CPPFLAGS -DDEBUG -DDEBUG_LOCKORDER"
  179. if test "x$GCC" = xyes; then
  180. CFLAGS="$CFLAGS -g3 -O0"
  181. fi
  182. if test "x$GXX" = xyes; then
  183. CXXFLAGS="$CXXFLAGS -g3 -O0"
  184. fi
  185. fi
  186. ERROR_CXXFLAGS=
  187. if test "x$enable_werror" = "xyes"; then
  188. if test "x$CXXFLAG_WERROR" = "x"; then
  189. AC_MSG_ERROR("enable-werror set but -Werror is not usable")
  190. fi
  191. AX_CHECK_COMPILE_FLAG([-Werror=vla],[ERROR_CXXFLAGS="$ERROR_CXXFLAGS -Werror=vla"],,[[$CXXFLAG_WERROR]])
  192. fi
  193. if test "x$CXXFLAGS_overridden" = "xno"; then
  194. AX_CHECK_COMPILE_FLAG([-Wall],[CXXFLAGS="$CXXFLAGS -Wall"],,[[$CXXFLAG_WERROR]])
  195. AX_CHECK_COMPILE_FLAG([-Wextra],[CXXFLAGS="$CXXFLAGS -Wextra"],,[[$CXXFLAG_WERROR]])
  196. AX_CHECK_COMPILE_FLAG([-Wformat],[CXXFLAGS="$CXXFLAGS -Wformat"],,[[$CXXFLAG_WERROR]])
  197. AX_CHECK_COMPILE_FLAG([-Wvla],[CXXFLAGS="$CXXFLAGS -Wvla"],,[[$CXXFLAG_WERROR]])
  198. AX_CHECK_COMPILE_FLAG([-Wformat-security],[CXXFLAGS="$CXXFLAGS -Wformat-security"],,[[$CXXFLAG_WERROR]])
  199. ## Some compilers (gcc) ignore unknown -Wno-* options, but warn about all
  200. ## unknown options if any other warning is produced. Test the -Wfoo case, and
  201. ## set the -Wno-foo case if it works.
  202. AX_CHECK_COMPILE_FLAG([-Wunused-parameter],[CXXFLAGS="$CXXFLAGS -Wno-unused-parameter"],,[[$CXXFLAG_WERROR]])
  203. AX_CHECK_COMPILE_FLAG([-Wself-assign],[CXXFLAGS="$CXXFLAGS -Wno-self-assign"],,[[$CXXFLAG_WERROR]])
  204. AX_CHECK_COMPILE_FLAG([-Wunused-local-typedef],[CXXFLAGS="$CXXFLAGS -Wno-unused-local-typedef"],,[[$CXXFLAG_WERROR]])
  205. AX_CHECK_COMPILE_FLAG([-Wdeprecated-register],[CXXFLAGS="$CXXFLAGS -Wno-deprecated-register"],,[[$CXXFLAG_WERROR]])
  206. AX_CHECK_COMPILE_FLAG([-Wimplicit-fallthrough],[CXXFLAGS="$CXXFLAGS -Wno-implicit-fallthrough"],,[[$CXXFLAG_WERROR]])
  207. # Check for optional instruction set support. Enabling these does _not_ imply that all code will
  208. # be compiled with them, rather that specific objects/libs may use them after checking for runtime
  209. # compatibility.
  210. AX_CHECK_COMPILE_FLAG([-msse4.2],[[enable_sse42=yes; SSE42_CXXFLAGS="-msse4.2"]],,[[$CXXFLAG_WERROR]])
  211. fi
  212. CPPFLAGS="$CPPFLAGS -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  213. AC_ARG_WITH([utils],
  214. [AS_HELP_STRING([--with-utils],
  215. [build bitcoin-cli bitcoin-tx (default=yes)])],
  216. [build_bitcoin_utils=$withval],
  217. [build_bitcoin_utils=yes])
  218. AC_ARG_WITH([libs],
  219. [AS_HELP_STRING([--with-libs],
  220. [build libraries (default=yes)])],
  221. [build_bitcoin_libs=$withval],
  222. [build_bitcoin_libs=yes])
  223. AC_ARG_WITH([daemon],
  224. [AS_HELP_STRING([--with-daemon],
  225. [build bitcoind daemon (default=yes)])],
  226. [build_bitcoind=$withval],
  227. [build_bitcoind=yes])
  228. use_pkgconfig=yes
  229. case $host in
  230. *mingw*)
  231. #pkgconfig does more harm than good with MinGW
  232. use_pkgconfig=no
  233. TARGET_OS=windows
  234. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  235. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  236. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  237. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  238. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  239. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  240. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  241. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  242. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  243. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  244. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  245. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  246. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  247. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  248. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  249. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  250. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  251. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  252. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  253. # -static is interpreted by libtool, where it has a different meaning.
  254. # In libtool-speak, it's -all-static.
  255. AX_CHECK_LINK_FLAG([[-static]],[LIBTOOL_APP_LDFLAGS="$LIBTOOL_APP_LDFLAGS -all-static"])
  256. AC_PATH_PROG([MAKENSIS], [makensis], none)
  257. if test x$MAKENSIS = xnone; then
  258. AC_MSG_WARN("makensis not found. Cannot create installer.")
  259. fi
  260. AC_PATH_TOOL(WINDRES, windres, none)
  261. if test x$WINDRES = xnone; then
  262. AC_MSG_ERROR("windres not found")
  263. fi
  264. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  265. LEVELDB_TARGET_FLAGS="-DOS_WINDOWS"
  266. if test "x$CXXFLAGS_overridden" = "xno"; then
  267. CXXFLAGS="$CXXFLAGS -w"
  268. fi
  269. case $host in
  270. i?86-*) WINDOWS_BITS=32 ;;
  271. x86_64-*) WINDOWS_BITS=64 ;;
  272. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  273. esac
  274. AC_SUBST(WINDOWS_BITS)
  275. dnl libtool insists upon adding -nostdlib and a list of objects/libs to link against.
  276. dnl That breaks our ability to build dll's with static libgcc/libstdc++/libssp. Override
  277. dnl its command here, with the predeps/postdeps removed, and -static inserted. Postdeps are
  278. dnl also overridden to prevent their insertion later.
  279. dnl This should only affect dll's.
  280. archive_cmds_CXX="\$CC -shared \$libobjs \$deplibs \$compiler_flags -static -o \$output_objdir/\$soname \${wl}--enable-auto-image-base -Xlinker --out-implib -Xlinker \$lib"
  281. postdeps_CXX=
  282. ;;
  283. *darwin*)
  284. TARGET_OS=darwin
  285. LEVELDB_TARGET_FLAGS="-DOS_MACOSX"
  286. if test x$cross_compiling != xyes; then
  287. BUILD_OS=darwin
  288. AC_CHECK_PROG([PORT],port, port)
  289. if test x$PORT = xport; then
  290. dnl add default macports paths
  291. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  292. LIBS="$LIBS -L/opt/local/lib"
  293. if test -d /opt/local/include/db48; then
  294. CPPFLAGS="$CPPFLAGS -I/opt/local/include/db48"
  295. LIBS="$LIBS -L/opt/local/lib/db48"
  296. fi
  297. fi
  298. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  299. AC_CHECK_PROG([BREW],brew, brew)
  300. if test x$BREW = xbrew; then
  301. dnl These Homebrew packages may be keg-only, meaning that they won't be found
  302. dnl in expected paths because they may conflict with system files. Ask
  303. dnl Homebrew where each one is located, then adjust paths accordingly.
  304. dnl It's safe to add these paths even if the functionality is disabled by
  305. dnl the user (--without-wallet or --without-gui for example).
  306. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  307. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  308. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  309. if test x$openssl_prefix != x; then
  310. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  311. export PKG_CONFIG_PATH
  312. fi
  313. if test x$bdb_prefix != x; then
  314. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  315. LIBS="$LIBS -L$bdb_prefix/lib"
  316. fi
  317. if test x$qt5_prefix != x; then
  318. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  319. export PKG_CONFIG_PATH
  320. fi
  321. fi
  322. else
  323. case $build_os in
  324. *darwin*)
  325. BUILD_OS=darwin
  326. ;;
  327. *)
  328. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  329. AC_PATH_TOOL([OTOOL], [otool], otool)
  330. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  331. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  332. AC_PATH_PROGS([IMAGEMAGICK_CONVERT], [convert],convert)
  333. AC_PATH_PROGS([TIFFCP], [tiffcp],tiffcp)
  334. dnl libtool will try to strip the static lib, which is a problem for
  335. dnl cross-builds because strip attempts to call a hard-coded ld,
  336. dnl which may not exist in the path. Stripping the .a is not
  337. dnl necessary, so just disable it.
  338. old_striplib=
  339. ;;
  340. esac
  341. fi
  342. AX_CHECK_LINK_FLAG([[-Wl,-headerpad_max_install_names]], [LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"])
  343. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  344. OBJCXXFLAGS="$CXXFLAGS"
  345. ;;
  346. *linux*)
  347. TARGET_OS=linux
  348. LEVELDB_TARGET_FLAGS="-DOS_LINUX"
  349. ;;
  350. *freebsd*)
  351. LEVELDB_TARGET_FLAGS="-DOS_FREEBSD"
  352. ;;
  353. *openbsd*)
  354. LEVELDB_TARGET_FLAGS="-DOS_OPENBSD"
  355. ;;
  356. *)
  357. OTHER_OS=`echo ${host_os} | awk '{print toupper($0)}'`
  358. AC_MSG_WARN([Guessing LevelDB OS as OS_${OTHER_OS}, please check whether this is correct, if not add an entry to configure.ac.])
  359. LEVELDB_TARGET_FLAGS="-DOS_${OTHER_OS}"
  360. ;;
  361. esac
  362. if test x$use_pkgconfig = xyes; then
  363. m4_ifndef([PKG_PROG_PKG_CONFIG], [AC_MSG_ERROR(PKG_PROG_PKG_CONFIG macro not found. Please install pkg-config and re-run autogen.sh.)])
  364. m4_ifdef([PKG_PROG_PKG_CONFIG], [
  365. PKG_PROG_PKG_CONFIG
  366. if test x"$PKG_CONFIG" = "x"; then
  367. AC_MSG_ERROR(pkg-config not found.)
  368. fi
  369. ])
  370. fi
  371. if test x$use_extended_functional_tests != xno; then
  372. AC_SUBST(EXTENDED_FUNCTIONAL_TESTS, --extended)
  373. fi
  374. if test x$use_lcov = xyes; then
  375. if test x$LCOV = x; then
  376. AC_MSG_ERROR("lcov testing requested but lcov not found")
  377. fi
  378. if test x$GCOV = x; then
  379. AC_MSG_ERROR("lcov testing requested but gcov not found")
  380. fi
  381. if test x$PYTHON = x; then
  382. AC_MSG_ERROR("lcov testing requested but python not found")
  383. fi
  384. if test x$GENHTML = x; then
  385. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  386. fi
  387. LCOV="$LCOV --gcov-tool=$GCOV"
  388. AX_CHECK_LINK_FLAG([[--coverage]], [LDFLAGS="$LDFLAGS --coverage"],
  389. [AC_MSG_ERROR("lcov testing requested but --coverage linker flag does not work")])
  390. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  391. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  392. AC_DEFINE(USE_COVERAGE, 1, [Define this symbol if coverage is enabled])
  393. CXXFLAGS="$CXXFLAGS -Og"
  394. fi
  395. if test x$use_lcov_branch != xno; then
  396. AC_SUBST(LCOV_OPTS, "$LCOV_OPTS --rc lcov_branch_coverage=1")
  397. fi
  398. dnl Check for endianness
  399. AC_C_BIGENDIAN
  400. dnl Check for pthread compile/link requirements
  401. AX_PTHREAD
  402. # The following macro will add the necessary defines to bitcoin-config.h, but
  403. # they also need to be passed down to any subprojects. Pull the results out of
  404. # the cache and add them to CPPFLAGS.
  405. AC_SYS_LARGEFILE
  406. # detect POSIX or GNU variant of strerror_r
  407. AC_FUNC_STRERROR_R
  408. if test x$ac_cv_sys_file_offset_bits != x &&
  409. test x$ac_cv_sys_file_offset_bits != xno &&
  410. test x$ac_cv_sys_file_offset_bits != xunknown; then
  411. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  412. fi
  413. if test x$ac_cv_sys_large_files != x &&
  414. test x$ac_cv_sys_large_files != xno &&
  415. test x$ac_cv_sys_large_files != xunknown; then
  416. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  417. fi
  418. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  419. AX_GCC_FUNC_ATTRIBUTE([visibility])
  420. AX_GCC_FUNC_ATTRIBUTE([dllexport])
  421. AX_GCC_FUNC_ATTRIBUTE([dllimport])
  422. if test x$use_glibc_compat != xno; then
  423. #glibc absorbed clock_gettime in 2.17. librt (its previous location) is safe to link
  424. #in anyway for back-compat.
  425. AC_CHECK_LIB([rt],[clock_gettime],, AC_MSG_ERROR(lib missing))
  426. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  427. # See which one is present here.
  428. AC_MSG_CHECKING(__fdelt_chk type)
  429. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  430. #undef _FORTIFY_SOURCE
  431. #endif
  432. #define _FORTIFY_SOURCE 2
  433. #include <sys/select.h>
  434. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  435. [ fdelt_type="long unsigned int"],
  436. [ fdelt_type="long int"])
  437. AC_MSG_RESULT($fdelt_type)
  438. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  439. else
  440. AC_SEARCH_LIBS([clock_gettime],[rt])
  441. fi
  442. if test x$TARGET_OS != xwindows; then
  443. # All windows code is PIC, forcing it on just adds useless compile warnings
  444. AX_CHECK_COMPILE_FLAG([-fPIC],[PIC_FLAGS="-fPIC"])
  445. fi
  446. if test x$use_hardening != xno; then
  447. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  448. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  449. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  450. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  451. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  452. ])
  453. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  454. ])
  455. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  456. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  457. AX_CHECK_LINK_FLAG([[-Wl,--high-entropy-va]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--high-entropy-va"])
  458. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  459. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  460. if test x$TARGET_OS != xwindows; then
  461. AX_CHECK_COMPILE_FLAG([-fPIE],[PIE_FLAGS="-fPIE"])
  462. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  463. fi
  464. case $host in
  465. *mingw*)
  466. AC_CHECK_LIB([ssp], [main],, AC_MSG_ERROR(lib missing))
  467. ;;
  468. esac
  469. fi
  470. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  471. if test x$TARGET_OS = xdarwin; then
  472. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  473. fi
  474. AC_CHECK_HEADERS([endian.h sys/endian.h byteswap.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  475. AC_CHECK_DECLS([strnlen])
  476. # Check for daemon(3), unrelated to --with-daemon (although used by it)
  477. AC_CHECK_DECLS([daemon])
  478. AC_CHECK_DECLS([le16toh, le32toh, le64toh, htole16, htole32, htole64, be16toh, be32toh, be64toh, htobe16, htobe32, htobe64],,,
  479. [#if HAVE_ENDIAN_H
  480. #include <endian.h>
  481. #elif HAVE_SYS_ENDIAN_H
  482. #include <sys/endian.h>
  483. #endif])
  484. AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64],,,
  485. [#if HAVE_BYTESWAP_H
  486. #include <byteswap.h>
  487. #endif])
  488. AC_CHECK_DECLS([__builtin_clz, __builtin_clzl, __builtin_clzll])
  489. dnl Check for MSG_NOSIGNAL
  490. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  491. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  492. [[ int f = MSG_NOSIGNAL; ]])],
  493. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  494. [ AC_MSG_RESULT(no)]
  495. )
  496. dnl Check for MSG_DONTWAIT
  497. AC_MSG_CHECKING(for MSG_DONTWAIT)
  498. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  499. [[ int f = MSG_DONTWAIT; ]])],
  500. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_DONTWAIT, 1,[Define this symbol if you have MSG_DONTWAIT]) ],
  501. [ AC_MSG_RESULT(no)]
  502. )
  503. dnl Check for malloc_info (for memory statistics information in getmemoryinfo)
  504. AC_MSG_CHECKING(for getmemoryinfo)
  505. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  506. [[ int f = malloc_info(0, NULL); ]])],
  507. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MALLOC_INFO, 1,[Define this symbol if you have malloc_info]) ],
  508. [ AC_MSG_RESULT(no)]
  509. )
  510. dnl Check for mallopt(M_ARENA_MAX) (to set glibc arenas)
  511. AC_MSG_CHECKING(for mallopt M_ARENA_MAX)
  512. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  513. [[ mallopt(M_ARENA_MAX, 1); ]])],
  514. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MALLOPT_ARENA_MAX, 1,[Define this symbol if you have mallopt with M_ARENA_MAX]) ],
  515. [ AC_MSG_RESULT(no)]
  516. )
  517. AC_MSG_CHECKING([for visibility attribute])
  518. AC_LINK_IFELSE([AC_LANG_SOURCE([
  519. int foo_def( void ) __attribute__((visibility("default")));
  520. int main(){}
  521. ])],
  522. [
  523. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  524. AC_MSG_RESULT(yes)
  525. ],
  526. [
  527. AC_MSG_RESULT(no)
  528. if test x$use_reduce_exports = xyes; then
  529. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduce-exports.])
  530. fi
  531. ]
  532. )
  533. # Check for different ways of gathering OS randomness
  534. AC_MSG_CHECKING(for Linux getrandom syscall)
  535. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
  536. #include <sys/syscall.h>
  537. #include <linux/random.h>]],
  538. [[ syscall(SYS_getrandom, nullptr, 32, 0); ]])],
  539. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SYS_GETRANDOM, 1,[Define this symbol if the Linux getrandom system call is available]) ],
  540. [ AC_MSG_RESULT(no)]
  541. )
  542. AC_MSG_CHECKING(for getentropy)
  543. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>]],
  544. [[ getentropy(nullptr, 32) ]])],
  545. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_GETENTROPY, 1,[Define this symbol if the BSD getentropy system call is available]) ],
  546. [ AC_MSG_RESULT(no)]
  547. )
  548. AC_MSG_CHECKING(for sysctl KERN_ARND)
  549. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
  550. #include <sys/sysctl.h>]],
  551. [[ static const int name[2] = {CTL_KERN, KERN_ARND};
  552. sysctl(name, 2, nullptr, nullptr, nullptr, 0); ]])],
  553. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SYSCTL_ARND, 1,[Define this symbol if the BSD sysctl(KERN_ARND) is available]) ],
  554. [ AC_MSG_RESULT(no)]
  555. )
  556. # Check for reduced exports
  557. if test x$use_reduce_exports = xyes; then
  558. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  559. [AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduce-exports.])])
  560. fi
  561. LEVELDB_CPPFLAGS=
  562. LIBLEVELDB=
  563. LIBMEMENV=
  564. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  565. AC_SUBST(LEVELDB_CPPFLAGS)
  566. AC_SUBST(LIBLEVELDB)
  567. AC_SUBST(LIBMEMENV)
  568. if test x$enable_wallet != xno; then
  569. dnl Check for libdb_cxx only if wallet enabled
  570. BITCOIN_FIND_BDB48
  571. fi
  572. dnl Check for libminiupnpc (optional)
  573. if test x$use_upnp != xno; then
  574. AC_CHECK_HEADERS(
  575. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  576. [AC_CHECK_LIB([miniupnpc], [main],[MINIUPNPC_LIBS=-lminiupnpc], [have_miniupnpc=no])],
  577. [have_miniupnpc=no]
  578. )
  579. fi
  580. BITCOIN_QT_INIT
  581. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  582. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt5])
  583. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  584. use_boost=no
  585. else
  586. use_boost=yes
  587. fi
  588. if test x$use_boost = xyes; then
  589. dnl Minimum required Boost version
  590. define(MINIMUM_REQUIRED_BOOST, 1.47.0)
  591. dnl Check for boost libs
  592. AX_BOOST_BASE([MINIMUM_REQUIRED_BOOST])
  593. AX_BOOST_SYSTEM
  594. AX_BOOST_FILESYSTEM
  595. AX_BOOST_PROGRAM_OPTIONS
  596. AX_BOOST_THREAD
  597. AX_BOOST_CHRONO
  598. dnl Boost 1.56 through 1.62 allow using std::atomic instead of its own atomic
  599. dnl counter implementations. In 1.63 and later the std::atomic approach is default.
  600. m4_pattern_allow(DBOOST_AC_USE_STD_ATOMIC) dnl otherwise it's treated like a macro
  601. BOOST_CPPFLAGS="-DBOOST_SP_USE_STD_ATOMIC -DBOOST_AC_USE_STD_ATOMIC $BOOST_CPPFLAGS"
  602. if test x$use_reduce_exports = xyes; then
  603. AC_MSG_CHECKING([for working boost reduced exports])
  604. TEMP_CPPFLAGS="$CPPFLAGS"
  605. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  606. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  607. @%:@include <boost/version.hpp>
  608. ]], [[
  609. #if BOOST_VERSION >= 104900
  610. // Everything is okay
  611. #else
  612. # error Boost version is too old
  613. #endif
  614. ]])],[
  615. AC_MSG_RESULT(yes)
  616. ],[
  617. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduce-exports.])
  618. ])
  619. CPPFLAGS="$TEMP_CPPFLAGS"
  620. fi
  621. fi
  622. if test x$use_reduce_exports = xyes; then
  623. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  624. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  625. fi
  626. if test x$use_tests = xyes; then
  627. if test x$HEXDUMP = x; then
  628. AC_MSG_ERROR(hexdump is required for tests)
  629. fi
  630. if test x$use_boost = xyes; then
  631. AX_BOOST_UNIT_TEST_FRAMEWORK
  632. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  633. AC_MSG_CHECKING([for dynamic linked boost test])
  634. TEMP_LIBS="$LIBS"
  635. LIBS="$LIBS $BOOST_LDFLAGS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  636. TEMP_CPPFLAGS="$CPPFLAGS"
  637. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  638. AC_LINK_IFELSE([AC_LANG_SOURCE([
  639. #define BOOST_TEST_DYN_LINK
  640. #define BOOST_TEST_MAIN
  641. #include <boost/test/unit_test.hpp>
  642. ])],
  643. [AC_MSG_RESULT(yes)]
  644. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  645. [AC_MSG_RESULT(no)])
  646. LIBS="$TEMP_LIBS"
  647. CPPFLAGS="$TEMP_CPPFLAGS"
  648. fi
  649. fi
  650. if test x$use_boost = xyes; then
  651. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB $BOOST_CHRONO_LIB"
  652. dnl If boost (prior to 1.57) was built without c++11, it emulated scoped enums
  653. dnl using c++98 constructs. Unfortunately, this implementation detail leaked into
  654. dnl the abi. This was fixed in 1.57.
  655. dnl When building against that installed version using c++11, the headers pick up
  656. dnl on the native c++11 scoped enum support and enable it, however it will fail to
  657. dnl link. This can be worked around by disabling c++11 scoped enums if linking will
  658. dnl fail.
  659. dnl BOOST_NO_SCOPED_ENUMS was changed to BOOST_NO_CXX11_SCOPED_ENUMS in 1.51.
  660. TEMP_LIBS="$LIBS"
  661. LIBS="$BOOST_LIBS $LIBS"
  662. TEMP_CPPFLAGS="$CPPFLAGS"
  663. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  664. AC_MSG_CHECKING([for mismatched boost c++11 scoped enums])
  665. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  666. #include "boost/config.hpp"
  667. #include "boost/version.hpp"
  668. #if !defined(BOOST_NO_SCOPED_ENUMS) && !defined(BOOST_NO_CXX11_SCOPED_ENUMS) && BOOST_VERSION < 105700
  669. #define BOOST_NO_SCOPED_ENUMS
  670. #define BOOST_NO_CXX11_SCOPED_ENUMS
  671. #define CHECK
  672. #endif
  673. #include "boost/filesystem.hpp"
  674. ]],[[
  675. #if defined(CHECK)
  676. boost::filesystem::copy_file("foo", "bar");
  677. #else
  678. choke;
  679. #endif
  680. ]])],
  681. [AC_MSG_RESULT(mismatched); BOOST_CPPFLAGS="$BOOST_CPPFLAGS -DBOOST_NO_SCOPED_ENUMS -DBOOST_NO_CXX11_SCOPED_ENUMS"], [AC_MSG_RESULT(ok)])
  682. LIBS="$TEMP_LIBS"
  683. CPPFLAGS="$TEMP_CPPFLAGS"
  684. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  685. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  686. dnl a working version is available, else fall back to sleep. sleep was removed
  687. dnl after 1.56.
  688. dnl If neither is available, abort.
  689. TEMP_LIBS="$LIBS"
  690. LIBS="$BOOST_LIBS $LIBS"
  691. TEMP_CPPFLAGS="$CPPFLAGS"
  692. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  693. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  694. #include <boost/thread/thread.hpp>
  695. #include <boost/version.hpp>
  696. ]],[[
  697. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  698. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  699. #else
  700. choke me
  701. #endif
  702. ]])],
  703. [boost_sleep=yes;
  704. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  705. [boost_sleep=no])
  706. LIBS="$TEMP_LIBS"
  707. CPPFLAGS="$TEMP_CPPFLAGS"
  708. if test x$boost_sleep != xyes; then
  709. TEMP_LIBS="$LIBS"
  710. LIBS="$BOOST_LIBS $LIBS"
  711. TEMP_CPPFLAGS="$CPPFLAGS"
  712. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  713. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  714. #include <boost/version.hpp>
  715. #include <boost/thread.hpp>
  716. #include <boost/date_time/posix_time/posix_time_types.hpp>
  717. ]],[[
  718. #if BOOST_VERSION <= 105600
  719. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  720. #else
  721. choke me
  722. #endif
  723. ]])],
  724. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  725. [boost_sleep=no])
  726. LIBS="$TEMP_LIBS"
  727. CPPFLAGS="$TEMP_CPPFLAGS"
  728. fi
  729. if test x$boost_sleep != xyes; then
  730. AC_MSG_ERROR(No working boost sleep implementation found.)
  731. fi
  732. fi
  733. if test x$use_pkgconfig = xyes; then
  734. : dnl
  735. m4_ifdef(
  736. [PKG_CHECK_MODULES],
  737. [
  738. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  739. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  740. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  741. if test x$use_qr != xno; then
  742. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  743. fi
  744. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  745. PKG_CHECK_MODULES([EVENT], [libevent],, [AC_MSG_ERROR(libevent not found.)])
  746. if test x$TARGET_OS != xwindows; then
  747. PKG_CHECK_MODULES([EVENT_PTHREADS], [libevent_pthreads],, [AC_MSG_ERROR(libevent_pthreads not found.)])
  748. fi
  749. fi
  750. if test "x$use_zmq" = "xyes"; then
  751. PKG_CHECK_MODULES([ZMQ],[libzmq >= 4],
  752. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  753. [AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  754. AC_MSG_WARN([libzmq version 4.x or greater not found, disabling])
  755. use_zmq=no])
  756. else
  757. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  758. fi
  759. ]
  760. )
  761. else
  762. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  763. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  764. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  765. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  766. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  767. AC_CHECK_HEADER([event2/event.h],, AC_MSG_ERROR(libevent headers missing),)
  768. AC_CHECK_LIB([event],[main],EVENT_LIBS=-levent,AC_MSG_ERROR(libevent missing))
  769. if test x$TARGET_OS != xwindows; then
  770. AC_CHECK_LIB([event_pthreads],[main],EVENT_PTHREADS_LIBS=-levent_pthreads,AC_MSG_ERROR(libevent_pthreads missing))
  771. fi
  772. fi
  773. if test "x$use_zmq" = "xyes"; then
  774. AC_CHECK_HEADER([zmq.h],
  775. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  776. [AC_MSG_WARN([zmq.h not found, disabling zmq support])
  777. use_zmq=no
  778. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  779. AC_CHECK_LIB([zmq],[zmq_ctx_shutdown],ZMQ_LIBS=-lzmq,
  780. [AC_MSG_WARN([libzmq >= 4.0 not found, disabling zmq support])
  781. use_zmq=no
  782. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  783. else
  784. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  785. fi
  786. if test "x$use_zmq" = "xyes"; then
  787. dnl Assume libzmq was built for static linking
  788. case $host in
  789. *mingw*)
  790. ZMQ_CFLAGS="$ZMQ_CFLAGS -DZMQ_STATIC"
  791. ;;
  792. esac
  793. fi
  794. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],[PROTOBUF_LIBS=-lprotobuf], BITCOIN_QT_FAIL(libprotobuf not found)))
  795. if test x$use_qr != xno; then
  796. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],[QR_LIBS=-lqrencode], [have_qrencode=no])])
  797. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  798. fi
  799. fi
  800. save_CXXFLAGS="${CXXFLAGS}"
  801. CXXFLAGS="${CXXFLAGS} ${CRYPTO_CFLAGS} ${SSL_CFLAGS}"
  802. AC_CHECK_DECLS([EVP_MD_CTX_new],,,[AC_INCLUDES_DEFAULT
  803. #include <openssl/x509_vfy.h>
  804. ])
  805. CXXFLAGS="${save_CXXFLAGS}"
  806. dnl univalue check
  807. need_bundled_univalue=yes
  808. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  809. need_bundled_univalue=no
  810. else
  811. if test x$system_univalue != xno ; then
  812. found_univalue=no
  813. if test x$use_pkgconfig = xyes; then
  814. : #NOP
  815. m4_ifdef(
  816. [PKG_CHECK_MODULES],
  817. [
  818. PKG_CHECK_MODULES([UNIVALUE],[libunivalue],[found_univalue=yes],[true])
  819. ]
  820. )
  821. else
  822. AC_CHECK_HEADER([univalue.h],[
  823. AC_CHECK_LIB([univalue], [main],[
  824. UNIVALUE_LIBS=-lunivalue
  825. found_univalue=yes
  826. ],[true])
  827. ],[true])
  828. fi
  829. if test x$found_univalue = xyes ; then
  830. system_univalue=yes
  831. need_bundled_univalue=no
  832. elif test x$system_univalue = xyes ; then
  833. AC_MSG_ERROR([univalue not found])
  834. else
  835. system_univalue=no
  836. fi
  837. fi
  838. if test x$need_bundled_univalue = xyes ; then
  839. UNIVALUE_CFLAGS='-I$(srcdir)/univalue/include'
  840. UNIVALUE_LIBS='univalue/libunivalue.la'
  841. fi
  842. fi
  843. AM_CONDITIONAL([EMBEDDED_UNIVALUE],[test x$need_bundled_univalue = xyes])
  844. AC_SUBST(UNIVALUE_CFLAGS)
  845. AC_SUBST(UNIVALUE_LIBS)
  846. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  847. AC_MSG_CHECKING([whether to build bitcoind])
  848. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  849. AC_MSG_RESULT($build_bitcoind)
  850. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  851. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  852. AC_MSG_RESULT($build_bitcoin_utils)
  853. AC_MSG_CHECKING([whether to build libraries])
  854. AM_CONDITIONAL([BUILD_BITCOIN_LIBS], [test x$build_bitcoin_libs = xyes])
  855. if test x$build_bitcoin_libs = xyes; then
  856. AC_DEFINE(HAVE_CONSENSUS_LIB, 1, [Define this symbol if the consensus lib has been built])
  857. AC_CONFIG_FILES([libbitcoinconsensus.pc:libbitcoinconsensus.pc.in])
  858. fi
  859. AC_MSG_RESULT($build_bitcoin_libs)
  860. AC_LANG_POP
  861. if test "x$use_ccache" != "xno"; then
  862. AC_MSG_CHECKING(if ccache should be used)
  863. if test x$CCACHE = x; then
  864. if test "x$use_ccache" = "xyes"; then
  865. AC_MSG_ERROR([ccache not found.]);
  866. else
  867. use_ccache=no
  868. fi
  869. else
  870. use_ccache=yes
  871. CC="$ac_cv_path_CCACHE $CC"
  872. CXX="$ac_cv_path_CCACHE $CXX"
  873. fi
  874. AC_MSG_RESULT($use_ccache)
  875. fi
  876. if test "x$use_ccache" = "xyes"; then
  877. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  878. fi
  879. dnl enable wallet
  880. AC_MSG_CHECKING([if wallet should be enabled])
  881. if test x$enable_wallet != xno; then
  882. AC_MSG_RESULT(yes)
  883. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  884. else
  885. AC_MSG_RESULT(no)
  886. fi
  887. dnl enable upnp support
  888. AC_MSG_CHECKING([whether to build with support for UPnP])
  889. if test x$have_miniupnpc = xno; then
  890. if test x$use_upnp = xyes; then
  891. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  892. fi
  893. AC_MSG_RESULT(no)
  894. else
  895. if test x$use_upnp != xno; then
  896. AC_MSG_RESULT(yes)
  897. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  898. use_upnp=yes
  899. upnp_setting=0
  900. if test x$use_upnp_default != xno; then
  901. use_upnp_default=yes
  902. upnp_setting=1
  903. fi
  904. AC_MSG_RESULT($use_upnp_default)
  905. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  906. if test x$TARGET_OS = xwindows; then
  907. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  908. fi
  909. else
  910. AC_MSG_RESULT(no)
  911. fi
  912. fi
  913. dnl these are only used when qt is enabled
  914. BUILD_TEST_QT=""
  915. if test x$bitcoin_enable_qt != xno; then
  916. dnl enable dbus support
  917. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  918. if test x$bitcoin_enable_qt_dbus != xno; then
  919. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  920. fi
  921. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  922. dnl enable qr support
  923. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  924. if test x$have_qrencode = xno; then
  925. if test x$use_qr = xyes; then
  926. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  927. fi
  928. AC_MSG_RESULT(no)
  929. else
  930. if test x$use_qr != xno; then
  931. AC_MSG_RESULT(yes)
  932. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  933. use_qr=yes
  934. else
  935. AC_MSG_RESULT(no)
  936. fi
  937. fi
  938. if test x$XGETTEXT = x; then
  939. AC_MSG_WARN("xgettext is required to update qt translations")
  940. fi
  941. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  942. if test x$use_gui_tests$bitcoin_enable_qt_test = xyesyes; then
  943. AC_MSG_RESULT([yes])
  944. BUILD_TEST_QT="yes"
  945. else
  946. AC_MSG_RESULT([no])
  947. fi
  948. fi
  949. AM_CONDITIONAL([ENABLE_ZMQ], [test "x$use_zmq" = "xyes"])
  950. AC_MSG_CHECKING([whether to build test_bitcoin])
  951. if test x$use_tests = xyes; then
  952. AC_MSG_RESULT([yes])
  953. BUILD_TEST="yes"
  954. else
  955. AC_MSG_RESULT([no])
  956. BUILD_TEST=""
  957. fi
  958. AC_MSG_CHECKING([whether to reduce exports])
  959. if test x$use_reduce_exports = xyes; then
  960. AC_MSG_RESULT([yes])
  961. else
  962. AC_MSG_RESULT([no])
  963. fi
  964. if test x$build_bitcoin_utils$build_bitcoin_libs$build_bitcoind$bitcoin_enable_qt$use_bench$use_tests = xnononononono; then
  965. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-libs --with-daemon --with-gui --enable-bench or --enable-tests])
  966. fi
  967. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  968. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  969. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  970. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  971. AM_CONDITIONAL([ENABLE_TESTS],[test x$BUILD_TEST = xyes])
  972. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  973. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$BUILD_TEST_QT = xyes])
  974. AM_CONDITIONAL([ENABLE_BENCH],[test x$use_bench = xyes])
  975. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  976. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  977. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  978. AM_CONDITIONAL([HARDEN],[test x$use_hardening = xyes])
  979. AM_CONDITIONAL([ENABLE_SSE42],[test x$enable_sse42 = xyes])
  980. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  981. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  982. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  983. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  984. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  985. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Copyright year])
  986. AC_DEFINE(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS", [Copyright holder(s) before %s replacement])
  987. AC_DEFINE(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION", [Replacement for %s in copyright holders string])
  988. define(_COPYRIGHT_HOLDERS_FINAL, [patsubst(_COPYRIGHT_HOLDERS, [%s], [_COPYRIGHT_HOLDERS_SUBSTITUTION])])
  989. AC_DEFINE(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL", [Copyright holder(s)])
  990. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  991. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  992. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  993. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  994. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  995. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  996. AC_SUBST(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS")
  997. AC_SUBST(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION")
  998. AC_SUBST(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL")
  999. AC_SUBST(BITCOIN_DAEMON_NAME)
  1000. AC_SUBST(BITCOIN_GUI_NAME)
  1001. AC_SUBST(BITCOIN_CLI_NAME)
  1002. AC_SUBST(BITCOIN_TX_NAME)
  1003. AC_SUBST(RELDFLAGS)
  1004. AC_SUBST(ERROR_CXXFLAGS)
  1005. AC_SUBST(HARDENED_CXXFLAGS)
  1006. AC_SUBST(HARDENED_CPPFLAGS)
  1007. AC_SUBST(HARDENED_LDFLAGS)
  1008. AC_SUBST(PIC_FLAGS)
  1009. AC_SUBST(PIE_FLAGS)
  1010. AC_SUBST(SSE42_CXXFLAGS)
  1011. AC_SUBST(LIBTOOL_APP_LDFLAGS)
  1012. AC_SUBST(USE_UPNP)
  1013. AC_SUBST(USE_QRCODE)
  1014. AC_SUBST(BOOST_LIBS)
  1015. AC_SUBST(TESTDEFS)
  1016. AC_SUBST(LEVELDB_TARGET_FLAGS)
  1017. AC_SUBST(MINIUPNPC_CPPFLAGS)
  1018. AC_SUBST(MINIUPNPC_LIBS)
  1019. AC_SUBST(CRYPTO_LIBS)
  1020. AC_SUBST(SSL_LIBS)
  1021. AC_SUBST(EVENT_LIBS)
  1022. AC_SUBST(EVENT_PTHREADS_LIBS)
  1023. AC_SUBST(ZMQ_LIBS)
  1024. AC_SUBST(PROTOBUF_LIBS)
  1025. AC_SUBST(QR_LIBS)
  1026. AC_CONFIG_FILES([Makefile src/Makefile doc/man/Makefile share/setup.nsi share/qt/Info.plist test/config.ini])
  1027. AC_CONFIG_FILES([contrib/devtools/split-debug.sh],[chmod +x contrib/devtools/split-debug.sh])
  1028. AC_CONFIG_FILES([doc/Doxyfile])
  1029. AC_CONFIG_LINKS([test/functional/test_runner.py:test/functional/test_runner.py])
  1030. AC_CONFIG_LINKS([test/util/bitcoin-util-test.py:test/util/bitcoin-util-test.py])
  1031. dnl boost's m4 checks do something really nasty: they export these vars. As a
  1032. dnl result, they leak into secp256k1's configure and crazy things happen.
  1033. dnl Until this is fixed upstream and we've synced, we'll just un-export them.
  1034. CPPFLAGS_TEMP="$CPPFLAGS"
  1035. unset CPPFLAGS
  1036. CPPFLAGS="$CPPFLAGS_TEMP"
  1037. LDFLAGS_TEMP="$LDFLAGS"
  1038. unset LDFLAGS
  1039. LDFLAGS="$LDFLAGS_TEMP"
  1040. LIBS_TEMP="$LIBS"
  1041. unset LIBS
  1042. LIBS="$LIBS_TEMP"
  1043. PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
  1044. unset PKG_CONFIG_PATH
  1045. PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
  1046. PKGCONFIG_LIBDIR_TEMP="$PKG_CONFIG_LIBDIR"
  1047. unset PKG_CONFIG_LIBDIR
  1048. PKG_CONFIG_LIBDIR="$PKGCONFIG_LIBDIR_TEMP"
  1049. if test x$need_bundled_univalue = xyes; then
  1050. AC_CONFIG_SUBDIRS([src/univalue])
  1051. fi
  1052. ac_configure_args="${ac_configure_args} --disable-shared --with-pic --with-bignum=no --enable-module-recovery"
  1053. AC_CONFIG_SUBDIRS([src/secp256k1])
  1054. AC_OUTPUT
  1055. dnl Taken from https://wiki.debian.org/RpathIssue
  1056. case $host in
  1057. *-*-linux-gnu)
  1058. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  1059. sed < libtool > libtool-2 \
  1060. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  1061. mv libtool-2 libtool
  1062. chmod 755 libtool
  1063. ;;
  1064. esac
  1065. dnl Replace the BUILDDIR path with the correct Windows path if compiling on Native Windows
  1066. case ${OS} in
  1067. *Windows*)
  1068. sed 's/BUILDDIR="\/\([[a-z]]\)/BUILDDIR="\1:/' test/config.ini > test/config-2.ini
  1069. mv test/config-2.ini test/config.ini
  1070. ;;
  1071. esac
  1072. echo
  1073. echo "Options used to compile and link:"
  1074. echo " with wallet = $enable_wallet"
  1075. echo " with gui / qt = $bitcoin_enable_qt"
  1076. if test x$bitcoin_enable_qt != xno; then
  1077. echo " qt version = $bitcoin_qt_got_major_vers"
  1078. echo " with qr = $use_qr"
  1079. fi
  1080. echo " with zmq = $use_zmq"
  1081. echo " with test = $use_tests"
  1082. echo " with bench = $use_bench"
  1083. echo " with upnp = $use_upnp"
  1084. echo " debug enabled = $enable_debug"
  1085. echo " werror = $enable_werror"
  1086. echo
  1087. echo " target os = $TARGET_OS"
  1088. echo " build os = $BUILD_OS"
  1089. echo
  1090. echo " CC = $CC"
  1091. echo " CFLAGS = $CFLAGS"
  1092. echo " CPPFLAGS = $CPPFLAGS"
  1093. echo " CXX = $CXX"
  1094. echo " CXXFLAGS = $CXXFLAGS"
  1095. echo " LDFLAGS = $LDFLAGS"
  1096. echo