You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 30KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 11)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2015)
  9. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[https://github.com/bitcoin/bitcoin/issues],[bitcoin])
  10. AC_CONFIG_SRCDIR([src/main.cpp])
  11. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  12. AC_CONFIG_AUX_DIR([build-aux])
  13. AC_CONFIG_MACRO_DIR([build-aux/m4])
  14. AC_CANONICAL_HOST
  15. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  16. AH_TOP([#define BITCOIN_CONFIG_H])
  17. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  18. dnl faketime breaks configure and is only needed for make. Disable it here.
  19. unset FAKETIME
  20. dnl Automake init set-up and checks
  21. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  22. dnl faketime messes with timestamps and causes configure to be re-run.
  23. dnl --disable-maintainer-mode can be used to bypass this.
  24. AM_MAINTAINER_MODE([enable])
  25. dnl make the compilation flags quiet unless V=1 is used
  26. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  27. dnl Compiler checks (here before libtool).
  28. if test "x${CXXFLAGS+set}" = "xset"; then
  29. CXXFLAGS_overridden=yes
  30. else
  31. CXXFLAGS_overridden=no
  32. fi
  33. AC_PROG_CXX
  34. m4_ifdef([AC_PROG_OBJCXX],[AC_PROG_OBJCXX])
  35. dnl By default, libtool for mingw refuses to link static libs into a dll for
  36. dnl fear of mixing pic/non-pic objects, and import/export complications. Since
  37. dnl we have those under control, re-enable that functionality.
  38. case $host in
  39. *mingw*)
  40. lt_cv_deplibs_check_method="pass_all"
  41. ;;
  42. esac
  43. dnl Libtool init checks.
  44. LT_INIT([pic-only])
  45. dnl Check/return PATH for base programs.
  46. AC_PATH_TOOL(AR, ar)
  47. AC_PATH_TOOL(RANLIB, ranlib)
  48. AC_PATH_TOOL(STRIP, strip)
  49. AC_PATH_TOOL(GCOV, gcov)
  50. AC_PATH_PROG(LCOV, lcov)
  51. AC_PATH_PROG(JAVA, java)
  52. AC_PATH_PROG(GENHTML, genhtml)
  53. AC_PATH_PROG([GIT], [git])
  54. AC_PATH_PROG(CCACHE,ccache)
  55. AC_PATH_PROG(XGETTEXT,xgettext)
  56. AC_PATH_PROG(HEXDUMP,hexdump)
  57. dnl pkg-config check.
  58. PKG_PROG_PKG_CONFIG
  59. # Enable wallet
  60. AC_ARG_ENABLE([wallet],
  61. [AS_HELP_STRING([--enable-wallet],
  62. [enable wallet (default is yes)])],
  63. [enable_wallet=$enableval],
  64. [enable_wallet=yes])
  65. AC_ARG_WITH([miniupnpc],
  66. [AS_HELP_STRING([--with-miniupnpc],
  67. [enable UPNP (default is yes if libminiupnpc is found)])],
  68. [use_upnp=$withval],
  69. [use_upnp=auto])
  70. AC_ARG_ENABLE([upnp-default],
  71. [AS_HELP_STRING([--enable-upnp-default],
  72. [if UPNP is enabled, turn it on at startup (default is no)])],
  73. [use_upnp_default=$enableval],
  74. [use_upnp_default=no])
  75. AC_ARG_ENABLE(tests,
  76. AS_HELP_STRING([--enable-tests],[compile tests (default is yes)]),
  77. [use_tests=$enableval],
  78. [use_tests=yes])
  79. AC_ARG_WITH([comparison-tool],
  80. AS_HELP_STRING([--with-comparison-tool],[path to java comparison tool (requires --enable-tests)]),
  81. [use_comparison_tool=$withval],
  82. [use_comparison_tool=no])
  83. AC_ARG_ENABLE([comparison-tool-reorg-tests],
  84. AS_HELP_STRING([--enable-comparison-tool-reorg-tests],[enable expensive reorg tests in the comparison tool (default no)]),
  85. [use_comparison_tool_reorg_tests=$enableval],
  86. [use_comparison_tool_reorg_tests=no])
  87. AC_ARG_WITH([qrencode],
  88. [AS_HELP_STRING([--with-qrencode],
  89. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  90. [use_qr=$withval],
  91. [use_qr=auto])
  92. AC_ARG_ENABLE([hardening],
  93. [AS_HELP_STRING([--enable-hardening],
  94. [attempt to harden the resulting executables (default is yes)])],
  95. [use_hardening=$enableval],
  96. [use_hardening=yes])
  97. AC_ARG_ENABLE([reduce-exports],
  98. [AS_HELP_STRING([--enable-reduce-exports],
  99. [attempt to reduce exported symbols in the resulting executables (default is no)])],
  100. [use_reduce_exports=$enableval],
  101. [use_reduce_exports=no])
  102. AC_ARG_ENABLE([ccache],
  103. [AS_HELP_STRING([--enable-ccache],
  104. [use ccache for building (default is yes if ccache is found)])],
  105. [use_ccache=$enableval],
  106. [use_ccache=auto])
  107. AC_ARG_ENABLE([lcov],
  108. [AS_HELP_STRING([--enable-lcov],
  109. [enable lcov testing (default is no)])],
  110. [use_lcov=yes],
  111. [use_lcov=no])
  112. AC_ARG_ENABLE([glibc-back-compat],
  113. [AS_HELP_STRING([--enable-glibc-back-compat],
  114. [enable backwards compatibility with glibc])],
  115. [use_glibc_compat=$enableval],
  116. [use_glibc_compat=no])
  117. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  118. # Enable debug
  119. AC_ARG_ENABLE([debug],
  120. [AS_HELP_STRING([--enable-debug],
  121. [use debug compiler flags and macros (default is no)])],
  122. [enable_debug=$enableval],
  123. [enable_debug=no])
  124. if test "x$enable_debug" = xyes; then
  125. if test "x$GCC" = xyes; then
  126. CFLAGS="-g3 -O0 -DDEBUG"
  127. fi
  128. if test "x$GXX" = xyes; then
  129. CXXFLAGS="-g3 -O0 -DDEBUG"
  130. fi
  131. fi
  132. ## TODO: Remove these hard-coded paths and flags. They are here for the sake of
  133. ## compatibility with the legacy buildsystem.
  134. ##
  135. if test "x$CXXFLAGS_overridden" = "xno"; then
  136. CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter"
  137. fi
  138. CPPFLAGS="$CPPFLAGS -DBOOST_SPIRIT_THREADSAFE -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  139. AC_ARG_WITH([utils],
  140. [AS_HELP_STRING([--with-utils],
  141. [build bitcoin-cli bitcoin-tx (default=yes)])],
  142. [build_bitcoin_utils=$withval],
  143. [build_bitcoin_utils=yes])
  144. AC_ARG_WITH([libs],
  145. [AS_HELP_STRING([--with-libs],
  146. [build libraries (default=yes)])],
  147. [build_bitcoin_libs=$withval],
  148. [build_bitcoin_libs=yes])
  149. AC_ARG_WITH([daemon],
  150. [AS_HELP_STRING([--with-daemon],
  151. [build bitcoind daemon (default=yes)])],
  152. [build_bitcoind=$withval],
  153. [build_bitcoind=yes])
  154. AC_LANG_PUSH([C++])
  155. use_pkgconfig=yes
  156. case $host in
  157. *mingw*)
  158. #pkgconfig does more harm than good with MinGW
  159. use_pkgconfig=no
  160. TARGET_OS=windows
  161. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  162. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  163. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  164. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  165. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  166. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  167. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  168. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  169. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  170. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  171. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  172. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  173. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  174. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  175. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  176. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  177. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  178. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  179. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  180. # -static is interpreted by libtool, where it has a different meaning.
  181. # In libtool-speak, it's -all-static.
  182. AX_CHECK_LINK_FLAG([[-static]],[LIBTOOL_APP_LDFLAGS="$LIBTOOL_APP_LDFLAGS -all-static"])
  183. AC_PATH_PROG([MAKENSIS], [makensis], none)
  184. if test x$MAKENSIS = xnone; then
  185. AC_MSG_WARN("makensis not found. Cannot create installer.")
  186. fi
  187. AC_PATH_TOOL(WINDRES, windres, none)
  188. if test x$WINDRES = xnone; then
  189. AC_MSG_ERROR("windres not found")
  190. fi
  191. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  192. LEVELDB_TARGET_FLAGS="TARGET_OS=OS_WINDOWS_CROSSCOMPILE"
  193. if test "x$CXXFLAGS_overridden" = "xno"; then
  194. CXXFLAGS="$CXXFLAGS -w"
  195. fi
  196. case $host in
  197. i?86-*) WINDOWS_BITS=32 ;;
  198. x86_64-*) WINDOWS_BITS=64 ;;
  199. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  200. esac
  201. AC_SUBST(WINDOWS_BITS)
  202. dnl libtool insists upon adding -nostdlib and a list of objects/libs to link against.
  203. dnl That breaks our ability to build dll's with static libgcc/libstdc++/libssp. Override
  204. dnl its command here, with the predeps/postdeps removed, and -static inserted. Postdeps are
  205. dnl also overridden to prevent their insertion later.
  206. dnl This should only affect dll's.
  207. archive_cmds_CXX="\$CC -shared \$libobjs \$deplibs \$compiler_flags -static -o \$output_objdir/\$soname \${wl}--enable-auto-image-base -Xlinker --out-implib -Xlinker \$lib"
  208. postdeps_CXX=
  209. ;;
  210. *darwin*)
  211. TARGET_OS=darwin
  212. LEVELDB_TARGET_FLAGS="TARGET_OS=Darwin"
  213. if test x$cross_compiling != xyes; then
  214. BUILD_OS=darwin
  215. AC_CHECK_PROG([PORT],port, port)
  216. if test x$PORT = xport; then
  217. dnl add default macports paths
  218. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  219. LIBS="$LIBS -L/opt/local/lib"
  220. if test -d /opt/local/include/db48; then
  221. CPPFLAGS="$CPPFLAGS -I/opt/local/include/db48"
  222. LIBS="$LIBS -L/opt/local/lib/db48"
  223. fi
  224. fi
  225. AC_CHECK_PROG([BREW],brew, brew)
  226. if test x$BREW = xbrew; then
  227. dnl These Homebrew packages may be keg-only, meaning that they won't be found
  228. dnl in expected paths because they may conflict with system files. Ask
  229. dnl Homebrew where each one is located, then adjust paths accordingly.
  230. dnl It's safe to add these paths even if the functionality is disabled by
  231. dnl the user (--without-wallet or --without-gui for example).
  232. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  233. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  234. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  235. if test x$openssl_prefix != x; then
  236. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  237. export PKG_CONFIG_PATH
  238. fi
  239. if test x$bdb_prefix != x; then
  240. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  241. LIBS="$LIBS -L$bdb_prefix/lib"
  242. fi
  243. if test x$qt5_prefix != x; then
  244. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  245. export PKG_CONFIG_PATH
  246. fi
  247. fi
  248. else
  249. case $build_os in
  250. *darwin*)
  251. BUILD_OS=darwin
  252. ;;
  253. *)
  254. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  255. AC_PATH_TOOL([OTOOL], [otool], otool)
  256. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  257. dnl libtool will try to strip the static lib, which is a problem for
  258. dnl cross-builds because strip attempts to call a hard-coded ld,
  259. dnl which may not exist in the path. Stripping the .a is not
  260. dnl necessary, so just disable it.
  261. old_striplib=
  262. ;;
  263. esac
  264. fi
  265. AX_CHECK_LINK_FLAG([[-Wl,-headerpad_max_install_names]], [LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"])
  266. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  267. ;;
  268. *linux*)
  269. TARGET_OS=linux
  270. ;;
  271. *)
  272. ;;
  273. esac
  274. if test x$use_comparison_tool != xno; then
  275. AC_SUBST(JAVA_COMPARISON_TOOL, $use_comparison_tool)
  276. fi
  277. if test x$use_comparison_tool_reorg_tests != xno; then
  278. if test x$use_comparison_tool = x; then
  279. AC_MSG_ERROR("comparison tool reorg tests but comparison tool was not specified")
  280. fi
  281. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 1)
  282. else
  283. AC_SUBST(COMPARISON_TOOL_REORG_TESTS, 0)
  284. fi
  285. if test x$use_lcov = xyes; then
  286. if test x$LCOV = x; then
  287. AC_MSG_ERROR("lcov testing requested but lcov not found")
  288. fi
  289. if test x$GCOV = x; then
  290. AC_MSG_ERROR("lcov testing requested but gcov not found")
  291. fi
  292. if test x$JAVA = x; then
  293. AC_MSG_ERROR("lcov testing requested but java not found")
  294. fi
  295. if test x$GENHTML = x; then
  296. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  297. fi
  298. if test x$use_comparison_tool = x; then
  299. AC_MSG_ERROR("lcov testing requested but comparison tool was not specified")
  300. fi
  301. LCOV="$LCOV --gcov-tool=$GCOV"
  302. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  303. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  304. fi
  305. dnl Check for endianness
  306. AC_C_BIGENDIAN
  307. dnl Check for pthread compile/link requirements
  308. AX_PTHREAD
  309. # The following macro will add the necessary defines to bitcoin-config.h, but
  310. # they also need to be passed down to any subprojects. Pull the results out of
  311. # the cache and add them to CPPFLAGS.
  312. AC_SYS_LARGEFILE
  313. # detect POSIX or GNU variant of strerror_r
  314. AC_FUNC_STRERROR_R
  315. if test x$ac_cv_sys_file_offset_bits != x &&
  316. test x$ac_cv_sys_file_offset_bits != xno &&
  317. test x$ac_cv_sys_file_offset_bits != xunknown; then
  318. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  319. fi
  320. if test x$ac_cv_sys_large_files != x &&
  321. test x$ac_cv_sys_large_files != xno &&
  322. test x$ac_cv_sys_large_files != xunknown; then
  323. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  324. fi
  325. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  326. AX_GCC_FUNC_ATTRIBUTE([visibility])
  327. AX_GCC_FUNC_ATTRIBUTE([dllexport])
  328. AX_GCC_FUNC_ATTRIBUTE([dllimport])
  329. if test x$use_glibc_compat != xno; then
  330. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  331. # See which one is present here.
  332. AC_MSG_CHECKING(__fdelt_chk type)
  333. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  334. #undef _FORTIFY_SOURCE
  335. #endif
  336. #define _FORTIFY_SOURCE 2
  337. #include <sys/select.h>
  338. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  339. [ fdelt_type="long unsigned int"],
  340. [ fdelt_type="long int"])
  341. AC_MSG_RESULT($fdelt_type)
  342. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  343. fi
  344. if test x$use_hardening != xno; then
  345. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  346. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  347. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  348. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  349. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  350. ])
  351. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  352. ])
  353. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  354. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  355. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  356. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  357. if test x$TARGET_OS != xwindows; then
  358. # All windows code is PIC, forcing it on just adds useless compile warnings
  359. AX_CHECK_COMPILE_FLAG([-fPIE],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fPIE"])
  360. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  361. fi
  362. case $host in
  363. *mingw*)
  364. AC_CHECK_LIB([ssp], [main],, AC_MSG_ERROR(lib missing))
  365. ;;
  366. esac
  367. CXXFLAGS="$CXXFLAGS $HARDENED_CXXFLAGS"
  368. CPPFLAGS="$CPPFLAGS $HARDENED_CPPFLAGS"
  369. LDFLAGS="$LDFLAGS $HARDENED_LDFLAGS"
  370. OBJCXXFLAGS="$CXXFLAGS"
  371. fi
  372. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  373. if test x$TARGET_OS = xdarwin; then
  374. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  375. fi
  376. AC_CHECK_HEADERS([endian.h sys/endian.h byteswap.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  377. AC_SEARCH_LIBS([getaddrinfo_a], [anl], [AC_DEFINE(HAVE_GETADDRINFO_A, 1, [Define this symbol if you have getaddrinfo_a])])
  378. AC_SEARCH_LIBS([inet_pton], [nsl resolv], [AC_DEFINE(HAVE_INET_PTON, 1, [Define this symbol if you have inet_pton])])
  379. AC_CHECK_DECLS([strnlen])
  380. AC_CHECK_DECLS([le16toh, le32toh, le64toh, htole16, htole32, htole64, be16toh, be32toh, be64toh, htobe16, htobe32, htobe64],,,
  381. [#if HAVE_ENDIAN_H
  382. #include <endian.h>
  383. #elif HAVE_SYS_ENDIAN_H
  384. #include <sys/endian.h>
  385. #endif])
  386. AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64],,,
  387. [#if HAVE_BYTESWAP_H
  388. #include <byteswap.h>
  389. #endif])
  390. dnl Check for MSG_NOSIGNAL
  391. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  392. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  393. [[ int f = MSG_NOSIGNAL; ]])],
  394. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  395. [ AC_MSG_RESULT(no)]
  396. )
  397. AC_SEARCH_LIBS([clock_gettime],[rt])
  398. AC_MSG_CHECKING([for visibility attribute])
  399. AC_LINK_IFELSE([AC_LANG_SOURCE([
  400. int foo_def( void ) __attribute__((visibility("default")));
  401. int main(){}
  402. ])],
  403. [
  404. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  405. AC_MSG_RESULT(yes)
  406. ],
  407. [
  408. AC_MSG_RESULT(no)
  409. if test x$use_reduce_exports = xyes; then
  410. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduce-exports.])
  411. fi
  412. ]
  413. )
  414. if test x$use_reduce_exports = xyes; then
  415. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  416. [AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduce-exports.])])
  417. fi
  418. LEVELDB_CPPFLAGS=
  419. LIBLEVELDB=
  420. LIBMEMENV=
  421. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  422. AC_SUBST(LEVELDB_CPPFLAGS)
  423. AC_SUBST(LIBLEVELDB)
  424. AC_SUBST(LIBMEMENV)
  425. if test x$enable_wallet != xno; then
  426. dnl Check for libdb_cxx only if wallet enabled
  427. BITCOIN_FIND_BDB48
  428. fi
  429. dnl Check for libminiupnpc (optional)
  430. if test x$use_upnp != xno; then
  431. AC_CHECK_HEADERS(
  432. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  433. [AC_CHECK_LIB([miniupnpc], [main],[MINIUPNPC_LIBS=-lminiupnpc], [have_miniupnpc=no])],
  434. [have_miniupnpc=no]
  435. )
  436. fi
  437. BITCOIN_QT_INIT
  438. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  439. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt4])
  440. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests = xnononono; then
  441. use_boost=no
  442. else
  443. use_boost=yes
  444. fi
  445. if test x$use_boost = xyes; then
  446. dnl Check for boost libs
  447. AX_BOOST_BASE
  448. AX_BOOST_SYSTEM
  449. AX_BOOST_FILESYSTEM
  450. AX_BOOST_PROGRAM_OPTIONS
  451. AX_BOOST_THREAD
  452. AX_BOOST_CHRONO
  453. if test x$use_reduce_exports = xyes; then
  454. AC_MSG_CHECKING([for working boost reduced exports])
  455. TEMP_CPPFLAGS="$CPPFLAGS"
  456. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  457. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  458. @%:@include <boost/version.hpp>
  459. ]], [[
  460. #if BOOST_VERSION >= 104900
  461. // Everything is okay
  462. #else
  463. # error Boost version is too old
  464. #endif
  465. ]])],[
  466. AC_MSG_RESULT(yes)
  467. ],[
  468. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduce-exports.])
  469. ])
  470. CPPFLAGS="$TEMP_CPPFLAGS"
  471. fi
  472. fi
  473. if test x$use_reduce_exports = xyes; then
  474. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  475. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  476. fi
  477. if test x$use_tests = xyes; then
  478. if test x$HEXDUMP = x; then
  479. AC_MSG_ERROR(hexdump is required for tests)
  480. fi
  481. if test x$use_boost = xyes; then
  482. AX_BOOST_UNIT_TEST_FRAMEWORK
  483. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  484. AC_MSG_CHECKING([for dynamic linked boost test])
  485. TEMP_LIBS="$LIBS"
  486. LIBS="$LIBS $BOOST_LDFLAGS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  487. TEMP_CPPFLAGS="$CPPFLAGS"
  488. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  489. AC_LINK_IFELSE([AC_LANG_SOURCE([
  490. #define BOOST_TEST_DYN_LINK
  491. #define BOOST_TEST_MAIN
  492. #include <boost/test/unit_test.hpp>
  493. ])],
  494. [AC_MSG_RESULT(yes)]
  495. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  496. [AC_MSG_RESULT(no)])
  497. LIBS="$TEMP_LIBS"
  498. CPPFLAGS="$TEMP_CPPFLAGS"
  499. fi
  500. fi
  501. if test x$use_boost = xyes; then
  502. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB $BOOST_CHRONO_LIB"
  503. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  504. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  505. dnl a working version is available, else fall back to sleep. sleep was removed
  506. dnl after 1.56.
  507. dnl If neither is available, abort.
  508. TEMP_LIBS="$LIBS"
  509. LIBS="$BOOST_LIBS $LIBS"
  510. TEMP_CPPFLAGS="$CPPFLAGS"
  511. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  512. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  513. #include <boost/thread/thread.hpp>
  514. #include <boost/version.hpp>
  515. ]],[[
  516. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  517. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  518. #else
  519. choke me
  520. #endif
  521. ]])],
  522. [boost_sleep=yes;
  523. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  524. [boost_sleep=no])
  525. LIBS="$TEMP_LIBS"
  526. CPPFLAGS="$TEMP_CPPFLAGS"
  527. if test x$boost_sleep != xyes; then
  528. TEMP_LIBS="$LIBS"
  529. LIBS="$BOOST_LIBS $LIBS"
  530. TEMP_CPPFLAGS="$CPPFLAGS"
  531. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  532. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  533. #include <boost/version.hpp>
  534. #include <boost/thread.hpp>
  535. #include <boost/date_time/posix_time/posix_time_types.hpp>
  536. ]],[[
  537. #if BOOST_VERSION <= 105600
  538. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  539. #else
  540. choke me
  541. #endif
  542. ]])],
  543. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  544. [boost_sleep=no])
  545. LIBS="$TEMP_LIBS"
  546. CPPFLAGS="$TEMP_CPPFLAGS"
  547. fi
  548. if test x$boost_sleep != xyes; then
  549. AC_MSG_ERROR(No working boost sleep implementation found.)
  550. fi
  551. fi
  552. if test x$use_pkgconfig = xyes; then
  553. if test x"$PKG_CONFIG" = "x"; then
  554. AC_MSG_ERROR(pkg-config not found.)
  555. fi
  556. : #NOP
  557. m4_ifdef(
  558. [PKG_CHECK_MODULES],
  559. [
  560. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  561. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  562. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  563. if test x$use_qr != xno; then
  564. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  565. fi
  566. ]
  567. )
  568. else
  569. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  570. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  571. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  572. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  573. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],[PROTOBUF_LIBS=-lprotobuf], BITCOIN_QT_FAIL(libprotobuf not found)))
  574. if test x$use_qr != xno; then
  575. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],[QR_LIBS=-lqrencode], [have_qrencode=no])])
  576. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  577. fi
  578. fi
  579. CFLAGS_TEMP="$CFLAGS"
  580. LIBS_TEMP="$LIBS"
  581. CFLAGS="$CFLAGS $SSL_CFLAGS $CRYPTO_CFLAGS"
  582. LIBS="$LIBS $SSL_LIBS $CRYPTO_LIBS"
  583. AC_CHECK_HEADER([openssl/ec.h],, AC_MSG_ERROR(OpenSSL ec header missing),)
  584. CFLAGS="$CFLAGS_TEMP"
  585. LIBS="$LIBS_TEMP"
  586. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  587. AC_MSG_CHECKING([whether to build bitcoind])
  588. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  589. AC_MSG_RESULT($build_bitcoind)
  590. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  591. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  592. AC_MSG_RESULT($build_bitcoin_utils)
  593. AC_MSG_CHECKING([whether to build libraries])
  594. AM_CONDITIONAL([BUILD_BITCOIN_LIBS], [test x$build_bitcoin_libs = xyes])
  595. if test x$build_bitcoin_libs = xyes; then
  596. AC_DEFINE(HAVE_CONSENSUS_LIB, 1, [Define this symbol if the consensus lib has been built])
  597. AC_CONFIG_FILES([libbitcoinconsensus.pc:libbitcoinconsensus.pc.in])
  598. fi
  599. AC_MSG_RESULT($build_bitcoin_libs)
  600. AC_LANG_POP
  601. if test "x$use_ccache" != "xno"; then
  602. AC_MSG_CHECKING(if ccache should be used)
  603. if test x$CCACHE = x; then
  604. if test "x$use_ccache" = "xyes"; then
  605. AC_MSG_ERROR([ccache not found.]);
  606. else
  607. use_ccache=no
  608. fi
  609. else
  610. use_ccache=yes
  611. CC="$ac_cv_path_CCACHE $CC"
  612. CXX="$ac_cv_path_CCACHE $CXX"
  613. fi
  614. AC_MSG_RESULT($use_ccache)
  615. fi
  616. if test "x$use_ccache" = "xyes"; then
  617. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  618. fi
  619. dnl enable wallet
  620. AC_MSG_CHECKING([if wallet should be enabled])
  621. if test x$enable_wallet != xno; then
  622. AC_MSG_RESULT(yes)
  623. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  624. else
  625. AC_MSG_RESULT(no)
  626. fi
  627. dnl enable upnp support
  628. AC_MSG_CHECKING([whether to build with support for UPnP])
  629. if test x$have_miniupnpc = xno; then
  630. if test x$use_upnp = xyes; then
  631. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  632. fi
  633. AC_MSG_RESULT(no)
  634. else
  635. if test x$use_upnp != xno; then
  636. AC_MSG_RESULT(yes)
  637. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  638. use_upnp=yes
  639. upnp_setting=0
  640. if test x$use_upnp_default != xno; then
  641. use_upnp_default=yes
  642. upnp_setting=1
  643. fi
  644. AC_MSG_RESULT($use_upnp_default)
  645. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  646. if test x$TARGET_OS = xwindows; then
  647. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  648. fi
  649. else
  650. AC_MSG_RESULT(no)
  651. fi
  652. fi
  653. dnl these are only used when qt is enabled
  654. if test x$bitcoin_enable_qt != xno; then
  655. BUILD_QT=qt
  656. dnl enable dbus support
  657. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  658. if test x$bitcoin_enable_qt_dbus != xno; then
  659. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  660. fi
  661. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  662. dnl enable qr support
  663. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  664. if test x$have_qrencode = xno; then
  665. if test x$use_qr = xyes; then
  666. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  667. fi
  668. AC_MSG_RESULT(no)
  669. else
  670. if test x$use_qr != xno; then
  671. AC_MSG_RESULT(yes)
  672. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  673. use_qr=yes
  674. else
  675. AC_MSG_RESULT(no)
  676. fi
  677. fi
  678. if test x$XGETTEXT = x; then
  679. AC_MSG_WARN("xgettext is required to update qt translations")
  680. fi
  681. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  682. if test x$use_tests$bitcoin_enable_qt_test = xyesyes; then
  683. AC_MSG_RESULT([yes])
  684. BUILD_TEST_QT="test"
  685. else
  686. AC_MSG_RESULT([no])
  687. fi
  688. fi
  689. AC_MSG_CHECKING([whether to build test_bitcoin])
  690. if test x$use_tests = xyes; then
  691. AC_MSG_RESULT([yes])
  692. BUILD_TEST="test"
  693. else
  694. AC_MSG_RESULT([no])
  695. fi
  696. AC_MSG_CHECKING([whether to reduce exports])
  697. if test x$use_reduce_exports = xyes; then
  698. AC_MSG_RESULT([yes])
  699. else
  700. AC_MSG_RESULT([no])
  701. fi
  702. if test x$build_bitcoin_utils$build_bitcoin_libs$build_bitcoind$bitcoin_enable_qt$use_tests = xnonononono; then
  703. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-libs --with-daemon --with-gui or --enable-tests])
  704. fi
  705. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  706. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  707. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  708. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  709. AM_CONDITIONAL([ENABLE_TESTS],[test x$use_tests = xyes])
  710. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  711. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$use_tests$bitcoin_enable_qt_test = xyesyes])
  712. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  713. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  714. AM_CONDITIONAL([USE_COMPARISON_TOOL],[test x$use_comparison_tool != xno])
  715. AM_CONDITIONAL([USE_COMPARISON_TOOL_REORG_TESTS],[test x$use_comparison_tool_reorg_test != xno])
  716. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  717. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  718. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  719. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  720. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  721. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  722. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Version is release])
  723. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  724. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  725. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  726. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  727. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  728. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  729. AC_SUBST(RELDFLAGS)
  730. AC_SUBST(LIBTOOL_APP_LDFLAGS)
  731. AC_SUBST(USE_UPNP)
  732. AC_SUBST(USE_QRCODE)
  733. AC_SUBST(BOOST_LIBS)
  734. AC_SUBST(TESTDEFS)
  735. AC_SUBST(LEVELDB_TARGET_FLAGS)
  736. AC_SUBST(BUILD_TEST)
  737. AC_SUBST(BUILD_QT)
  738. AC_SUBST(BUILD_TEST_QT)
  739. AC_SUBST(MINIUPNPC_CPPFLAGS)
  740. AC_SUBST(MINIUPNPC_LIBS)
  741. AC_CONFIG_FILES([Makefile src/Makefile share/setup.nsi share/qt/Info.plist src/test/buildenv.py])
  742. AC_CONFIG_FILES([qa/pull-tester/run-bitcoind-for-test.sh],[chmod +x qa/pull-tester/run-bitcoind-for-test.sh])
  743. AC_CONFIG_FILES([qa/pull-tester/tests-config.sh],[chmod +x qa/pull-tester/tests-config.sh])
  744. dnl boost's m4 checks do something really nasty: they export these vars. As a
  745. dnl result, they leak into secp256k1's configure and crazy things happen.
  746. dnl Until this is fixed upstream and we've synced, we'll just un-export them.
  747. CPPFLAGS_TEMP="$CPPFLAGS"
  748. unset CPPFLAGS
  749. CPPFLAGS="$CPPFLAGS_TEMP"
  750. LDFLAGS_TEMP="$LDFLAGS"
  751. unset LDFLAGS
  752. LDFLAGS="$LDFLAGS_TEMP"
  753. LIBS_TEMP="$LIBS"
  754. unset LIBS
  755. LIBS="$LIBS_TEMP"
  756. PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
  757. unset PKG_CONFIG_PATH
  758. PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
  759. PKGCONFIG_LIBDIR_TEMP="$PKG_CONFIG_LIBDIR"
  760. unset PKG_CONFIG_LIBDIR
  761. PKG_CONFIG_LIBDIR="$PKGCONFIG_LIBDIR_TEMP"
  762. ac_configure_args="${ac_configure_args} --disable-shared --with-pic --with-bignum=no"
  763. AC_CONFIG_SUBDIRS([src/secp256k1])
  764. AC_OUTPUT
  765. dnl Taken from https://wiki.debian.org/RpathIssue
  766. case $host in
  767. *-*-linux-gnu)
  768. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  769. sed < libtool > libtool-2 \
  770. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  771. mv libtool-2 libtool
  772. chmod 755 libtool
  773. ;;
  774. esac