You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

ax_pthread.m4 20KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485
  1. # ===========================================================================
  2. # http://www.gnu.org/software/autoconf-archive/ax_pthread.html
  3. # ===========================================================================
  4. #
  5. # SYNOPSIS
  6. #
  7. # AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  8. #
  9. # DESCRIPTION
  10. #
  11. # This macro figures out how to build C programs using POSIX threads. It
  12. # sets the PTHREAD_LIBS output variable to the threads library and linker
  13. # flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14. # flags that are needed. (The user can also force certain compiler
  15. # flags/libs to be tested by setting these environment variables.)
  16. #
  17. # Also sets PTHREAD_CC to any special C compiler that is needed for
  18. # multi-threaded programs (defaults to the value of CC otherwise). (This
  19. # is necessary on AIX to use the special cc_r compiler alias.)
  20. #
  21. # NOTE: You are assumed to not only compile your program with these flags,
  22. # but also to link with them as well. For example, you might link with
  23. # $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24. #
  25. # If you are only building threaded programs, you may wish to use these
  26. # variables in your default LIBS, CFLAGS, and CC:
  27. #
  28. # LIBS="$PTHREAD_LIBS $LIBS"
  29. # CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30. # CC="$PTHREAD_CC"
  31. #
  32. # In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33. # has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to
  34. # that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35. #
  36. # Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  37. # PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  38. # PTHREAD_CFLAGS.
  39. #
  40. # ACTION-IF-FOUND is a list of shell commands to run if a threads library
  41. # is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  42. # is not found. If ACTION-IF-FOUND is not specified, the default action
  43. # will define HAVE_PTHREAD.
  44. #
  45. # Please let the authors know if this macro fails on any platform, or if
  46. # you have any other suggestions or comments. This macro was based on work
  47. # by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  48. # from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  49. # Alejandro Forero Cuervo to the autoconf macro repository. We are also
  50. # grateful for the helpful feedback of numerous users.
  51. #
  52. # Updated for Autoconf 2.68 by Daniel Richard G.
  53. #
  54. # LICENSE
  55. #
  56. # Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  57. # Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  58. #
  59. # This program is free software: you can redistribute it and/or modify it
  60. # under the terms of the GNU General Public License as published by the
  61. # Free Software Foundation, either version 3 of the License, or (at your
  62. # option) any later version.
  63. #
  64. # This program is distributed in the hope that it will be useful, but
  65. # WITHOUT ANY WARRANTY; without even the implied warranty of
  66. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  67. # Public License for more details.
  68. #
  69. # You should have received a copy of the GNU General Public License along
  70. # with this program. If not, see <http://www.gnu.org/licenses/>.
  71. #
  72. # As a special exception, the respective Autoconf Macro's copyright owner
  73. # gives unlimited permission to copy, distribute and modify the configure
  74. # scripts that are the output of Autoconf when processing the Macro. You
  75. # need not follow the terms of the GNU General Public License when using
  76. # or distributing such scripts, even though portions of the text of the
  77. # Macro appear in them. The GNU General Public License (GPL) does govern
  78. # all other use of the material that constitutes the Autoconf Macro.
  79. #
  80. # This special exception to the GPL applies to versions of the Autoconf
  81. # Macro released by the Autoconf Archive. When you make and distribute a
  82. # modified version of the Autoconf Macro, you may extend this special
  83. # exception to the GPL to apply to your modified version as well.
  84. #serial 23
  85. AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  86. AC_DEFUN([AX_PTHREAD], [
  87. AC_REQUIRE([AC_CANONICAL_HOST])
  88. AC_REQUIRE([AC_PROG_CC])
  89. AC_REQUIRE([AC_PROG_SED])
  90. AC_LANG_PUSH([C])
  91. ax_pthread_ok=no
  92. # We used to check for pthread.h first, but this fails if pthread.h
  93. # requires special compiler flags (e.g. on Tru64 or Sequent).
  94. # It gets checked for in the link test anyway.
  95. # First of all, check if the user has set any of the PTHREAD_LIBS,
  96. # etcetera environment variables, and if threads linking works using
  97. # them:
  98. if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then
  99. ax_pthread_save_CC="$CC"
  100. ax_pthread_save_CFLAGS="$CFLAGS"
  101. ax_pthread_save_LIBS="$LIBS"
  102. AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"])
  103. CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  104. LIBS="$PTHREAD_LIBS $LIBS"
  105. AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
  106. AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
  107. AC_MSG_RESULT([$ax_pthread_ok])
  108. if test "x$ax_pthread_ok" = "xno"; then
  109. PTHREAD_LIBS=""
  110. PTHREAD_CFLAGS=""
  111. fi
  112. CC="$ax_pthread_save_CC"
  113. CFLAGS="$ax_pthread_save_CFLAGS"
  114. LIBS="$ax_pthread_save_LIBS"
  115. fi
  116. # We must check for the threads library under a number of different
  117. # names; the ordering is very important because some systems
  118. # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
  119. # libraries is broken (non-POSIX).
  120. # Create a list of thread flags to try. Items starting with a "-" are
  121. # C compiler flags, and other items are library names, except for "none"
  122. # which indicates that we try without any flags at all, and "pthread-config"
  123. # which is a program returning the flags for the Pth emulation library.
  124. ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
  125. # The ordering *is* (sometimes) important. Some notes on the
  126. # individual items follow:
  127. # pthreads: AIX (must check this before -lpthread)
  128. # none: in case threads are in libc; should be tried before -Kthread and
  129. # other compiler flags to prevent continual compiler warnings
  130. # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
  131. # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
  132. # (Note: HP C rejects this with "bad form for `-t' option")
  133. # -pthreads: Solaris/gcc (Note: HP C also rejects)
  134. # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
  135. # doesn't hurt to check since this sometimes defines pthreads and
  136. # -D_REENTRANT too), HP C (must be checked before -lpthread, which
  137. # is present but should not be used directly; and before -mthreads,
  138. # because the compiler interprets this as "-mt" + "-hreads")
  139. # -mthreads: Mingw32/gcc, Lynx/gcc
  140. # pthread: Linux, etcetera
  141. # --thread-safe: KAI C++
  142. # pthread-config: use pthread-config program (for GNU Pth library)
  143. case $host_os in
  144. freebsd*)
  145. # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
  146. # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
  147. ax_pthread_flags="-kthread lthread $ax_pthread_flags"
  148. ;;
  149. hpux*)
  150. # From the cc(1) man page: "[-mt] Sets various -D flags to enable
  151. # multi-threading and also sets -lpthread."
  152. ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
  153. ;;
  154. openedition*)
  155. # IBM z/OS requires a feature-test macro to be defined in order to
  156. # enable POSIX threads at all, so give the user a hint if this is
  157. # not set. (We don't define these ourselves, as they can affect
  158. # other portions of the system API in unpredictable ways.)
  159. AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
  160. [
  161. # if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
  162. AX_PTHREAD_ZOS_MISSING
  163. # endif
  164. ],
  165. [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
  166. ;;
  167. solaris*)
  168. # On Solaris (at least, for some versions), libc contains stubbed
  169. # (non-functional) versions of the pthreads routines, so link-based
  170. # tests will erroneously succeed. (N.B.: The stubs are missing
  171. # pthread_cleanup_push, or rather a function called by this macro,
  172. # so we could check for that, but who knows whether they'll stub
  173. # that too in a future libc.) So we'll check first for the
  174. # standard Solaris way of linking pthreads (-mt -lpthread).
  175. ax_pthread_flags="-mt,pthread pthread $ax_pthread_flags"
  176. ;;
  177. esac
  178. # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC)
  179. AS_IF([test "x$GCC" = "xyes"],
  180. [ax_pthread_flags="-pthread -pthreads $ax_pthread_flags"])
  181. # The presence of a feature test macro requesting re-entrant function
  182. # definitions is, on some systems, a strong hint that pthreads support is
  183. # correctly enabled
  184. case $host_os in
  185. darwin* | hpux* | linux* | osf* | solaris*)
  186. ax_pthread_check_macro="_REENTRANT"
  187. ;;
  188. aix*)
  189. ax_pthread_check_macro="_THREAD_SAFE"
  190. ;;
  191. *)
  192. ax_pthread_check_macro="--"
  193. ;;
  194. esac
  195. AS_IF([test "x$ax_pthread_check_macro" = "x--"],
  196. [ax_pthread_check_cond=0],
  197. [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"])
  198. # Are we compiling with Clang?
  199. AC_CACHE_CHECK([whether $CC is Clang],
  200. [ax_cv_PTHREAD_CLANG],
  201. [ax_cv_PTHREAD_CLANG=no
  202. # Note that Autoconf sets GCC=yes for Clang as well as GCC
  203. if test "x$GCC" = "xyes"; then
  204. AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG],
  205. [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */
  206. # if defined(__clang__) && defined(__llvm__)
  207. AX_PTHREAD_CC_IS_CLANG
  208. # endif
  209. ],
  210. [ax_cv_PTHREAD_CLANG=yes])
  211. fi
  212. ])
  213. ax_pthread_clang="$ax_cv_PTHREAD_CLANG"
  214. ax_pthread_clang_warning=no
  215. # Clang needs special handling, because older versions handle the -pthread
  216. # option in a rather... idiosyncratic way
  217. if test "x$ax_pthread_clang" = "xyes"; then
  218. # Clang takes -pthread; it has never supported any other flag
  219. # (Note 1: This will need to be revisited if a system that Clang
  220. # supports has POSIX threads in a separate library. This tends not
  221. # to be the way of modern systems, but it's conceivable.)
  222. # (Note 2: On some systems, notably Darwin, -pthread is not needed
  223. # to get POSIX threads support; the API is always present and
  224. # active. We could reasonably leave PTHREAD_CFLAGS empty. But
  225. # -pthread does define _REENTRANT, and while the Darwin headers
  226. # ignore this macro, third-party headers might not.)
  227. PTHREAD_CFLAGS="-pthread"
  228. PTHREAD_LIBS=
  229. ax_pthread_ok=yes
  230. # However, older versions of Clang make a point of warning the user
  231. # that, in an invocation where only linking and no compilation is
  232. # taking place, the -pthread option has no effect ("argument unused
  233. # during compilation"). They expect -pthread to be passed in only
  234. # when source code is being compiled.
  235. #
  236. # Problem is, this is at odds with the way Automake and most other
  237. # C build frameworks function, which is that the same flags used in
  238. # compilation (CFLAGS) are also used in linking. Many systems
  239. # supported by AX_PTHREAD require exactly this for POSIX threads
  240. # support, and in fact it is often not straightforward to specify a
  241. # flag that is used only in the compilation phase and not in
  242. # linking. Such a scenario is extremely rare in practice.
  243. #
  244. # Even though use of the -pthread flag in linking would only print
  245. # a warning, this can be a nuisance for well-run software projects
  246. # that build with -Werror. So if the active version of Clang has
  247. # this misfeature, we search for an option to squash it.
  248. AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread],
  249. [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG],
  250. [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown
  251. # Create an alternate version of $ac_link that compiles and
  252. # links in two steps (.c -> .o, .o -> exe) instead of one
  253. # (.c -> exe), because the warning occurs only in the second
  254. # step
  255. ax_pthread_save_ac_link="$ac_link"
  256. ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g'
  257. ax_pthread_link_step=`$as_echo "$ac_link" | sed "$ax_pthread_sed"`
  258. ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)"
  259. ax_pthread_save_CFLAGS="$CFLAGS"
  260. for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do
  261. AS_IF([test "x$ax_pthread_try" = "xunknown"], [break])
  262. CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS"
  263. ac_link="$ax_pthread_save_ac_link"
  264. AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
  265. [ac_link="$ax_pthread_2step_ac_link"
  266. AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
  267. [break])
  268. ])
  269. done
  270. ac_link="$ax_pthread_save_ac_link"
  271. CFLAGS="$ax_pthread_save_CFLAGS"
  272. AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no])
  273. ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try"
  274. ])
  275. case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in
  276. no | unknown) ;;
  277. *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;;
  278. esac
  279. fi # $ax_pthread_clang = yes
  280. if test "x$ax_pthread_ok" = "xno"; then
  281. for ax_pthread_try_flag in $ax_pthread_flags; do
  282. case $ax_pthread_try_flag in
  283. none)
  284. AC_MSG_CHECKING([whether pthreads work without any flags])
  285. ;;
  286. -mt,pthread)
  287. AC_MSG_CHECKING([whether pthreads work with -mt -lpthread])
  288. PTHREAD_CFLAGS="-mt"
  289. PTHREAD_LIBS="-lpthread"
  290. ;;
  291. -*)
  292. AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag])
  293. PTHREAD_CFLAGS="$ax_pthread_try_flag"
  294. ;;
  295. pthread-config)
  296. AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
  297. AS_IF([test "x$ax_pthread_config" = "xno"], [continue])
  298. PTHREAD_CFLAGS="`pthread-config --cflags`"
  299. PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
  300. ;;
  301. *)
  302. AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag])
  303. PTHREAD_LIBS="-l$ax_pthread_try_flag"
  304. ;;
  305. esac
  306. ax_pthread_save_CFLAGS="$CFLAGS"
  307. ax_pthread_save_LIBS="$LIBS"
  308. CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  309. LIBS="$PTHREAD_LIBS $LIBS"
  310. # Check for various functions. We must include pthread.h,
  311. # since some functions may be macros. (On the Sequent, we
  312. # need a special flag -Kthread to make this header compile.)
  313. # We check for pthread_join because it is in -lpthread on IRIX
  314. # while pthread_create is in libc. We check for pthread_attr_init
  315. # due to DEC craziness with -lpthreads. We check for
  316. # pthread_cleanup_push because it is one of the few pthread
  317. # functions on Solaris that doesn't have a non-functional libc stub.
  318. # We try pthread_create on general principles.
  319. AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
  320. # if $ax_pthread_check_cond
  321. # error "$ax_pthread_check_macro must be defined"
  322. # endif
  323. static void routine(void *a) { a = 0; }
  324. static void *start_routine(void *a) { return a; }],
  325. [pthread_t th; pthread_attr_t attr;
  326. pthread_create(&th, 0, start_routine, 0);
  327. pthread_join(th, 0);
  328. pthread_attr_init(&attr);
  329. pthread_cleanup_push(routine, 0);
  330. pthread_cleanup_pop(0) /* ; */])],
  331. [ax_pthread_ok=yes],
  332. [])
  333. CFLAGS="$ax_pthread_save_CFLAGS"
  334. LIBS="$ax_pthread_save_LIBS"
  335. AC_MSG_RESULT([$ax_pthread_ok])
  336. AS_IF([test "x$ax_pthread_ok" = "xyes"], [break])
  337. PTHREAD_LIBS=""
  338. PTHREAD_CFLAGS=""
  339. done
  340. fi
  341. # Various other checks:
  342. if test "x$ax_pthread_ok" = "xyes"; then
  343. ax_pthread_save_CFLAGS="$CFLAGS"
  344. ax_pthread_save_LIBS="$LIBS"
  345. CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  346. LIBS="$PTHREAD_LIBS $LIBS"
  347. # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
  348. AC_CACHE_CHECK([for joinable pthread attribute],
  349. [ax_cv_PTHREAD_JOINABLE_ATTR],
  350. [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
  351. for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
  352. AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
  353. [int attr = $ax_pthread_attr; return attr /* ; */])],
  354. [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break],
  355. [])
  356. done
  357. ])
  358. AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \
  359. test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \
  360. test "x$ax_pthread_joinable_attr_defined" != "xyes"],
  361. [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
  362. [$ax_cv_PTHREAD_JOINABLE_ATTR],
  363. [Define to necessary symbol if this constant
  364. uses a non-standard name on your system.])
  365. ax_pthread_joinable_attr_defined=yes
  366. ])
  367. AC_CACHE_CHECK([whether more special flags are required for pthreads],
  368. [ax_cv_PTHREAD_SPECIAL_FLAGS],
  369. [ax_cv_PTHREAD_SPECIAL_FLAGS=no
  370. case $host_os in
  371. solaris*)
  372. ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS"
  373. ;;
  374. esac
  375. ])
  376. AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
  377. test "x$ax_pthread_special_flags_added" != "xyes"],
  378. [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
  379. ax_pthread_special_flags_added=yes])
  380. AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
  381. [ax_cv_PTHREAD_PRIO_INHERIT],
  382. [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
  383. [[int i = PTHREAD_PRIO_INHERIT;]])],
  384. [ax_cv_PTHREAD_PRIO_INHERIT=yes],
  385. [ax_cv_PTHREAD_PRIO_INHERIT=no])
  386. ])
  387. AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \
  388. test "x$ax_pthread_prio_inherit_defined" != "xyes"],
  389. [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])
  390. ax_pthread_prio_inherit_defined=yes
  391. ])
  392. CFLAGS="$ax_pthread_save_CFLAGS"
  393. LIBS="$ax_pthread_save_LIBS"
  394. # More AIX lossage: compile with *_r variant
  395. if test "x$GCC" != "xyes"; then
  396. case $host_os in
  397. aix*)
  398. AS_CASE(["x/$CC"],
  399. [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
  400. [#handle absolute path differently from PATH based program lookup
  401. AS_CASE(["x$CC"],
  402. [x/*],
  403. [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])],
  404. [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])])
  405. ;;
  406. esac
  407. fi
  408. fi
  409. test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
  410. AC_SUBST([PTHREAD_LIBS])
  411. AC_SUBST([PTHREAD_CFLAGS])
  412. AC_SUBST([PTHREAD_CC])
  413. # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
  414. if test "x$ax_pthread_ok" = "xyes"; then
  415. ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
  416. :
  417. else
  418. ax_pthread_ok=no
  419. $2
  420. fi
  421. AC_LANG_POP
  422. ])dnl AX_PTHREAD