dotfiles/zsh/.zsh/completion/_cap

#compdef cap
# ------------------------------------------------------------------------------
# Copyright (c) 2016 Github zsh-users - http://github.com/zsh-users
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#     * Redistributions of source code must retain the above copyright
#       notice, this list of conditions and the following disclaimer.
#     * Redistributions in binary form must reproduce the above copyright
#       notice, this list of conditions and the following disclaimer in the
#       documentation and/or other materials provided with the distribution.
#     * Neither the name of the zsh-users nor the
#       names of its contributors may be used to endorse or promote products
#       derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL ZSH-USERS BE LIABLE FOR ANY
# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
# ------------------------------------------------------------------------------
# Description
# -----------
#
#  Completion script for Capistrano (http://capify.org).
#
# ------------------------------------------------------------------------------
# Authors
# -------
#
#  * Bruno Michel (https://github.com/nono)
#
# ------------------------------------------------------------------------------


local curcontext="$curcontext" state line cmds ret=1

_arguments -C \
	{-d,--debug}'[Prompts before each remote command execution]' \
    {-e,--explain}'[Displays help (if available) for the task]:task' \
    {-F,--default-config}'[Always use default config, even with -f]' \
    {-f,--file}'[A recipe file to load. May be given more than once]:file:_files' \
    {-H,--long-help}'[Explain these options and environment variables]' \
    {-h,--help}'[Display this help message]' \
    {-l,--logger}'[Choose logger method. STDERR used by default]:file:_files' \
    {-n,--dry-run}'[Prints out commands without running them]' \
    {-p,--password}'[Immediately prompt for the password]' \
    {-q,--quiet}'[Make the output as quiet as possible]' \
    {-r,--preserve-roles}'[Preserve task roles]' \
    {-S,--set-before}'[Set a variable before the recipes are loaded]:variable' \
    {-s,--set}'[Set a variable after the recipes are loaded]:variable' \
    {-T,--tasks}'[List all tasks (matching optional PATTERN) in the loaded recipe files]:pattern' \
    {-t,--tool}'[Abbreviates the output of -T for tool integration]' \
    {-V,--version}'[Display the Capistrano version, and exit]' \
    {-v,--verbose}'[Be more verbose. May be given more than once]' \
    {-X,--skip-system-config}'[Do not load the system config file (capistrano.conf)]' \
    {-x,--skip-user-config}'[Do not load the user config file (.caprc)]' \
	'*: :->cmds' && ret=0

case $state in
	cmds)
		cmds=( ${(f)"$(_call_program commands cap -T 2> /dev/null | sed -e '/ # /!d; s/:/\\:/g; s/cap \([A-Za-z0-9\\:_-]*\) .*# /\1:/')"} )
		_describe -t commands 'cap command' cmds && ret=0
		;;
esac

return ret

# Local Variables:
# mode: Shell-Script
# sh-indentation: 2
# indent-tabs-mode: nil
# sh-basic-offset: 2
# End:
# vim: ft=zsh sw=2 ts=2 et