You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

configure.ac 40KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168
  1. dnl require autoconf 2.60 (AS_ECHO/AS_ECHO_N)
  2. AC_PREREQ([2.60])
  3. define(_CLIENT_VERSION_MAJOR, 0)
  4. define(_CLIENT_VERSION_MINOR, 14)
  5. define(_CLIENT_VERSION_REVISION, 99)
  6. define(_CLIENT_VERSION_BUILD, 0)
  7. define(_CLIENT_VERSION_IS_RELEASE, false)
  8. define(_COPYRIGHT_YEAR, 2017)
  9. define(_COPYRIGHT_HOLDERS,[The %s developers])
  10. define(_COPYRIGHT_HOLDERS_SUBSTITUTION,[[Bitcoin Core]])
  11. AC_INIT([Bitcoin Core],[_CLIENT_VERSION_MAJOR._CLIENT_VERSION_MINOR._CLIENT_VERSION_REVISION],[https://github.com/bitcoin/bitcoin/issues],[bitcoin],[https://bitcoincore.org/])
  12. AC_CONFIG_SRCDIR([src/validation.cpp])
  13. AC_CONFIG_HEADERS([src/config/bitcoin-config.h])
  14. AC_CONFIG_AUX_DIR([build-aux])
  15. AC_CONFIG_MACRO_DIR([build-aux/m4])
  16. BITCOIN_DAEMON_NAME=bitcoind
  17. BITCOIN_GUI_NAME=bitcoin-qt
  18. BITCOIN_CLI_NAME=bitcoin-cli
  19. BITCOIN_TX_NAME=bitcoin-tx
  20. AC_CANONICAL_HOST
  21. AH_TOP([#ifndef BITCOIN_CONFIG_H])
  22. AH_TOP([#define BITCOIN_CONFIG_H])
  23. AH_BOTTOM([#endif //BITCOIN_CONFIG_H])
  24. dnl faketime breaks configure and is only needed for make. Disable it here.
  25. unset FAKETIME
  26. dnl Automake init set-up and checks
  27. AM_INIT_AUTOMAKE([no-define subdir-objects foreign])
  28. dnl faketime messes with timestamps and causes configure to be re-run.
  29. dnl --disable-maintainer-mode can be used to bypass this.
  30. AM_MAINTAINER_MODE([enable])
  31. dnl make the compilation flags quiet unless V=1 is used
  32. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33. dnl Compiler checks (here before libtool).
  34. if test "x${CXXFLAGS+set}" = "xset"; then
  35. CXXFLAGS_overridden=yes
  36. else
  37. CXXFLAGS_overridden=no
  38. fi
  39. AC_PROG_CXX
  40. dnl By default, libtool for mingw refuses to link static libs into a dll for
  41. dnl fear of mixing pic/non-pic objects, and import/export complications. Since
  42. dnl we have those under control, re-enable that functionality.
  43. case $host in
  44. *mingw*)
  45. lt_cv_deplibs_check_method="pass_all"
  46. ;;
  47. esac
  48. dnl Require C++11 compiler (no GNU extensions)
  49. AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory], [nodefault])
  50. dnl Check if -latomic is required for <std::atomic>
  51. CHECK_ATOMIC
  52. dnl Unless the user specified OBJCXX, force it to be the same as CXX. This ensures
  53. dnl that we get the same -std flags for both.
  54. m4_ifdef([AC_PROG_OBJCXX],[
  55. if test "x${OBJCXX+set}" = "x"; then
  56. OBJCXX="${CXX}"
  57. fi
  58. AC_PROG_OBJCXX
  59. ])
  60. dnl Libtool init checks.
  61. LT_INIT([pic-only])
  62. dnl Check/return PATH for base programs.
  63. AC_PATH_TOOL(AR, ar)
  64. AC_PATH_TOOL(RANLIB, ranlib)
  65. AC_PATH_TOOL(STRIP, strip)
  66. AC_PATH_TOOL(GCOV, gcov)
  67. AC_PATH_PROG(LCOV, lcov)
  68. dnl Python 3.x is supported from 3.4 on (see https://github.com/bitcoin/bitcoin/issues/7893)
  69. AC_PATH_PROGS([PYTHON], [python3.6 python3.5 python3.4 python3 python2.7 python2 python])
  70. AC_PATH_PROG(GENHTML, genhtml)
  71. AC_PATH_PROG([GIT], [git])
  72. AC_PATH_PROG(CCACHE,ccache)
  73. AC_PATH_PROG(XGETTEXT,xgettext)
  74. AC_PATH_PROG(HEXDUMP,hexdump)
  75. AC_PATH_TOOL(READELF, readelf)
  76. AC_PATH_TOOL(CPPFILT, c++filt)
  77. AC_PATH_TOOL(OBJCOPY, objcopy)
  78. AC_ARG_VAR(PYTHONPATH, Augments the default search path for python module files)
  79. # Enable wallet
  80. AC_ARG_ENABLE([wallet],
  81. [AS_HELP_STRING([--disable-wallet],
  82. [disable wallet (enabled by default)])],
  83. [enable_wallet=$enableval],
  84. [enable_wallet=yes])
  85. AC_ARG_WITH([miniupnpc],
  86. [AS_HELP_STRING([--with-miniupnpc],
  87. [enable UPNP (default is yes if libminiupnpc is found)])],
  88. [use_upnp=$withval],
  89. [use_upnp=auto])
  90. AC_ARG_ENABLE([upnp-default],
  91. [AS_HELP_STRING([--enable-upnp-default],
  92. [if UPNP is enabled, turn it on at startup (default is no)])],
  93. [use_upnp_default=$enableval],
  94. [use_upnp_default=no])
  95. AC_ARG_ENABLE(tests,
  96. AS_HELP_STRING([--disable-tests],[do not compile tests (default is to compile)]),
  97. [use_tests=$enableval],
  98. [use_tests=yes])
  99. AC_ARG_ENABLE(gui-tests,
  100. AS_HELP_STRING([--disable-gui-tests],[do not compile GUI tests (default is to compile if GUI and tests enabled)]),
  101. [use_gui_tests=$enableval],
  102. [use_gui_tests=$use_tests])
  103. AC_ARG_ENABLE(bench,
  104. AS_HELP_STRING([--disable-bench],[do not compile benchmarks (default is to compile)]),
  105. [use_bench=$enableval],
  106. [use_bench=yes])
  107. AC_ARG_ENABLE([extended-rpc-tests],
  108. AS_HELP_STRING([--enable-extended-rpc-tests],[enable expensive RPC tests when using lcov (default no)]),
  109. [use_extended_rpc_tests=$enableval],
  110. [use_extended_rpc_tests=no])
  111. AC_ARG_WITH([qrencode],
  112. [AS_HELP_STRING([--with-qrencode],
  113. [enable QR code support (default is yes if qt is enabled and libqrencode is found)])],
  114. [use_qr=$withval],
  115. [use_qr=auto])
  116. AC_ARG_ENABLE([hardening],
  117. [AS_HELP_STRING([--disable-hardening],
  118. [do not attempt to harden the resulting executables (default is to harden)])],
  119. [use_hardening=$enableval],
  120. [use_hardening=yes])
  121. AC_ARG_ENABLE([reduce-exports],
  122. [AS_HELP_STRING([--enable-reduce-exports],
  123. [attempt to reduce exported symbols in the resulting executables (default is no)])],
  124. [use_reduce_exports=$enableval],
  125. [use_reduce_exports=no])
  126. AC_ARG_ENABLE([ccache],
  127. [AS_HELP_STRING([--disable-ccache],
  128. [do not use ccache for building (default is to use if found)])],
  129. [use_ccache=$enableval],
  130. [use_ccache=auto])
  131. AC_ARG_ENABLE([lcov],
  132. [AS_HELP_STRING([--enable-lcov],
  133. [enable lcov testing (default is no)])],
  134. [use_lcov=yes],
  135. [use_lcov=no])
  136. AC_ARG_ENABLE([glibc-back-compat],
  137. [AS_HELP_STRING([--enable-glibc-back-compat],
  138. [enable backwards compatibility with glibc])],
  139. [use_glibc_compat=$enableval],
  140. [use_glibc_compat=no])
  141. AC_ARG_WITH([system-univalue],
  142. [AS_HELP_STRING([--with-system-univalue],
  143. [Build with system UniValue (default is no)])],
  144. [system_univalue=$withval],
  145. [system_univalue=no]
  146. )
  147. AC_ARG_ENABLE([zmq],
  148. [AS_HELP_STRING([--disable-zmq],
  149. [disable ZMQ notifications])],
  150. [use_zmq=$enableval],
  151. [use_zmq=yes])
  152. AC_ARG_WITH([protoc-bindir],[AS_HELP_STRING([--with-protoc-bindir=BIN_DIR],[specify protoc bin path])], [protoc_bin_path=$withval], [])
  153. AC_ARG_ENABLE(man,
  154. [AS_HELP_STRING([--disable-man],
  155. [do not install man pages (default is to install)])],,
  156. enable_man=yes)
  157. AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
  158. # Enable debug
  159. AC_ARG_ENABLE([debug],
  160. [AS_HELP_STRING([--enable-debug],
  161. [use debug compiler flags and macros (default is no)])],
  162. [enable_debug=$enableval],
  163. [enable_debug=no])
  164. AC_LANG_PUSH([C++])
  165. AX_CHECK_COMPILE_FLAG([-Werror],[CXXFLAG_WERROR="-Werror"],[CXXFLAG_WERROR=""])
  166. if test "x$enable_debug" = xyes; then
  167. CPPFLAGS="$CPPFLAGS -DDEBUG -DDEBUG_LOCKORDER"
  168. if test "x$GCC" = xyes; then
  169. CFLAGS="$CFLAGS -g3 -O0"
  170. fi
  171. if test "x$GXX" = xyes; then
  172. CXXFLAGS="$CXXFLAGS -g3 -O0"
  173. fi
  174. fi
  175. if test "x$CXXFLAGS_overridden" = "xno"; then
  176. AX_CHECK_COMPILE_FLAG([-Wall],[CXXFLAGS="$CXXFLAGS -Wall"],,[[$CXXFLAG_WERROR]])
  177. AX_CHECK_COMPILE_FLAG([-Wextra],[CXXFLAGS="$CXXFLAGS -Wextra"],,[[$CXXFLAG_WERROR]])
  178. AX_CHECK_COMPILE_FLAG([-Wformat],[CXXFLAGS="$CXXFLAGS -Wformat"],,[[$CXXFLAG_WERROR]])
  179. AX_CHECK_COMPILE_FLAG([-Wformat-security],[CXXFLAGS="$CXXFLAGS -Wformat-security"],,[[$CXXFLAG_WERROR]])
  180. ## Some compilers (gcc) ignore unknown -Wno-* options, but warn about all
  181. ## unknown options if any other warning is produced. Test the -Wfoo case, and
  182. ## set the -Wno-foo case if it works.
  183. AX_CHECK_COMPILE_FLAG([-Wunused-parameter],[CXXFLAGS="$CXXFLAGS -Wno-unused-parameter"],,[[$CXXFLAG_WERROR]])
  184. AX_CHECK_COMPILE_FLAG([-Wself-assign],[CXXFLAGS="$CXXFLAGS -Wno-self-assign"],,[[$CXXFLAG_WERROR]])
  185. AX_CHECK_COMPILE_FLAG([-Wunused-local-typedef],[CXXFLAGS="$CXXFLAGS -Wno-unused-local-typedef"],,[[$CXXFLAG_WERROR]])
  186. AX_CHECK_COMPILE_FLAG([-Wdeprecated-register],[CXXFLAGS="$CXXFLAGS -Wno-deprecated-register"],,[[$CXXFLAG_WERROR]])
  187. fi
  188. CPPFLAGS="$CPPFLAGS -DHAVE_BUILD_INFO -D__STDC_FORMAT_MACROS"
  189. AC_ARG_WITH([utils],
  190. [AS_HELP_STRING([--with-utils],
  191. [build bitcoin-cli bitcoin-tx (default=yes)])],
  192. [build_bitcoin_utils=$withval],
  193. [build_bitcoin_utils=yes])
  194. AC_ARG_WITH([libs],
  195. [AS_HELP_STRING([--with-libs],
  196. [build libraries (default=yes)])],
  197. [build_bitcoin_libs=$withval],
  198. [build_bitcoin_libs=yes])
  199. AC_ARG_WITH([daemon],
  200. [AS_HELP_STRING([--with-daemon],
  201. [build bitcoind daemon (default=yes)])],
  202. [build_bitcoind=$withval],
  203. [build_bitcoind=yes])
  204. use_pkgconfig=yes
  205. case $host in
  206. *mingw*)
  207. #pkgconfig does more harm than good with MinGW
  208. use_pkgconfig=no
  209. TARGET_OS=windows
  210. AC_CHECK_LIB([mingwthrd], [main],, AC_MSG_ERROR(lib missing))
  211. AC_CHECK_LIB([kernel32], [main],, AC_MSG_ERROR(lib missing))
  212. AC_CHECK_LIB([user32], [main],, AC_MSG_ERROR(lib missing))
  213. AC_CHECK_LIB([gdi32], [main],, AC_MSG_ERROR(lib missing))
  214. AC_CHECK_LIB([comdlg32], [main],, AC_MSG_ERROR(lib missing))
  215. AC_CHECK_LIB([winspool], [main],, AC_MSG_ERROR(lib missing))
  216. AC_CHECK_LIB([winmm], [main],, AC_MSG_ERROR(lib missing))
  217. AC_CHECK_LIB([shell32], [main],, AC_MSG_ERROR(lib missing))
  218. AC_CHECK_LIB([comctl32], [main],, AC_MSG_ERROR(lib missing))
  219. AC_CHECK_LIB([ole32], [main],, AC_MSG_ERROR(lib missing))
  220. AC_CHECK_LIB([oleaut32], [main],, AC_MSG_ERROR(lib missing))
  221. AC_CHECK_LIB([uuid], [main],, AC_MSG_ERROR(lib missing))
  222. AC_CHECK_LIB([rpcrt4], [main],, AC_MSG_ERROR(lib missing))
  223. AC_CHECK_LIB([advapi32], [main],, AC_MSG_ERROR(lib missing))
  224. AC_CHECK_LIB([ws2_32], [main],, AC_MSG_ERROR(lib missing))
  225. AC_CHECK_LIB([mswsock], [main],, AC_MSG_ERROR(lib missing))
  226. AC_CHECK_LIB([shlwapi], [main],, AC_MSG_ERROR(lib missing))
  227. AC_CHECK_LIB([iphlpapi], [main],, AC_MSG_ERROR(lib missing))
  228. AC_CHECK_LIB([crypt32], [main],, AC_MSG_ERROR(lib missing))
  229. # -static is interpreted by libtool, where it has a different meaning.
  230. # In libtool-speak, it's -all-static.
  231. AX_CHECK_LINK_FLAG([[-static]],[LIBTOOL_APP_LDFLAGS="$LIBTOOL_APP_LDFLAGS -all-static"])
  232. AC_PATH_PROG([MAKENSIS], [makensis], none)
  233. if test x$MAKENSIS = xnone; then
  234. AC_MSG_WARN("makensis not found. Cannot create installer.")
  235. fi
  236. AC_PATH_TOOL(WINDRES, windres, none)
  237. if test x$WINDRES = xnone; then
  238. AC_MSG_ERROR("windres not found")
  239. fi
  240. CPPFLAGS="$CPPFLAGS -D_MT -DWIN32 -D_WINDOWS -DBOOST_THREAD_USE_LIB"
  241. LEVELDB_TARGET_FLAGS="-DOS_WINDOWS"
  242. if test "x$CXXFLAGS_overridden" = "xno"; then
  243. CXXFLAGS="$CXXFLAGS -w"
  244. fi
  245. case $host in
  246. i?86-*) WINDOWS_BITS=32 ;;
  247. x86_64-*) WINDOWS_BITS=64 ;;
  248. *) AC_MSG_ERROR("Could not determine win32/win64 for installer") ;;
  249. esac
  250. AC_SUBST(WINDOWS_BITS)
  251. dnl libtool insists upon adding -nostdlib and a list of objects/libs to link against.
  252. dnl That breaks our ability to build dll's with static libgcc/libstdc++/libssp. Override
  253. dnl its command here, with the predeps/postdeps removed, and -static inserted. Postdeps are
  254. dnl also overridden to prevent their insertion later.
  255. dnl This should only affect dll's.
  256. archive_cmds_CXX="\$CC -shared \$libobjs \$deplibs \$compiler_flags -static -o \$output_objdir/\$soname \${wl}--enable-auto-image-base -Xlinker --out-implib -Xlinker \$lib"
  257. postdeps_CXX=
  258. ;;
  259. *darwin*)
  260. TARGET_OS=darwin
  261. LEVELDB_TARGET_FLAGS="-DOS_MACOSX"
  262. if test x$cross_compiling != xyes; then
  263. BUILD_OS=darwin
  264. AC_CHECK_PROG([PORT],port, port)
  265. if test x$PORT = xport; then
  266. dnl add default macports paths
  267. CPPFLAGS="$CPPFLAGS -isystem /opt/local/include"
  268. LIBS="$LIBS -L/opt/local/lib"
  269. if test -d /opt/local/include/db48; then
  270. CPPFLAGS="$CPPFLAGS -I/opt/local/include/db48"
  271. LIBS="$LIBS -L/opt/local/lib/db48"
  272. fi
  273. fi
  274. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  275. AC_CHECK_PROG([BREW],brew, brew)
  276. if test x$BREW = xbrew; then
  277. dnl These Homebrew packages may be keg-only, meaning that they won't be found
  278. dnl in expected paths because they may conflict with system files. Ask
  279. dnl Homebrew where each one is located, then adjust paths accordingly.
  280. dnl It's safe to add these paths even if the functionality is disabled by
  281. dnl the user (--without-wallet or --without-gui for example).
  282. openssl_prefix=`$BREW --prefix openssl 2>/dev/null`
  283. bdb_prefix=`$BREW --prefix berkeley-db4 2>/dev/null`
  284. qt5_prefix=`$BREW --prefix qt5 2>/dev/null`
  285. if test x$openssl_prefix != x; then
  286. PKG_CONFIG_PATH="$openssl_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  287. export PKG_CONFIG_PATH
  288. fi
  289. if test x$bdb_prefix != x; then
  290. CPPFLAGS="$CPPFLAGS -I$bdb_prefix/include"
  291. LIBS="$LIBS -L$bdb_prefix/lib"
  292. fi
  293. if test x$qt5_prefix != x; then
  294. PKG_CONFIG_PATH="$qt5_prefix/lib/pkgconfig:$PKG_CONFIG_PATH"
  295. export PKG_CONFIG_PATH
  296. fi
  297. fi
  298. else
  299. case $build_os in
  300. *darwin*)
  301. BUILD_OS=darwin
  302. ;;
  303. *)
  304. AC_PATH_TOOL([INSTALLNAMETOOL], [install_name_tool], install_name_tool)
  305. AC_PATH_TOOL([OTOOL], [otool], otool)
  306. AC_PATH_PROGS([GENISOIMAGE], [genisoimage mkisofs],genisoimage)
  307. AC_PATH_PROGS([RSVG_CONVERT], [rsvg-convert rsvg],rsvg-convert)
  308. AC_PATH_PROGS([IMAGEMAGICK_CONVERT], [convert],convert)
  309. AC_PATH_PROGS([TIFFCP], [tiffcp],tiffcp)
  310. dnl libtool will try to strip the static lib, which is a problem for
  311. dnl cross-builds because strip attempts to call a hard-coded ld,
  312. dnl which may not exist in the path. Stripping the .a is not
  313. dnl necessary, so just disable it.
  314. old_striplib=
  315. ;;
  316. esac
  317. fi
  318. AX_CHECK_LINK_FLAG([[-Wl,-headerpad_max_install_names]], [LDFLAGS="$LDFLAGS -Wl,-headerpad_max_install_names"])
  319. CPPFLAGS="$CPPFLAGS -DMAC_OSX"
  320. OBJCXXFLAGS="$CXXFLAGS"
  321. ;;
  322. *linux*)
  323. TARGET_OS=linux
  324. LEVELDB_TARGET_FLAGS="-DOS_LINUX"
  325. ;;
  326. *freebsd*)
  327. LEVELDB_TARGET_FLAGS="-DOS_FREEBSD"
  328. ;;
  329. *openbsd*)
  330. LEVELDB_TARGET_FLAGS="-DOS_OPENBSD"
  331. ;;
  332. *)
  333. OTHER_OS=`echo ${host_os} | awk '{print toupper($0)}'`
  334. AC_MSG_WARN([Guessing LevelDB OS as OS_${OTHER_OS}, please check whether this is correct, if not add an entry to configure.ac.])
  335. LEVELDB_TARGET_FLAGS="-DOS_${OTHER_OS}"
  336. ;;
  337. esac
  338. if test x$use_pkgconfig = xyes; then
  339. m4_ifndef([PKG_PROG_PKG_CONFIG], [AC_MSG_ERROR(PKG_PROG_PKG_CONFIG macro not found. Please install pkg-config and re-run autogen.sh.)])
  340. m4_ifdef([PKG_PROG_PKG_CONFIG], [
  341. PKG_PROG_PKG_CONFIG
  342. if test x"$PKG_CONFIG" = "x"; then
  343. AC_MSG_ERROR(pkg-config not found.)
  344. fi
  345. ])
  346. fi
  347. if test x$use_extended_rpc_tests != xno; then
  348. AC_SUBST(EXTENDED_RPC_TESTS, -extended)
  349. fi
  350. if test x$use_lcov = xyes; then
  351. if test x$LCOV = x; then
  352. AC_MSG_ERROR("lcov testing requested but lcov not found")
  353. fi
  354. if test x$GCOV = x; then
  355. AC_MSG_ERROR("lcov testing requested but gcov not found")
  356. fi
  357. if test x$PYTHON = x; then
  358. AC_MSG_ERROR("lcov testing requested but python not found")
  359. fi
  360. if test x$GENHTML = x; then
  361. AC_MSG_ERROR("lcov testing requested but genhtml not found")
  362. fi
  363. LCOV="$LCOV --gcov-tool=$GCOV"
  364. AX_CHECK_LINK_FLAG([[--coverage]], [LDFLAGS="$LDFLAGS --coverage"],
  365. [AC_MSG_ERROR("lcov testing requested but --coverage linker flag does not work")])
  366. AX_CHECK_COMPILE_FLAG([--coverage],[CXXFLAGS="$CXXFLAGS --coverage"],
  367. [AC_MSG_ERROR("lcov testing requested but --coverage flag does not work")])
  368. fi
  369. dnl Check for endianness
  370. AC_C_BIGENDIAN
  371. dnl Check for pthread compile/link requirements
  372. AX_PTHREAD
  373. # The following macro will add the necessary defines to bitcoin-config.h, but
  374. # they also need to be passed down to any subprojects. Pull the results out of
  375. # the cache and add them to CPPFLAGS.
  376. AC_SYS_LARGEFILE
  377. # detect POSIX or GNU variant of strerror_r
  378. AC_FUNC_STRERROR_R
  379. if test x$ac_cv_sys_file_offset_bits != x &&
  380. test x$ac_cv_sys_file_offset_bits != xno &&
  381. test x$ac_cv_sys_file_offset_bits != xunknown; then
  382. CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
  383. fi
  384. if test x$ac_cv_sys_large_files != x &&
  385. test x$ac_cv_sys_large_files != xno &&
  386. test x$ac_cv_sys_large_files != xunknown; then
  387. CPPFLAGS="$CPPFLAGS -D_LARGE_FILES=$ac_cv_sys_large_files"
  388. fi
  389. AX_CHECK_LINK_FLAG([[-Wl,--large-address-aware]], [LDFLAGS="$LDFLAGS -Wl,--large-address-aware"])
  390. AX_GCC_FUNC_ATTRIBUTE([visibility])
  391. AX_GCC_FUNC_ATTRIBUTE([dllexport])
  392. AX_GCC_FUNC_ATTRIBUTE([dllimport])
  393. if test x$use_glibc_compat != xno; then
  394. #glibc absorbed clock_gettime in 2.17. librt (its previous location) is safe to link
  395. #in anyway for back-compat.
  396. AC_CHECK_LIB([rt],[clock_gettime],, AC_MSG_ERROR(lib missing))
  397. #__fdelt_chk's params and return type have changed from long unsigned int to long int.
  398. # See which one is present here.
  399. AC_MSG_CHECKING(__fdelt_chk type)
  400. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef _FORTIFY_SOURCE
  401. #undef _FORTIFY_SOURCE
  402. #endif
  403. #define _FORTIFY_SOURCE 2
  404. #include <sys/select.h>
  405. extern "C" long unsigned int __fdelt_warn(long unsigned int);]],[[]])],
  406. [ fdelt_type="long unsigned int"],
  407. [ fdelt_type="long int"])
  408. AC_MSG_RESULT($fdelt_type)
  409. AC_DEFINE_UNQUOTED(FDELT_TYPE, $fdelt_type,[parameter and return value type for __fdelt_chk])
  410. else
  411. AC_SEARCH_LIBS([clock_gettime],[rt])
  412. fi
  413. if test x$TARGET_OS != xwindows; then
  414. # All windows code is PIC, forcing it on just adds useless compile warnings
  415. AX_CHECK_COMPILE_FLAG([-fPIC],[PIC_FLAGS="-fPIC"])
  416. fi
  417. if test x$use_hardening != xno; then
  418. AX_CHECK_COMPILE_FLAG([-Wstack-protector],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -Wstack-protector"])
  419. AX_CHECK_COMPILE_FLAG([-fstack-protector-all],[HARDENED_CXXFLAGS="$HARDENED_CXXFLAGS -fstack-protector-all"])
  420. AX_CHECK_PREPROC_FLAG([-D_FORTIFY_SOURCE=2],[
  421. AX_CHECK_PREPROC_FLAG([-U_FORTIFY_SOURCE],[
  422. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -U_FORTIFY_SOURCE"
  423. ])
  424. HARDENED_CPPFLAGS="$HARDENED_CPPFLAGS -D_FORTIFY_SOURCE=2"
  425. ])
  426. AX_CHECK_LINK_FLAG([[-Wl,--dynamicbase]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--dynamicbase"])
  427. AX_CHECK_LINK_FLAG([[-Wl,--nxcompat]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--nxcompat"])
  428. AX_CHECK_LINK_FLAG([[-Wl,--high-entropy-va]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,--high-entropy-va"])
  429. AX_CHECK_LINK_FLAG([[-Wl,-z,relro]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,relro"])
  430. AX_CHECK_LINK_FLAG([[-Wl,-z,now]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -Wl,-z,now"])
  431. if test x$TARGET_OS != xwindows; then
  432. AX_CHECK_COMPILE_FLAG([-fPIE],[PIE_FLAGS="-fPIE"])
  433. AX_CHECK_LINK_FLAG([[-pie]], [HARDENED_LDFLAGS="$HARDENED_LDFLAGS -pie"])
  434. fi
  435. case $host in
  436. *mingw*)
  437. AC_CHECK_LIB([ssp], [main],, AC_MSG_ERROR(lib missing))
  438. ;;
  439. esac
  440. fi
  441. dnl this flag screws up non-darwin gcc even when the check fails. special-case it.
  442. if test x$TARGET_OS = xdarwin; then
  443. AX_CHECK_LINK_FLAG([[-Wl,-dead_strip]], [LDFLAGS="$LDFLAGS -Wl,-dead_strip"])
  444. fi
  445. AC_CHECK_HEADERS([endian.h sys/endian.h byteswap.h stdio.h stdlib.h unistd.h strings.h sys/types.h sys/stat.h sys/select.h sys/prctl.h])
  446. AC_CHECK_DECLS([strnlen])
  447. # Check for daemon(3), unrelated to --with-daemon (although used by it)
  448. AC_CHECK_DECLS([daemon])
  449. AC_CHECK_DECLS([le16toh, le32toh, le64toh, htole16, htole32, htole64, be16toh, be32toh, be64toh, htobe16, htobe32, htobe64],,,
  450. [#if HAVE_ENDIAN_H
  451. #include <endian.h>
  452. #elif HAVE_SYS_ENDIAN_H
  453. #include <sys/endian.h>
  454. #endif])
  455. AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64],,,
  456. [#if HAVE_BYTESWAP_H
  457. #include <byteswap.h>
  458. #endif])
  459. dnl Check for MSG_NOSIGNAL
  460. AC_MSG_CHECKING(for MSG_NOSIGNAL)
  461. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  462. [[ int f = MSG_NOSIGNAL; ]])],
  463. [ AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MSG_NOSIGNAL, 1,[Define this symbol if you have MSG_NOSIGNAL]) ],
  464. [ AC_MSG_RESULT(no)]
  465. )
  466. AC_MSG_CHECKING([for visibility attribute])
  467. AC_LINK_IFELSE([AC_LANG_SOURCE([
  468. int foo_def( void ) __attribute__((visibility("default")));
  469. int main(){}
  470. ])],
  471. [
  472. AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE,1,[Define if the visibility attribute is supported.])
  473. AC_MSG_RESULT(yes)
  474. ],
  475. [
  476. AC_MSG_RESULT(no)
  477. if test x$use_reduce_exports = xyes; then
  478. AC_MSG_ERROR([Cannot find a working visibility attribute. Use --disable-reduce-exports.])
  479. fi
  480. ]
  481. )
  482. if test x$use_reduce_exports = xyes; then
  483. AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],[RE_CXXFLAGS="-fvisibility=hidden"],
  484. [AC_MSG_ERROR([Cannot set default symbol visibility. Use --disable-reduce-exports.])])
  485. fi
  486. LEVELDB_CPPFLAGS=
  487. LIBLEVELDB=
  488. LIBMEMENV=
  489. AM_CONDITIONAL([EMBEDDED_LEVELDB],[true])
  490. AC_SUBST(LEVELDB_CPPFLAGS)
  491. AC_SUBST(LIBLEVELDB)
  492. AC_SUBST(LIBMEMENV)
  493. if test x$enable_wallet != xno; then
  494. dnl Check for libdb_cxx only if wallet enabled
  495. BITCOIN_FIND_BDB48
  496. fi
  497. dnl Check for libminiupnpc (optional)
  498. if test x$use_upnp != xno; then
  499. AC_CHECK_HEADERS(
  500. [miniupnpc/miniwget.h miniupnpc/miniupnpc.h miniupnpc/upnpcommands.h miniupnpc/upnperrors.h],
  501. [AC_CHECK_LIB([miniupnpc], [main],[MINIUPNPC_LIBS=-lminiupnpc], [have_miniupnpc=no])],
  502. [have_miniupnpc=no]
  503. )
  504. fi
  505. BITCOIN_QT_INIT
  506. dnl sets $bitcoin_enable_qt, $bitcoin_enable_qt_test, $bitcoin_enable_qt_dbus
  507. BITCOIN_QT_CONFIGURE([$use_pkgconfig], [qt5])
  508. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  509. use_boost=no
  510. else
  511. use_boost=yes
  512. fi
  513. if test x$use_boost = xyes; then
  514. dnl Minimum required Boost version
  515. define(MINIMUM_REQUIRED_BOOST, 1.47.0)
  516. dnl Check for boost libs
  517. AX_BOOST_BASE([MINIMUM_REQUIRED_BOOST])
  518. AX_BOOST_SYSTEM
  519. AX_BOOST_FILESYSTEM
  520. AX_BOOST_PROGRAM_OPTIONS
  521. AX_BOOST_THREAD
  522. AX_BOOST_CHRONO
  523. if test x$use_reduce_exports = xyes; then
  524. AC_MSG_CHECKING([for working boost reduced exports])
  525. TEMP_CPPFLAGS="$CPPFLAGS"
  526. CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
  527. AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
  528. @%:@include <boost/version.hpp>
  529. ]], [[
  530. #if BOOST_VERSION >= 104900
  531. // Everything is okay
  532. #else
  533. # error Boost version is too old
  534. #endif
  535. ]])],[
  536. AC_MSG_RESULT(yes)
  537. ],[
  538. AC_MSG_ERROR([boost versions < 1.49 are known to be broken with reduced exports. Use --disable-reduce-exports.])
  539. ])
  540. CPPFLAGS="$TEMP_CPPFLAGS"
  541. fi
  542. fi
  543. if test x$use_reduce_exports = xyes; then
  544. CXXFLAGS="$CXXFLAGS $RE_CXXFLAGS"
  545. AX_CHECK_LINK_FLAG([[-Wl,--exclude-libs,ALL]], [RELDFLAGS="-Wl,--exclude-libs,ALL"])
  546. fi
  547. if test x$use_tests = xyes; then
  548. if test x$HEXDUMP = x; then
  549. AC_MSG_ERROR(hexdump is required for tests)
  550. fi
  551. if test x$use_boost = xyes; then
  552. AX_BOOST_UNIT_TEST_FRAMEWORK
  553. dnl Determine if -DBOOST_TEST_DYN_LINK is needed
  554. AC_MSG_CHECKING([for dynamic linked boost test])
  555. TEMP_LIBS="$LIBS"
  556. LIBS="$LIBS $BOOST_LDFLAGS $BOOST_UNIT_TEST_FRAMEWORK_LIB"
  557. TEMP_CPPFLAGS="$CPPFLAGS"
  558. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  559. AC_LINK_IFELSE([AC_LANG_SOURCE([
  560. #define BOOST_TEST_DYN_LINK
  561. #define BOOST_TEST_MAIN
  562. #include <boost/test/unit_test.hpp>
  563. ])],
  564. [AC_MSG_RESULT(yes)]
  565. [TESTDEFS="$TESTDEFS -DBOOST_TEST_DYN_LINK"],
  566. [AC_MSG_RESULT(no)])
  567. LIBS="$TEMP_LIBS"
  568. CPPFLAGS="$TEMP_CPPFLAGS"
  569. fi
  570. fi
  571. if test x$use_boost = xyes; then
  572. BOOST_LIBS="$BOOST_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_FILESYSTEM_LIB $BOOST_PROGRAM_OPTIONS_LIB $BOOST_THREAD_LIB $BOOST_CHRONO_LIB"
  573. dnl If boost (prior to 1.57) was built without c++11, it emulated scoped enums
  574. dnl using c++98 constructs. Unfortunately, this implementation detail leaked into
  575. dnl the abi. This was fixed in 1.57.
  576. dnl When building against that installed version using c++11, the headers pick up
  577. dnl on the native c++11 scoped enum support and enable it, however it will fail to
  578. dnl link. This can be worked around by disabling c++11 scoped enums if linking will
  579. dnl fail.
  580. dnl BOOST_NO_SCOPED_ENUMS was changed to BOOST_NO_CXX11_SCOPED_ENUMS in 1.51.
  581. TEMP_LIBS="$LIBS"
  582. LIBS="$BOOST_LIBS $LIBS"
  583. TEMP_CPPFLAGS="$CPPFLAGS"
  584. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  585. AC_MSG_CHECKING([for mismatched boost c++11 scoped enums])
  586. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  587. #include "boost/config.hpp"
  588. #include "boost/version.hpp"
  589. #if !defined(BOOST_NO_SCOPED_ENUMS) && !defined(BOOST_NO_CXX11_SCOPED_ENUMS) && BOOST_VERSION < 105700
  590. #define BOOST_NO_SCOPED_ENUMS
  591. #define BOOST_NO_CXX11_SCOPED_ENUMS
  592. #define CHECK
  593. #endif
  594. #include "boost/filesystem.hpp"
  595. ]],[[
  596. #if defined(CHECK)
  597. boost::filesystem::copy_file("foo", "bar");
  598. #else
  599. choke;
  600. #endif
  601. ]])],
  602. [AC_MSG_RESULT(mismatched); BOOST_CPPFLAGS="$BOOST_CPPFLAGS -DBOOST_NO_SCOPED_ENUMS -DBOOST_NO_CXX11_SCOPED_ENUMS"], [AC_MSG_RESULT(ok)])
  603. LIBS="$TEMP_LIBS"
  604. CPPFLAGS="$TEMP_CPPFLAGS"
  605. dnl Boost >= 1.50 uses sleep_for rather than the now-deprecated sleep, however
  606. dnl it was broken from 1.50 to 1.52 when backed by nanosleep. Use sleep_for if
  607. dnl a working version is available, else fall back to sleep. sleep was removed
  608. dnl after 1.56.
  609. dnl If neither is available, abort.
  610. TEMP_LIBS="$LIBS"
  611. LIBS="$BOOST_LIBS $LIBS"
  612. TEMP_CPPFLAGS="$CPPFLAGS"
  613. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  614. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  615. #include <boost/thread/thread.hpp>
  616. #include <boost/version.hpp>
  617. ]],[[
  618. #if BOOST_VERSION >= 105000 && (!defined(BOOST_HAS_NANOSLEEP) || BOOST_VERSION >= 105200)
  619. boost::this_thread::sleep_for(boost::chrono::milliseconds(0));
  620. #else
  621. choke me
  622. #endif
  623. ]])],
  624. [boost_sleep=yes;
  625. AC_DEFINE(HAVE_WORKING_BOOST_SLEEP_FOR, 1, [Define this symbol if boost sleep_for works])],
  626. [boost_sleep=no])
  627. LIBS="$TEMP_LIBS"
  628. CPPFLAGS="$TEMP_CPPFLAGS"
  629. if test x$boost_sleep != xyes; then
  630. TEMP_LIBS="$LIBS"
  631. LIBS="$BOOST_LIBS $LIBS"
  632. TEMP_CPPFLAGS="$CPPFLAGS"
  633. CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
  634. AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  635. #include <boost/version.hpp>
  636. #include <boost/thread.hpp>
  637. #include <boost/date_time/posix_time/posix_time_types.hpp>
  638. ]],[[
  639. #if BOOST_VERSION <= 105600
  640. boost::this_thread::sleep(boost::posix_time::milliseconds(0));
  641. #else
  642. choke me
  643. #endif
  644. ]])],
  645. [boost_sleep=yes; AC_DEFINE(HAVE_WORKING_BOOST_SLEEP, 1, [Define this symbol if boost sleep works])],
  646. [boost_sleep=no])
  647. LIBS="$TEMP_LIBS"
  648. CPPFLAGS="$TEMP_CPPFLAGS"
  649. fi
  650. if test x$boost_sleep != xyes; then
  651. AC_MSG_ERROR(No working boost sleep implementation found.)
  652. fi
  653. fi
  654. if test x$use_pkgconfig = xyes; then
  655. : dnl
  656. m4_ifdef(
  657. [PKG_CHECK_MODULES],
  658. [
  659. PKG_CHECK_MODULES([SSL], [libssl],, [AC_MSG_ERROR(openssl not found.)])
  660. PKG_CHECK_MODULES([CRYPTO], [libcrypto],,[AC_MSG_ERROR(libcrypto not found.)])
  661. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([PROTOBUF], [protobuf], [have_protobuf=yes], [BITCOIN_QT_FAIL(libprotobuf not found)])])
  662. if test x$use_qr != xno; then
  663. BITCOIN_QT_CHECK([PKG_CHECK_MODULES([QR], [libqrencode], [have_qrencode=yes], [have_qrencode=no])])
  664. fi
  665. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  666. PKG_CHECK_MODULES([EVENT], [libevent],, [AC_MSG_ERROR(libevent not found.)])
  667. if test x$TARGET_OS != xwindows; then
  668. PKG_CHECK_MODULES([EVENT_PTHREADS], [libevent_pthreads],, [AC_MSG_ERROR(libevent_pthreads not found.)])
  669. fi
  670. fi
  671. if test "x$use_zmq" = "xyes"; then
  672. PKG_CHECK_MODULES([ZMQ],[libzmq >= 4],
  673. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  674. [AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  675. AC_MSG_WARN([libzmq version 4.x or greater not found, disabling])
  676. use_zmq=no])
  677. else
  678. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  679. fi
  680. ]
  681. )
  682. else
  683. AC_CHECK_HEADER([openssl/crypto.h],,AC_MSG_ERROR(libcrypto headers missing))
  684. AC_CHECK_LIB([crypto], [main],CRYPTO_LIBS=-lcrypto, AC_MSG_ERROR(libcrypto missing))
  685. AC_CHECK_HEADER([openssl/ssl.h],, AC_MSG_ERROR(libssl headers missing),)
  686. AC_CHECK_LIB([ssl], [main],SSL_LIBS=-lssl, AC_MSG_ERROR(libssl missing))
  687. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests != xnononono; then
  688. AC_CHECK_HEADER([event2/event.h],, AC_MSG_ERROR(libevent headers missing),)
  689. AC_CHECK_LIB([event],[main],EVENT_LIBS=-levent,AC_MSG_ERROR(libevent missing))
  690. if test x$TARGET_OS != xwindows; then
  691. AC_CHECK_LIB([event_pthreads],[main],EVENT_PTHREADS_LIBS=-levent_pthreads,AC_MSG_ERROR(libevent_pthreads missing))
  692. fi
  693. fi
  694. if test "x$use_zmq" = "xyes"; then
  695. AC_CHECK_HEADER([zmq.h],
  696. [AC_DEFINE([ENABLE_ZMQ],[1],[Define to 1 to enable ZMQ functions])],
  697. [AC_MSG_WARN([zmq.h not found, disabling zmq support])
  698. use_zmq=no
  699. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  700. AC_CHECK_LIB([zmq],[zmq_ctx_shutdown],ZMQ_LIBS=-lzmq,
  701. [AC_MSG_WARN([libzmq >= 4.0 not found, disabling zmq support])
  702. use_zmq=no
  703. AC_DEFINE([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])])
  704. else
  705. AC_DEFINE_UNQUOTED([ENABLE_ZMQ],[0],[Define to 1 to enable ZMQ functions])
  706. fi
  707. if test "x$use_zmq" = "xyes"; then
  708. dnl Assume libzmq was built for static linking
  709. case $host in
  710. *mingw*)
  711. ZMQ_CFLAGS="$ZMQ_CFLAGS -DZMQ_STATIC"
  712. ;;
  713. esac
  714. fi
  715. BITCOIN_QT_CHECK(AC_CHECK_LIB([protobuf] ,[main],[PROTOBUF_LIBS=-lprotobuf], BITCOIN_QT_FAIL(libprotobuf not found)))
  716. if test x$use_qr != xno; then
  717. BITCOIN_QT_CHECK([AC_CHECK_LIB([qrencode], [main],[QR_LIBS=-lqrencode], [have_qrencode=no])])
  718. BITCOIN_QT_CHECK([AC_CHECK_HEADER([qrencode.h],, have_qrencode=no)])
  719. fi
  720. fi
  721. save_CXXFLAGS="${CXXFLAGS}"
  722. CXXFLAGS="${CXXFLAGS} ${CRYPTO_CFLAGS} ${SSL_CFLAGS}"
  723. AC_CHECK_DECLS([EVP_MD_CTX_new],,,[AC_INCLUDES_DEFAULT
  724. #include <openssl/x509_vfy.h>
  725. ])
  726. CXXFLAGS="${save_CXXFLAGS}"
  727. dnl univalue check
  728. need_bundled_univalue=yes
  729. if test x$build_bitcoin_utils$build_bitcoind$bitcoin_enable_qt$use_tests$use_bench = xnonononono; then
  730. need_bundled_univalue=no
  731. else
  732. if test x$system_univalue != xno ; then
  733. found_univalue=no
  734. if test x$use_pkgconfig = xyes; then
  735. : #NOP
  736. m4_ifdef(
  737. [PKG_CHECK_MODULES],
  738. [
  739. PKG_CHECK_MODULES([UNIVALUE],[libunivalue],[found_univalue=yes],[true])
  740. ]
  741. )
  742. else
  743. AC_CHECK_HEADER([univalue.h],[
  744. AC_CHECK_LIB([univalue], [main],[
  745. UNIVALUE_LIBS=-lunivalue
  746. found_univalue=yes
  747. ],[true])
  748. ],[true])
  749. fi
  750. if test x$found_univalue = xyes ; then
  751. system_univalue=yes
  752. need_bundled_univalue=no
  753. elif test x$system_univalue = xyes ; then
  754. AC_MSG_ERROR([univalue not found])
  755. else
  756. system_univalue=no
  757. fi
  758. fi
  759. if test x$need_bundled_univalue = xyes ; then
  760. UNIVALUE_CFLAGS='-I$(srcdir)/univalue/include'
  761. UNIVALUE_LIBS='univalue/libunivalue.la'
  762. fi
  763. fi
  764. AM_CONDITIONAL([EMBEDDED_UNIVALUE],[test x$need_bundled_univalue = xyes])
  765. AC_SUBST(UNIVALUE_CFLAGS)
  766. AC_SUBST(UNIVALUE_LIBS)
  767. BITCOIN_QT_PATH_PROGS([PROTOC], [protoc],$protoc_bin_path)
  768. AC_MSG_CHECKING([whether to build bitcoind])
  769. AM_CONDITIONAL([BUILD_BITCOIND], [test x$build_bitcoind = xyes])
  770. AC_MSG_RESULT($build_bitcoind)
  771. AC_MSG_CHECKING([whether to build utils (bitcoin-cli bitcoin-tx)])
  772. AM_CONDITIONAL([BUILD_BITCOIN_UTILS], [test x$build_bitcoin_utils = xyes])
  773. AC_MSG_RESULT($build_bitcoin_utils)
  774. AC_MSG_CHECKING([whether to build libraries])
  775. AM_CONDITIONAL([BUILD_BITCOIN_LIBS], [test x$build_bitcoin_libs = xyes])
  776. if test x$build_bitcoin_libs = xyes; then
  777. AC_DEFINE(HAVE_CONSENSUS_LIB, 1, [Define this symbol if the consensus lib has been built])
  778. AC_CONFIG_FILES([libbitcoinconsensus.pc:libbitcoinconsensus.pc.in])
  779. fi
  780. AC_MSG_RESULT($build_bitcoin_libs)
  781. AC_LANG_POP
  782. if test "x$use_ccache" != "xno"; then
  783. AC_MSG_CHECKING(if ccache should be used)
  784. if test x$CCACHE = x; then
  785. if test "x$use_ccache" = "xyes"; then
  786. AC_MSG_ERROR([ccache not found.]);
  787. else
  788. use_ccache=no
  789. fi
  790. else
  791. use_ccache=yes
  792. CC="$ac_cv_path_CCACHE $CC"
  793. CXX="$ac_cv_path_CCACHE $CXX"
  794. fi
  795. AC_MSG_RESULT($use_ccache)
  796. fi
  797. if test "x$use_ccache" = "xyes"; then
  798. AX_CHECK_PREPROC_FLAG([-Qunused-arguments],[CPPFLAGS="-Qunused-arguments $CPPFLAGS"])
  799. fi
  800. dnl enable wallet
  801. AC_MSG_CHECKING([if wallet should be enabled])
  802. if test x$enable_wallet != xno; then
  803. AC_MSG_RESULT(yes)
  804. AC_DEFINE_UNQUOTED([ENABLE_WALLET],[1],[Define to 1 to enable wallet functions])
  805. else
  806. AC_MSG_RESULT(no)
  807. fi
  808. dnl enable upnp support
  809. AC_MSG_CHECKING([whether to build with support for UPnP])
  810. if test x$have_miniupnpc = xno; then
  811. if test x$use_upnp = xyes; then
  812. AC_MSG_ERROR("UPnP requested but cannot be built. use --without-miniupnpc")
  813. fi
  814. AC_MSG_RESULT(no)
  815. else
  816. if test x$use_upnp != xno; then
  817. AC_MSG_RESULT(yes)
  818. AC_MSG_CHECKING([whether to build with UPnP enabled by default])
  819. use_upnp=yes
  820. upnp_setting=0
  821. if test x$use_upnp_default != xno; then
  822. use_upnp_default=yes
  823. upnp_setting=1
  824. fi
  825. AC_MSG_RESULT($use_upnp_default)
  826. AC_DEFINE_UNQUOTED([USE_UPNP],[$upnp_setting],[UPnP support not compiled if undefined, otherwise value (0 or 1) determines default state])
  827. if test x$TARGET_OS = xwindows; then
  828. MINIUPNPC_CPPFLAGS="-DSTATICLIB -DMINIUPNP_STATICLIB"
  829. fi
  830. else
  831. AC_MSG_RESULT(no)
  832. fi
  833. fi
  834. dnl these are only used when qt is enabled
  835. BUILD_TEST_QT=""
  836. if test x$bitcoin_enable_qt != xno; then
  837. dnl enable dbus support
  838. AC_MSG_CHECKING([whether to build GUI with support for D-Bus])
  839. if test x$bitcoin_enable_qt_dbus != xno; then
  840. AC_DEFINE([USE_DBUS],[1],[Define if dbus support should be compiled in])
  841. fi
  842. AC_MSG_RESULT($bitcoin_enable_qt_dbus)
  843. dnl enable qr support
  844. AC_MSG_CHECKING([whether to build GUI with support for QR codes])
  845. if test x$have_qrencode = xno; then
  846. if test x$use_qr = xyes; then
  847. AC_MSG_ERROR("QR support requested but cannot be built. use --without-qrencode")
  848. fi
  849. AC_MSG_RESULT(no)
  850. else
  851. if test x$use_qr != xno; then
  852. AC_MSG_RESULT(yes)
  853. AC_DEFINE([USE_QRCODE],[1],[Define if QR support should be compiled in])
  854. use_qr=yes
  855. else
  856. AC_MSG_RESULT(no)
  857. fi
  858. fi
  859. if test x$XGETTEXT = x; then
  860. AC_MSG_WARN("xgettext is required to update qt translations")
  861. fi
  862. AC_MSG_CHECKING([whether to build test_bitcoin-qt])
  863. if test x$use_gui_tests$bitcoin_enable_qt_test = xyesyes; then
  864. AC_MSG_RESULT([yes])
  865. BUILD_TEST_QT="yes"
  866. else
  867. AC_MSG_RESULT([no])
  868. fi
  869. fi
  870. AM_CONDITIONAL([ENABLE_ZMQ], [test "x$use_zmq" = "xyes"])
  871. AC_MSG_CHECKING([whether to build test_bitcoin])
  872. if test x$use_tests = xyes; then
  873. AC_MSG_RESULT([yes])
  874. BUILD_TEST="yes"
  875. else
  876. AC_MSG_RESULT([no])
  877. BUILD_TEST=""
  878. fi
  879. AC_MSG_CHECKING([whether to reduce exports])
  880. if test x$use_reduce_exports = xyes; then
  881. AC_MSG_RESULT([yes])
  882. else
  883. AC_MSG_RESULT([no])
  884. fi
  885. if test x$build_bitcoin_utils$build_bitcoin_libs$build_bitcoind$bitcoin_enable_qt$use_bench$use_tests = xnononononono; then
  886. AC_MSG_ERROR([No targets! Please specify at least one of: --with-utils --with-libs --with-daemon --with-gui --enable-bench or --enable-tests])
  887. fi
  888. AM_CONDITIONAL([TARGET_DARWIN], [test x$TARGET_OS = xdarwin])
  889. AM_CONDITIONAL([BUILD_DARWIN], [test x$BUILD_OS = xdarwin])
  890. AM_CONDITIONAL([TARGET_WINDOWS], [test x$TARGET_OS = xwindows])
  891. AM_CONDITIONAL([ENABLE_WALLET],[test x$enable_wallet = xyes])
  892. AM_CONDITIONAL([ENABLE_TESTS],[test x$BUILD_TEST = xyes])
  893. AM_CONDITIONAL([ENABLE_QT],[test x$bitcoin_enable_qt = xyes])
  894. AM_CONDITIONAL([ENABLE_QT_TESTS],[test x$BUILD_TEST_QT = xyes])
  895. AM_CONDITIONAL([ENABLE_BENCH],[test x$use_bench = xyes])
  896. AM_CONDITIONAL([USE_QRCODE], [test x$use_qr = xyes])
  897. AM_CONDITIONAL([USE_LCOV],[test x$use_lcov = xyes])
  898. AM_CONDITIONAL([GLIBC_BACK_COMPAT],[test x$use_glibc_compat = xyes])
  899. AM_CONDITIONAL([HARDEN],[test x$use_hardening = xyes])
  900. AC_DEFINE(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR, [Major version])
  901. AC_DEFINE(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR, [Minor version])
  902. AC_DEFINE(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION, [Build revision])
  903. AC_DEFINE(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD, [Version Build])
  904. AC_DEFINE(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE, [Version is release])
  905. AC_DEFINE(COPYRIGHT_YEAR, _COPYRIGHT_YEAR, [Copyright year])
  906. AC_DEFINE(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS", [Copyright holder(s) before %s replacement])
  907. AC_DEFINE(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION", [Replacement for %s in copyright holders string])
  908. define(_COPYRIGHT_HOLDERS_FINAL, [patsubst(_COPYRIGHT_HOLDERS, [%s], [_COPYRIGHT_HOLDERS_SUBSTITUTION])])
  909. AC_DEFINE(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL", [Copyright holder(s)])
  910. AC_SUBST(CLIENT_VERSION_MAJOR, _CLIENT_VERSION_MAJOR)
  911. AC_SUBST(CLIENT_VERSION_MINOR, _CLIENT_VERSION_MINOR)
  912. AC_SUBST(CLIENT_VERSION_REVISION, _CLIENT_VERSION_REVISION)
  913. AC_SUBST(CLIENT_VERSION_BUILD, _CLIENT_VERSION_BUILD)
  914. AC_SUBST(CLIENT_VERSION_IS_RELEASE, _CLIENT_VERSION_IS_RELEASE)
  915. AC_SUBST(COPYRIGHT_YEAR, _COPYRIGHT_YEAR)
  916. AC_SUBST(COPYRIGHT_HOLDERS, "_COPYRIGHT_HOLDERS")
  917. AC_SUBST(COPYRIGHT_HOLDERS_SUBSTITUTION, "_COPYRIGHT_HOLDERS_SUBSTITUTION")
  918. AC_SUBST(COPYRIGHT_HOLDERS_FINAL, "_COPYRIGHT_HOLDERS_FINAL")
  919. AC_SUBST(BITCOIN_DAEMON_NAME)
  920. AC_SUBST(BITCOIN_GUI_NAME)
  921. AC_SUBST(BITCOIN_CLI_NAME)
  922. AC_SUBST(BITCOIN_TX_NAME)
  923. AC_SUBST(RELDFLAGS)
  924. AC_SUBST(HARDENED_CXXFLAGS)
  925. AC_SUBST(HARDENED_CPPFLAGS)
  926. AC_SUBST(HARDENED_LDFLAGS)
  927. AC_SUBST(PIC_FLAGS)
  928. AC_SUBST(PIE_FLAGS)
  929. AC_SUBST(LIBTOOL_APP_LDFLAGS)
  930. AC_SUBST(USE_UPNP)
  931. AC_SUBST(USE_QRCODE)
  932. AC_SUBST(BOOST_LIBS)
  933. AC_SUBST(TESTDEFS)
  934. AC_SUBST(LEVELDB_TARGET_FLAGS)
  935. AC_SUBST(MINIUPNPC_CPPFLAGS)
  936. AC_SUBST(MINIUPNPC_LIBS)
  937. AC_SUBST(CRYPTO_LIBS)
  938. AC_SUBST(SSL_LIBS)
  939. AC_SUBST(EVENT_LIBS)
  940. AC_SUBST(EVENT_PTHREADS_LIBS)
  941. AC_SUBST(ZMQ_LIBS)
  942. AC_SUBST(PROTOBUF_LIBS)
  943. AC_SUBST(QR_LIBS)
  944. AC_CONFIG_FILES([Makefile src/Makefile doc/man/Makefile share/setup.nsi share/qt/Info.plist src/test/buildenv.py])
  945. AC_CONFIG_FILES([qa/pull-tester/tests_config.ini],[chmod +x qa/pull-tester/tests_config.ini])
  946. AC_CONFIG_FILES([contrib/devtools/split-debug.sh],[chmod +x contrib/devtools/split-debug.sh])
  947. AC_CONFIG_LINKS([qa/pull-tester/rpc-tests.py:qa/pull-tester/rpc-tests.py])
  948. dnl boost's m4 checks do something really nasty: they export these vars. As a
  949. dnl result, they leak into secp256k1's configure and crazy things happen.
  950. dnl Until this is fixed upstream and we've synced, we'll just un-export them.
  951. CPPFLAGS_TEMP="$CPPFLAGS"
  952. unset CPPFLAGS
  953. CPPFLAGS="$CPPFLAGS_TEMP"
  954. LDFLAGS_TEMP="$LDFLAGS"
  955. unset LDFLAGS
  956. LDFLAGS="$LDFLAGS_TEMP"
  957. LIBS_TEMP="$LIBS"
  958. unset LIBS
  959. LIBS="$LIBS_TEMP"
  960. PKGCONFIG_PATH_TEMP="$PKG_CONFIG_PATH"
  961. unset PKG_CONFIG_PATH
  962. PKG_CONFIG_PATH="$PKGCONFIG_PATH_TEMP"
  963. PKGCONFIG_LIBDIR_TEMP="$PKG_CONFIG_LIBDIR"
  964. unset PKG_CONFIG_LIBDIR
  965. PKG_CONFIG_LIBDIR="$PKGCONFIG_LIBDIR_TEMP"
  966. if test x$need_bundled_univalue = xyes; then
  967. AC_CONFIG_SUBDIRS([src/univalue])
  968. fi
  969. ac_configure_args="${ac_configure_args} --disable-shared --with-pic --with-bignum=no --enable-module-recovery"
  970. AC_CONFIG_SUBDIRS([src/secp256k1])
  971. AC_OUTPUT
  972. dnl Taken from https://wiki.debian.org/RpathIssue
  973. case $host in
  974. *-*-linux-gnu)
  975. AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  976. sed < libtool > libtool-2 \
  977. 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  978. mv libtool-2 libtool
  979. chmod 755 libtool
  980. ;;
  981. esac
  982. dnl Replace the BUILDDIR path with the correct Windows path if compiling on Native Windows
  983. case ${OS} in
  984. *Windows*)
  985. sed 's/BUILDDIR="\/\([[a-z]]\)/BUILDDIR="\1:/' qa/pull-tester/tests_config.py > qa/pull-tester/tests_config-2.py
  986. mv qa/pull-tester/tests_config-2.py qa/pull-tester/tests_config.py
  987. ;;
  988. esac
  989. echo
  990. echo "Options used to compile and link:"
  991. echo " with wallet = $enable_wallet"
  992. echo " with gui / qt = $bitcoin_enable_qt"
  993. if test x$bitcoin_enable_qt != xno; then
  994. echo " qt version = $bitcoin_qt_got_major_vers"
  995. echo " with qr = $use_qr"
  996. fi
  997. echo " with zmq = $use_zmq"
  998. echo " with test = $use_tests"
  999. echo " with bench = $use_bench"
  1000. echo " with upnp = $use_upnp"
  1001. echo " debug enabled = $enable_debug"
  1002. echo
  1003. echo " target os = $TARGET_OS"
  1004. echo " build os = $BUILD_OS"
  1005. echo
  1006. echo " CC = $CC"
  1007. echo " CFLAGS = $CFLAGS"
  1008. echo " CPPFLAGS = $CPPFLAGS"
  1009. echo " CXX = $CXX"
  1010. echo " CXXFLAGS = $CXXFLAGS"
  1011. echo " LDFLAGS = $LDFLAGS"
  1012. echo